Foro - Perl en Español

por **bvayap** » 2013-05-31 05:31 @271

Hola,

Soy nuevo en Perl y también en este foro (aunque me está gustando y creo que vengo para quedarme :wink:

)

Tengo un fichero.csv con dos columnas de longitud variable:

Nombre_Sede;Red_Sede

La idea es leer ambos valores, abrir un fichero .txt, buscar en él el valor Red_Sede y reemplazarlo por Nombre_Sede.

¿Alguna sugerencia? Lo he hecho con VBscript, pero obviamente con un rendimiento nefasto :-(

Gracias por la ayuda.

#!/usr/bin/perl
use strict;                                # estilo estricto
use warnings;                              # activar advertencias
use diagnostics;                           # diagnósticos de fallos
use autodie;                               # «Es mejor morir que regresar con deshonor» --proverbio Klingon
 
### Variables
my $archivo;                               # archivo a procesar
 
### Lectura del archivo a tratar
open my $ARCHIVO, '<', 'archivo.txt';
{
    local $/;                              # activar modo aspiradora
    $archivo = <$ARCHIVO>;                 # lo leemos de una pasada
}
close $ARCHIVO;
 
### Lectura del archivo CSV
open my $CSV, '<', 'archivo.csv';
 
while (<$CSV>) {                           # para cada línea, hasta fin de archivo
    chomp;                                 # quitamos caracteres fin de línea
    my($nombre, $red) = split /[;]/;       # partimos la línea, extraemos columnas
 
    $archivo =~ s/\b$red\b/$nombre/g;      # cambiamos toda aparición de $red por $nombre, en el $archivo
}
 
close $CSV;
 
### Grabación del resultado
open my $SALIDA, '>', 'archivo.txt';
print   $SALIDA $archivo;
close   $SALIDA;
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

por **bvayap** » 2013-05-31 07:05 @336

Muchas gracias por tu respuesta, explorer.

He probado el script y al principio me daba un error (o warning, no sé) diciendo que la variable $ARCHIVO enmascaraba una declaración tardía y que podía ser un error tipográfico, así que he probado a cambiar en las tres últimas lineas de código y utilizar otra variable, $ARCHIVO2. Ahora ya no sale el warning, pero no hace lo que quiero, y creo que es por el cambio que he hecho.

Te paso un ejemplo de los ficheros que gasto:

Sintáxis: (archivo.csv) [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

Sede_Cantabria;172.16.18.5

Sede_Leon;172.19.194.101

...Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Sintáxis: (archivo.txt) [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

2013-05-31 09:00:15 172.16.18.5

2013-05-31 09:00:18 172.19.194.101

2013-05-31 09:00:21 172.16.18.5

...Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Al ejecutar el script no da ningún error pero el fichero archivo.txt sigue igual, sin cambiar la IP por el nombre de la sede. ¿Alguna idea sobre el warning/error?

Gracias por tu ayuda

por **danimera** » 2013-05-31 09:09 @423

O a mi manera usándolo como una base de datos... manejándolo como una tabla de una DB

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

  $dbh = DBI->connect ("dbi:CSV:") or
        die "Cannot connect: $DBI::errstr";
 
 
    my $sth = $dbh->prepare ("select * from fichero.csv");
    $sth->execute;
    while (my @fila = $sth->fetchrow_array) {
        print "id: $fila [0], name: $fila [1]\n";
        }
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Ya recorriendolo así, puedo hacer updates

# Updates

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

  my $sth = $dbh->prepare ("UPDATE fichero.csv SET colunma = ? WHERE colunma= ?");
    $sth->execute ("Nombre_Sede", "red_SEde");
    $sth->finish
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2013-05-31 09:58 @457

Sí, el error era precisamente ese: que habíamos declarado la variable $ARCHIVO dos veces (con my()).

He reeditado el mensaje, lo he probado, y ya funciona:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

> perl code_34828.pl

> cat archivo.txt

2013-05-31 09:00:15 Sede_Cantabria

2013-05-31 09:00:18 Sede_Leon

2013-05-31 09:00:21 Sede_CantabriaColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

por **bvayap** » 2013-06-03 06:31 @313

Muchas gracias a ambos.

He probado la solución de explorer y funciona bien. Tengo pendiente probar la de Danimera. Tenía un pequeño problema ya que mi fichero .csv terminaba en ".", pero ya está solucionado. Ahora el problema que tengo es de rendimiento, pero bueno, voy a ver cómo puedo solucionarlo.

Gracias por la ayuda.

por **explorer** » 2013-06-03 07:22 @348

Entonces lo haría de otra manera: primero leería todo el archivo CSV y lo guardaría en un hash, y luego recorrería el archivo a cambiar, línea a línea.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;                                     # estilo estricto
use warnings;                                   # activar advertencias
use diagnostics;                                # diagnósticos de fallos
use autodie;                                    # «Es mejor morir que regresar con deshonor» --proverbio Klingon
 
### Variables
my %redes;                                      # almacén con los cambios
 
### Lectura del archivo CSV
open my $CSV, '<', 'archivo.csv';
 
while (<$CSV>) {                                # para cada línea, hasta fin de archivo
    chomp;                                      # quitamos caracteres fin de línea
    my($nombre, $red) = split /[;]/;            # partimos la línea, extraemos columnas
 
    $redes{$red} = $nombre;
}
 
close $CSV;
 
### Procesado
open my $ARCHIVO, '<', 'archivo.txt';           # Lectura del archivo a tratar
open my $SALIDA,  '>', 'archivo.new.txt';       # Escritura del archivo resultado
 
while (my $linea = <$ARCHIVO>) {                # para cada línea del $ARCHIVO
    chomp $linea;
    my $IP = substr $linea, 20;                 # extraemos la IP
 
    if (exists $redes{$IP}) {                   # si tenemos que cambiarla
        substr $linea, 20, length($IP), $redes{$IP};    # la cambiamos
    }
 
    print $SALIDA "$linea\n";                   # guardamos el resultado
}
 
close   $ARCHIVO;
close   $SALIDA;
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

por **bvayap** » 2013-06-03 10:13 @467

Gracias por la respuesta, explorer.

No me hace los cambios y creo que es por lo siguiente:

Por lo que entiendo, en la línea se define $IP como todo lo que lea en $linea a partir del carácter 20, ¿no?. El problema es que archivo.txt tiene el formato:

2013-05-31 09:00:15 172.16.18.5 "texto variable"
...

He probado a intentar sacar la length($red), que es la que interesaría leer en la línea 28, pero me da un error de definición de variable global. Así que he probado a comentar la línea use strict (que seguro que es una burrada, pero ya comenté que soy nuevo ;-)

y ahora sí me reemplaza las IP por sedes, pero se queda con la longitud de la última red leída de archivo.csv... Te adjunto el código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;                                     # estilo estricto
use warnings;                                   # activar advertencias
use diagnostics;                                # diagnósticos de fallos
use autodie;                                    # «Es mejor morir que regresar con deshonor» --proverbio Klingon
 
### Variables
my %redes;                                      # almacén co los cambios
my %longitud;
 
### Lectura del archivo CSV
open my $CSV, '<', 'archivo.csv';
 
while (<$CSV>) {                                # para cada línea, hasta fin de archivo
    chomp;                                      # quitamos caracteres fin de línea
    my($nombre, $red) = split /[;]/;            # partimos la línea, extraemos columnas
 
    $redes{$red} = $nombre;
        $longitud = length($red);
        print "$longitud\n";
}
 
close $CSV;
 
### Procesado
open my $ARCHIVO, '<', 'archivo.txt';           # Lectura del archivo a tratar
open my $SALIDA,  '>', 'archivo.new.txt';       # Escritura del archivo resultado
 
while (my $linea = <$ARCHIVO>) {                # para cada línea del $ARCHIVO
    chomp $linea;
    my $IP = substr ($linea, 20, $longitud);                 # extraemos la IP
        print "$IP\n";
 
    if (exists $redes{$IP}) {                   # si tenemos que cambiarla
        substr $linea, 20, length($IP), $redes{$IP};    # la cambiamos
    }
 
    print $SALIDA "$linea\n";                   # guardamos el resultado
}
 
close   $ARCHIVO;
close   $SALIDA;
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2013-06-03 10:29 @478

Se puede adoptar otra estrategia: como el archivo consiste en cuatro campos separados por espacios en blanco, podemos usar split() para extraerlos, y join() para recrear los registros:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;                                     # estilo estricto
use warnings;                                   # activar advertencias
use diagnostics;                                # diagnósticos de fallos
use autodie;                                    # «Es mejor morir que regresar con deshonor» --proverbio Klingon
 
### Variables
my %redes;                                      # almacén con los cambios
 
### Lectura del archivo CSV
open my $CSV, '<', 'archivo.csv';
 
while (<$CSV>) {                                # para cada línea, hasta fin de archivo
    chomp;                                      # quitamos caracteres fin de línea
    my($nombre, $red) = split /[;]/;            # partimos la línea, extraemos columnas
 
    $redes{$red} = $nombre;
}
 
close $CSV;
 
### Procesado
open my $ARCHIVO, '<', 'archivo.txt';           # Lectura del archivo a tratar
open my $SALIDA,  '>', 'archivo.new.txt';       # Escritura del archivo resultado
 
while (my $linea = <$ARCHIVO>) {                # para cada línea del $ARCHIVO
    my(@campos) = split " ", $linea, 4;         # partir en cuatro cachos
    my $IP = $campos[2];
 
    if (exists $redes{$IP}) {                   # si tenemos que cambiarla
        $campos[2] = $redes{$IP};               # la cambiamos
    }
 
    print $SALIDA join " ", @campos;            # guardamos el resultado
}
 
close   $ARCHIVO;
close   $SALIDA;
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

por **bvayap** » 2013-06-03 10:55 @497

Muchas gracias, explorer. Funciona de maravilla y con un rendimiento asombroso comparado con lo que yo había hecho :shock:

Voy a intentar ahora buscar una cadena en el cuarto campo y, si existe, reemplazar todo el campo, además de intentar ignorar las 6 primeras líneas del archivo.txt, ya que son una cabecera que debo ignorar.

Si me surge alguna duda, vuelvo al ataque ;-)

Gracias por vuestra ayuda.

Foro - Perl en Español

Leer y reemplazar cadena de texto

Leer y reemplazar cadena de texto

Publicidad

Re: Leer y reemplazar cadena de texto

Re: Leer y reemplazar cadena de texto

Re: Leer y reemplazar cadena de texto

Re: Leer y reemplazar cadena de texto

Re: Leer y reemplazar cadena de texto

Re: Leer y reemplazar cadena de texto

Re: Leer y reemplazar cadena de texto

Re: Leer y reemplazar cadena de texto

Re: Leer y reemplazar cadena de texto

¿Quién está conectado?