Foro - Perl en Español

por **Abraham** » 2013-08-27 12:55 @580

Tengo una página con vídeo en HTML5:

Sintáxis: [ Descargar ] [ Ocultar ]

Using html4strict Syntax Highlighting

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<title>Documento sin título</title>
</head>
<body>
<video controls src="http://192.168.1.68/video.mp4">Tu navegador no soporta HTML5 </video>
</body>
</html>
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

como ven es muy simple pero funciona. El problema está cuando cambia la URL del vídeo, de src="http://192.168.1.68/video.mp4" por un cgi src="http://192.168.1.68/descargas/d.pl", que usaba para servir imágenes, vídeos Flash, MP3, y distintas descargas. PERO parece no funciona con vídeo MP4.

EL d.pl es básicamente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use CGI qw(:standard);
use CGI::Carp qw(fatalsToBrowser);
use LWP::Simple;
use URI::Escape;
use LWP::UserAgent;
 
$archivo = "video.mp4";
$peso    = -s $archivo;
 
print "Accept-Ranges:bytes\r\n";
print "content-Length: 3621948\r\n";
print "Content-Range:bytes 2331-3624278/3624279\r\n";
print "Content-type: video/mp4\r\n";
print "Last-Modified:Fri, 23 Aug 2013 16:34:09 GMT\r\n";
print "ETag:\"2381da4-374d57-4e49ff9d138a7\"\r\n";
print "\r\n";
print "\r\n";
 
open IMAGE, "$archivo";
my ($buff);
while ( read IMAGE, $buff, 1024 ) {
    print $buff;
}
close IMAGE;
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Pero solo funciona los cinco primeros segundos del vídeo y todo pasa deprisa hasta los "4:20", el reproductor de HTML5 no detecta los 4:20, solo los 00:05...

Al parecer es la cabecera, ahí se muestra un intento de COPIA de la cabecera que manda el Apache cuando la URL del vídeo es directo.

Nuevamente, estoy perdido...

Prueba, y dinos qué tal.

Además (no lo sé), como Range está indicando que empezamos en el byte 2331 (no sé por qué) entonces necesitaremos un

seek IMAGE,2331,0;

antes de la lectura del archivo, para posicionarnos. ¿No es esto lo que quieres hacer?

Otra cosa... hay que indicar en la respuesta un código

HTTP/1.1 206 Partial content

Yo usaría la función header() del módulo CGI, ya que lo estás cargando.

(no probado)

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

print header(
-type           =>'video/mp4',
-status         =>'206 Partial content',
-Accept_Ranges  =>'bytes',
-Content_Length =>3621948,
-Content_Range  =>'bytes 2331-3624278/3624279',
-Last_Modified  =>'Fri, 23 Aug 2013 16:34:09 GMT',
-ETag           =>'2381da4-374d57-4e49ff9d138a7',
);Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **Abraham** » 2013-08-27 16:51 @744

Gracias por responder...

Aclarando que la cabecera presentada es un intento de copia de lo que entrega Apache cuando es una URL directa...
(Yo tampoco sé el porqué de las cabeceras).

Probando insertar los binmode no parece afectar en lo mas mínimo, tendiendo el mismo resultado.

Aquí va el código que funciona parcialmente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use CGI       qw(:standard);
use CGI::Carp qw(fatalsToBrowser);
use LWP::Simple;
use URI::Escape;
use LWP::UserAgent;
 
        $archivo = "hola.mp4";
        $peso    = -s $archivo;
 
        print "content-Length: ".$peso."\r\n";
        print "Content-type: video/mp4\r\n";
        print "\r\n";
 
        open IMAGE, "$archivo";
                my ($buff);
                while ( read IMAGE, $buff, 1024 ) {
                        print $buff;
                }
        close IMAGE;
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Aquí con las modificaciones:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use CGI       qw(:standard);
use CGI::Carp qw(fatalsToBrowser);
use LWP::Simple;
use URI::Escape;
use LWP::UserAgent;
 
        $archivo = "hola.mp4";
        $peso    = -s $archivo;
 
        print header(
     -type           => 'video/mp4',
     -Content_Length => $peso ,
    );
 
        open IMAGE, "$archivo";
                binmode IMAGE;
                binmode STDOUT;
                my ($buff);
                while ( read IMAGE, $buff, 1024 ) {
                        print $buff;
                }
        close IMAGE;
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Me he dado cuenta que la etiqueta <VIDEO> de HTML5 hace la petición del vídeo 3 veces. En la primera solo descarga 13 bytes; en la segunda 3.4 MB; y la tercera 2 MB (al parecer es por el PRELOAD del vídeo) y este tercero llega a descargarse por completo 3.5 MB y es de este tercero que COPIÉ las cabeceras.

Unas imágenes de Chrome, usando la URL DIRECTA del vídeo:
Imagen

se puede ver que la página cargó 3 veces el vídeo (no sé por qué es este comportamiento)
Imagen

y en esta imagen están las cabeceras copiadas.

Como podemos ver en las imágenes se carga por completo porque el tiempo se marca como 4:20 pero con CGI solo carga el vídeo dos veces pero aun cargando por completo el tiempo se marca como 00:05; en estos 5 segundos el vídeo va bien; luego pasando los 5 segundos el vídeo va sumamente corrido.

Aquí esta la imagen de la prueba:
Imagen

¡Y AHORA QUÉ PUEDE SER!

Mientras estaba redactando la respuesta, y como estaba mandando imágenes de Chrome hice la prueba en Firefox y todo FUNCIONA CORRECTAMENTE. ¿Qué puede estar mal en Chrome? Uso Chrome por la herramienta que se muestran en las imágenes, pero ahora descubro que Chrome es el causante de este dolor de cabeza... ¿Quién de los dos maneja adecuadamente la etiqueta <VIDEO> de HTML5?

por **Abraham** » 2013-08-27 20:44 @906

Al parecer el problema está en que el Chrome hace peticiones de rangos cuando lo ve "conveniente" y esto mi pequeño CGI no puede abastecerlo, no comprendo bien, pero pude satisfacer las 3 peticiones principales (obviamente con los datos sugeridos gracias a explorer), y ahora está funcionando al menos en la primera etapa, ya que si muevo el progreso del vídeo, el Chrome hace peticiones de rangos que falta satisfacer... Muestro mi intento de solución, espero mejorarlo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use CGI qw(:standard);
use CGI::Carp qw(fatalsToBrowser);
use LWP::Simple;
use URI::Escape;
use LWP::UserAgent;
 
$archivo = "hola.mp4";
$peso    = -s $archivo;
 
if ( $ENV{'HTTP_RANGE'} eq "" ) {
 
    print header(
        -type           => 'video/mp4',
        -Content_Length => $peso
    );
 
    open IMAGE, "$archivo";
    binmode IMAGE;
    binmode STDOUT;
    my ($buff);
 
    #read IMAGE, $buff,2000000;
    while ( read IMAGE, $buff, 211024 ) {
        print $buff;
    }
    close IMAGE;
}
else {
    if ( $ENV{'HTTP_RANGE'} =~ m/bytes=0-/i ) {
 
        print header(
            -type           => 'video/mp4',
            -Content_Length => $peso,
            -Accept_Ranges  => 'bytes',
            -Content_Range  => 'bytes 0-3624278/3624279'
        );
        open IMAGE, "$archivo";
        my ($buff);
        read IMAGE, $buff, 3624278;
 
        #while ( read IMAGE, $buff, 3624278 ) {
        print $buff;
 
        #}
        close IMAGE;
 
    }
    else {
        print header(
            -type           => 'video/mp4',
            -status         => '206 Partial content',
            -Content_Length => '3621948',
            -Accept_Ranges  => 'bytes',
            -Content_Range  => 'bytes 2331-3624278/3624279'
        );
        open IMAGE, "$archivo";
        my ($buff);
        seek IMAGE, 2331, 0;
        read IMAGE, $buff, 3624278;
 
        #while ( read IMAGE, $buff, 3624278 ) {
        print $buff;
 
        #}
        close IMAGE;
    }
}
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2013-08-28 04:24 @225

Efectivamente: el distinto comportamiento de los dos navegadores es por el controlador (driver) de vídeo que utilizan. En un caso, solicita varios rangos distintos (quizás para ver primero las cabeceras y luego hacer una prueba de búfer), y en otro caso, se lo baja entero.

El cgi, entonces, debe estar preparado para responder a las peticiones de Ranges:.

En este hilo sobre Ubuntu he encontrado una solución completa, que te puede servir de inspiración. Si hay algo del código que no entiendes, te lo aclaramos. Fíjate que el autor utiliza una cabecera llamada 'Content_disposition', lo cual me sorprende, pues parece que está retransmitiendo un archivo como si fuera un adjunto (como en el correo), por lo que, entiendo, el navegador debería estar mostrando la opción de grabar el archivo a disco.

En fin, cuestión de probar.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
#
# MythWeb Streaming/Download module
#
# @url       $URL: http://svn.mythtv.org/svn/trunk/mythplu ... eam_raw.pl $
# @date      $Date: 2010-05-31 20:52:27 +0100 (Mon, 31 May 2010) $
# @version   $Revision: 24917 $
# @author    $Author: kormoc $
#
 
$| = 1;
 
use HTTP::Date;
 
# File size
my $size = -s $filename;
 
# Zero bytes?
if ( $size < 1 ) {
    print header(), "$basename is an empty file.";
    exit;
}
 
# File type
my $type   = 'text/html';
my $suffix = '';
if ( $basename =~ /\.mpe?g2?$/ ) {
    $type   = 'video/mpeg';
    $suffix = '.mpg';
}
elsif ( $basename =~ /\.nuv$/ ) {
    $type   = 'video/nuppelvideo';
    $suffix = '.nuv';
}
elsif ( $basename =~ /\.avi$/ ) {
    $type   = 'video/mpeg';
    $suffix = '.avi';
}
elsif ( $basename =~ /\.mkv$/ ) {
    $type   = 'video/mpeg';
    $suffix = '.mkv';
}
else {
    print header(), "Unknown video type requested:  $basename\n";
    exit;
}
 
# Download filename
my $name = $basename;
if ( $name =~ /^\d+_\d+\.\w+$/ ) {
    if ( $title =~ /\w/ ) {
        $name = $title;
        if ( $subtitle =~ /\w/ ) {
            $name .= " - $subtitle";
        }
    }
    $name .= $suffix;
}
 
# Open the file for reading
unless ( sysopen DATA, $filename, O_RDONLY ) {
    print header(), "Can't read $basename:  $!";
    exit;
}
 
# Binmode, in case someone is running this from Windows.
binmode DATA;
 
my $start      = 0;
my $end        = $size;
my $total_size = $size;
my $read_size  = 1024;
my $mtime      = ( stat($filename) )[9];
 
# Handle cache hits/misses
if ( $ENV{'HTTP_IF_MODIFIED_SINCE'} ) {
    my $check_time = str2time( $ENV{'HTTP_IF_MODIFIED_SINCE'} );
    if ( $mtime <= $check_time ) {
        print header(
            -Content_type => $type,
            -status       => "304 Not Modified"
        );
        exit;
    }
}
 
# Requested a range?
if ( $ENV{'HTTP_RANGE'} ) {
 
    # Figure out the size of the requested chunk
    ( $start, $end ) = $ENV{'HTTP_RANGE'} =~ /bytes\W+(\d*)-(\d*)\W*$/;
    if ( $end < 1 || $end > $size ) {
        $end = $size;
    }
    $size = $end - $start + 1;
    if ( $read_size > $size ) {
        $read_size = $size;
    }
    print header(
        -status              => "206 Partial Content",
        -type                => $type,
        -Content_length      => $size,
        -Accept_Ranges       => 'bytes',
        -Content_Range       => "bytes $start-$end/$total_size",
        -Last_Modified       => time2str($mtime),
        -Content_disposition => " attachment; filename=\"$name\""
    );
}
else {
    print header(
        -type                => $type,
        -Content_length      => $size,
        -Accept_Ranges       => 'bytes',
        -Last_Modified       => time2str($mtime),
        -Content_disposition => " attachment; filename=\"$name.$suffix\""
    );
}
 
# Seek to the requested position
sysseek DATA, $start, 0;
 
# Print the content to the browser
my $buffer;
while ( sysread DATA, $buffer, $read_size ) {
    print $buffer;
    $size -= $read_size;
    if ( $size <= 0 ) {
        my $fileSize = -s $filename;
        my $filePos  = tell DATA;
        if ( ( $fileSize - $filePos ) > 0 ) {
            $size = $fileSize - $filePos;
        }
        else {
            last;
        }
    }
    if ( $size < $read_size ) {
        $read_size = $size;
    }
    if ( $read_size < 0 ) {
        $read_size = 0;
    }
}
close DATA;
 
1;
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

por **Abraham** » 2013-08-28 15:56 @705

El comportamiento del navegador Chrome y todos los que se basan en Chromium (creo que es así) lo considero un GRAN error, si bien en alguna parte del mundo el ANCHO de banda casi, casi, lo regalan, existe una gran mayoría que tienen limitado acceso al mismo, y por eso no puede ser que se cargue repetidas veces el mismo vídeo.

Sobre el código sugerido, aunque no entiendo algunas partes, entiendo lo que se quiere hacer, esto me servirá un poco más adelante, ya que considero importante adecuar la página html en primer lugar, cambiar la forma en que se va a pedir el vídeo, ya que no todos los vídeos los tengo en mi servidor, es más parecido a un Spider de YouTube con caché de vídeos y mientras descargo el vídeo pretendía servir el vídeo, y con esto de los rangos no puedo servir rangos de lo que no tengo.

Por el momento mi batalla es con HTML5, Ajax y jQuery.

Gracias, explorer, por el interés de siempre, estaré por aquí un poco más adelante.

por **explorer** » 2013-08-28 16:19 @722

Es que, precisamente, lo hacen así, para que el controlador de vídeo tenga información suficiente para calcular el ancho de banda disponible, y de ahí calcular cuántos segundos de búfer debe almacenar antes de comenzar la reproducción. Todo ello va encaminado para que el usuario no vea cortes. O vea los mínimos cortes.

En cuanto a rangos y demás, piensa en el ejemplo de Youtube, que permite crear enlaces a vídeos, en un determinado punto de la reproducción. Eso permite a los usuarios intercambiarse enlaces de vídeos apuntando al momento justo en que el gato hace su monería. :lol:

En el código que te he puesto, sí que está contemplado todos los casos: existir o no el archivo que nos piden, y ajustar el puntero de lectura según el rango solicitado. Si no pide rango, se manda todo, claro.

por **Abraham** » 2013-08-29 10:42 @487

Pero en el código, al no existir el archivo, solo manda un mensaje:

unless ( sysopen DATA, $filename, O_RDONLY ) {

print header(), "Can't read $basename: $!";

exit;

}

En esa parte el código debería ser capaz de buscar el vídeo en Youtube, empezar la descarga y al mismo tiempo servir la descarga parcial. ¡OJO!, que esto lo tengo solucionado pero con VÍDEOS de Flash y un reproductor Flash en el lado del cliente, pero esto del HTML5 y su vídeo me ha dado nuevos retos que pienso solucionarlo con Ajax interactuando con el servidor y controlando al reproductor del vídeo, todo internamente.

Foro - Perl en Español

Cómo servir vídeo MP4 para HTML5

Cómo servir vídeo MP4 para HTML5

Publicidad

Re: Cómo servir vídeo MP4 para HTML5

Re: Cómo servir vídeo MP4 para HTML5

Re: Cómo servir vídeo MP4 para HTML5

Re: Cómo servir vídeo MP4 para HTML5

Re: Cómo servir vídeo MP4 para HTML5

Re: Cómo servir vídeo MP4 para HTML5

Re: Cómo servir vídeo MP4 para HTML5

¿Quién está conectado?