Foro - Perl en Español

por **primitivo** » 2013-06-16 13:31 @605

¡Hola amigos! Estoy de vuelta, perdón por la demora.

Resulta que ando trabajando en un contador sencillo para un website que llevo, pero el "querido" contador, me tira siempre en Error 500.

Por acá el código.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl #Gracias por el arreglo explorer ^^
#Contador de visitas
 
&escribe_visita;
sub escribe_visita
{
    my $user_agente = $ENV{HTTP_USER_AGENT};
    my $remote_address = $ENV{REMOTE_ADDR};
    my $file = open(VS,"visitas/visitas.txt");
    if (!$file);
    {
           print "Content-type:text/html\n\n";
           print "<html>";
           print "<head>";
           print "<body>";
           print "<p>No es posible obtener la lectura!</p>";
           print "</body>";
           print "</head>";
           print "</html>";
    } else {
        my $visita;
        print $file "Navegador: $user_agente = IP: $remote_address\n";
        @contador = <$file>;
        foreach $contar (@contador)
        {
    
             $visita++;
    
        }
        close(VS);
        print "Content-type:text/html\n\n";
        print "<html>";
        print "<head>";
        print "<link rel=\"stylesheet\" type=\"text/css\" href=\"count.css\"/>";
        print "<title>Nuestras visitas</title>";
        print "</head>";
        print "<body>";
        print "<table class=\"count\">";
        print "<tbody>";
        print "<tr>";
        print "<td>";
        print "<span style=\"color:#000;\">Visitas: $visita </span>";
        print "</td>";
        print "</tr>";
        print "</tbody>";
        print "</table>";
        print "</body>";
        print "</html>";
    }
}
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

¿Cuál sería el error?

El error 500 puede salir por muchas razones.

Lo que sí veo mal es que $file adopte el valor de retorno de open(). open() no devuelve el gestor de archivo, sino un valor de verdad: verdadero si ha conseguido abrir el archivo, falso si no.

Por eso la línea 22 fallará: estás intentando usarlo como gestor. El gestor es VS .

Debes mirar el archivo error.log para saber por qué ha fallado. Ahí vendrá un mensaje más claro. O como danimera, usar 'use CGI::Carp qw(fatalsToBrowser);' .

Esta es otra versión, más moderna.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
# Registro de visitas
# Joaquín Ferrero. 20130617.
 
use autodie;
use CGI       qw(:standard);
use CGI::Carp qw(fatalsToBrowser);
 
## Configuración ##
my $archivo_contador = "/tmp/visitas.txt";
## Fin configuración ##
 
 
my $visitas        = 0;
my $user_agente    = $ENV{'HTTP_USER_AGENT'};
my $remote_address = $ENV{'REMOTE_ADDR'    };
 
 
open my $ARCHIVO, '+<', $archivo_contador;              # abrimos en modo lectura/escritura
while (<$ARCHIVO>) {
    $visitas++;
}
print   $ARCHIVO "Navegador: $user_agente = IP: $remote_address\n";
close   $ARCHIVO;
 
 
print
    header,
    start_html(
        -title => 'Nuestras visitas',
        -head  => Link({-rel => 'stylesheet', -href => 'count.css'}),
    ),
    table({-class => 'count'}, Tr(td(span({-style=>'color:#000;'}, "Visitas: $visitas")))),
    end_html,
    ;
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **primitivo** » 2013-06-17 19:45 @864

Vale, lo ensayaré.

Muchas gracias, explorer, como siempre.

Un pregunta ¿Dónde puedo conseguir FAQ sobre PSGI?

Foro - Perl en Español

Contador CGI

Contador CGI

Publicidad

Re: Contador CGI

Re: Contador CGI

Re: Contador CGI

Re: Contador CGI

Re: Contador CGI

Re: Contador CGI

¿Quién está conectado?