Foro - Perl en Español

por **Skull118** » 2013-08-07 17:03 @752

Buenas tardes, maestros de Perl en español, tengo el siguiente inconveniente:

Tengo un CSV, que obviamente va separado por comas, pero a veces en la cadena (vista como texto), hay algo como esto

aquí va algo,aquí va algo más,"ESTO ES UNA CADENA, EN LA CUAL, NECESITO, ELIMINAR, TODAS, LAS COMAS QUE APARECEN, DENTRO DE LAS COMILLAS", aquí va algo más, y aquí algo más

Lo anterior es por poner un ejemplo.

He intentado varias combinaciones de expresiones regulares para reemplazar SOLO LAS COMAS que están dentro de las comillas, pero no logro reemplazarlas con un espacio o bien eliminarlas, para que la cadena termine así:

aquí va algo,aquí va algo más,"ESTO ES UNA CADENA EN LA CUAL NECESITO ELIMINAR TODAS LAS COMAS QUE APARECEN DENTRO DE LAS COMILLAS", aquí va algo más, y aquí algo más

De antemano, muchas gracias.

#!/usr/bin/perl
use v5.10;
 
my $linea = q(aquí va algo,"OTRA",aquí va algo más,"ESTO ES UNA CADENA, EN LA CUAL, NECESITO, ELIMINAR, TODAS, LAS COMAS QUE APARECEN, DENTRO DE LAS COMILLAS", aquí va algo más, y aquí algo más);
 
1 while                         # un bucle que no hace nada mientras se puede hacer alguna sustitución
    $linea =~ s/
                (?:^|,)         # principio de línea o de campo
                "               # seguido por unas comillas dobles
                [^"]*?          # seguidas por un número indeterminado de caracteres que no contienen unas comillas
                \K              # vale, pues si hemos encontrado eso, no nos interesa cambiarlo
                ,               # esto es lo único que cambiaremos: una coma
                (?=             # siempre y cuando esa coma esté seguida por
                    .*?         # un número indeterminado de caracteres que no contienen comillas dobles
                    "           # seguidos, inmediatamente por unas comillas dobles
                )
                //x;            # la coma encontrada es cambiada por nada (es eliminada)
 
say $linea;
__END__
aquí va algo,"OTRA",aquí va algo más,"ESTO ES UNA CADENA EN LA CUAL NECESITO ELIMINAR TODAS LAS COMAS QUE APARECEN DENTRO DE LAS COMILLAS", aquí va algo más, y aquí algo más
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

La línea 6 se puede compactar en:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

1 while $linea =~ s/(?:^|,)"[^"]*?\K,(?=.*?")//;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Aunque... lo más cómodo sería usar Text::CSV, sacar el campo, filtrarlo con un simple s/,//g, y recrear el archivo.

por **Skull118** » 2013-08-08 11:59 @541

Muchas gracia,s explorer, definitivamente el mejor en el tema. La expresión que realicé funciona, pero parcialmente, no es tan exacta como la tuya :shock:

Solamente otra duda, maestro: ¿dónde puedo encontrar un tutorial para poder programar expresiones regulares, a tal nivel? Lo que he aprendido, lo he buscado y entendido a grandes rasgos. Si tuvieras una página donde pudiera aprenderlo, te lo agradecería mucho.

Todo mi respeto, y agradecimiento, un abrazo desde Guatemala.

por **explorer** » 2013-08-08 12:48 @575

Bueno, en Internet hay muchos recursos para aprender expresiones regulares, solo es cuestión de buscarlas, pero te cuento cómo aprendí yo: leyendo el libro "Mastering Regular Expressions", de O'Reilly. Bueno, el caso es que es un libro de alto nivel, casi matemático, pues enseña cómo funcionan las expresiones regulares desde dentro. Y las particularidades de sus implementaciones en cada lenguaje informático.

Perl sobresale en todos los aspectos, pues tiene el mejor soporte de expresiones regulares.

Tampoco tienes que ir muy lejos... en tu propio ordenador, en la documentación de Perl, hay varios documentos al respecto:

perldoc perlrequick - tutorial rápido de expresiones regulares (traduciéndose al español)
perldoc perlretut - tutorial de expresiones regulares
perldoc perlre - manual de expresiones regulares (traducido al español)
perldoc perlrebackslash - Secuencias de escape en expresiones regulares
perldoc perlrecharclass - Clases de caracteres en expresiones regulares
perldoc perlreref - Referencia rápida de expresiones regulares
perldoc perlreapi - Interfaz de complementos: expresiones regulares
perldoc perlreguts - Componentes del motor de expresiones regulares

Los dos últimos no te interesan, salvo que tengas un interés real en saber cómo funciona la implementación de exp. reg. dentro de perl. Los que sí te interesan son los tutoriales y manuales.

En la sección de Tutoriales de esta web, hay un par de ellos. En la Wikipedia, en la página de Expresiones regulares, también hay una introducción y más enlaces a más tutoriales. La versión inglesa de esa página tiene mucha más información y más enlaces.

Para resolver tu caso, solo he tenido que consultar perlre, pero claro, como todo manual, es muy pesado de leer.

por **explorer** » 2013-08-08 13:28 @603

Hola, he encontrado una solución mejor.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$linea =~ s/(?:^|,)"\K(.*?)(?=")/(my $x = $1) =~ tr{,}{}d; $x/ge;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

El funcionamiento es más óptimo, ya que no se ejecuta el bucle while().

El funcionamiento es, además, más claro.

se trata de una exp. reg. que se aplica de forma global (/g) a la variable $linea
el patrón intenta localizar unas comillas dobles, tanto al principio de la variable o justo después de una ','
si es así, obvia lo encontrado hasta el momento (\K) y sigue buscando concordancias
capturamos todo lo que encontremos ((.*?))
hasta justo antes de la siguiente comilla, que no es capturada ((?="))
el resultado es la captura en $1 de sólo lo que está entrecomillado doble
la parte de sustitución es un código ejecutable (/e) en Perl
el código, lo que hace es hacer una copia de $1 en $x, y realizar una transliteración (tr{}{})
la transliteración busca comas, y las borra (/d)
y termina devolviendo $x con las comas ya filtradas, que se incorpora como cambio a $linea

Foro - Perl en Español

Reemplazar solo un carácter entre comillas

Reemplazar solo un carácter entre comillas

Publicidad

Re: Reemplazar solo un carácter entre comillas

Re: Reemplazar solo un carácter entre comillas

Re: Reemplazar solo un carácter entre comillas

Re: Reemplazar solo un carácter entre comillas

Re: Reemplazar solo un carácter entre comillas

¿Quién está conectado?