Foro - Perl en Español

por **otronovato** » 2013-09-01 07:16 @344

SOLUCIONADO

He escrito una función con la intención de que a partir de una referencia a un hash con los trigramas como claves y su número de apariciones en una cadena como valores, y de una cadena de la que se ha calculado ese hash mediante otra función, me almacene en un hash los trigramas repetidos y los lugares de la cadena en que aparecen.

Pero no funciona. Ni a tiros. :roll:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub análisis_frec{
 
#Recibe una referencia a un hash que contiene las cadenas (digramas o trigramas)
#relacionadas con sus repeticiones, y una cadena con el mensaje cifrado.
#Retorna un hash que relaciona cada cadena, (digrama o trigrama), con
#la distancia en caracteres entre cada repetición.
    my %dist;
    my @dist_por_elemento;
    my %input = %{$_[0]}; #Dereferencio el hash recibido
 
    foreach(sort keys %input){
 
        #print "Clave ",        $_, " valor ", $input{$_}, "\n";
 
        if($input{$_} > 1){ #Dejamos sin procesar los elementos que no aparecen repetidos
 
            my $offset = 0; #Es el offset que pasaré a index()
            my $distancia;
 
            for(my $i = 0; $i < $input{$_}; $i++){ #Para cada una de las veces que aparece cada trigrama
 
                $distancia = index $_[1], $_, $offset;#$_[1] almacena la cadena con el mensaje
                #EDIT ¡Barbaridad! $dist_por_elemento[$i]= $distancia;
                push @dist_por_elemento, $distancia;
                #EDIT ¡Vergonzoso! $offset += 2; #¿No puedo usar length porque estoy trabajando con caracteres no ascii??
                $offset = $distancia + 2;
                #print "Longitud ", $offset, "\n";
            }
 
            #print "debug ",(split ',', @dist_por_elemento), "\n";
            $dist{$_} = [@dist_por_elemento]; #AQUÍ ESTABA EL PROBLEMA: tenía $dist{$_} = @dist_por_elemento;
            undef @dist_por_elemento;
 
        }
 
 
    }
 
    return \%dist;
 
}
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

EDITADO [Aparentemente calcula bien los desplazamientos, pero no los guarda en el array que deseo convertir en valor de cada clave del hash que retorna la función]. No era ese el problema.

Además tengo la duda de si con el módulo utf8::all funciona correctamente la función length(). Aquí me ha dado problemas, pero podrían haberse debido a la "creatividad" con que acometo el trabajo con hashes en estos momentos... :oops:

Un saludo.

EDITO[PS: He visto un montón de errores de lógica, y de aún sentido común, en el código que ya he editado. Aun con todo, no consigo ver por qué no funciona

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

push @dist_por_elemento, $distancia;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

] Solucionado.
PS: No hay como pensar. :oops:

Mete la línea

my @dist_por_elemento;

dentro del if(), y quita la línea del undef, porque ya no hará falta. El my() creará un nuevo array, en cada vuelta.

Cuando haces la asignación [ @dist_por_elemento ], estás guardando una referencia a una lista de caracteres, que son los que había en ese array, así que es correcto (es un hash de arrays).

Cuando funcione, pruébalo con este caso, con una cadena así: 'AAAAAAAACCCCCCCG'

Cuidado, porque hay truco. :mrgreen:

por **otronovato** » 2013-09-01 12:15 @552

¡Vaya día que llevo! ¡Tener problemas con Perl es una cosa, pero tenerlos con la lógica...! :lol:

Comprendido lo de la declaración de @dist_por_elemento. Como su alcance se limita al bloque en que ha sido declarada no necesito hacerla global a la función ni reiniciarla explícitamente.

Cuando funcione, pruébalo con este caso, con una cadena así: 'AAAAAAAACCCCCCCG'

Creo que ya lo tengo...

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$offset = $distancia + 3;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Y la salida ahora queda:

Sintáxis: [ Descargar ] [ Ocultar ]

xxxx@xxxxxxx:~/Escritorio/scripts_criptografía$ ./frec_calc.pl
Introduce la cadena a considerar
AAAAAAAACCCCCCCG
Hay 5 tríos de caracteres, que son AAA,AAC,ACC,CCC,CCG,
La frecuencia de cada trigrama es:
Trigrama AAA ------>2
Trigrama AAC ------>1
Trigrama ACC ------>1
Trigrama CCC ------>2
Trigrama CCG ------>1
La DISTANCIA para AAA es 0
Empujo 0 dentro de @dist_por_elemento
La DISTANCIA para AAA es 3
Empujo 3 dentro de @dist_por_elemento
OFFSET----->0
OFFSET----->3
La DISTANCIA para CCC es 8
Empujo 8 dentro de @dist_por_elemento
La DISTANCIA para CCC es 11
Empujo 11 dentro de @dist_por_elemento
OFFSET----->8
OFFSET----->11
El trigrama AAA se encuentra en los desplazamientos 0,3,
El trigrama CCC se encuentra en los desplazamientos 8,11,

¿Trampas? ¡Para mí una simple raya de lápiz en el suelo ya es una trampa! :lol:

Gracias, explorer.

por **explorer** » 2013-09-01 12:50 @576

¿Estás completamente seguro de que en la cadena 'AAAAAAAACCCCCCCG' solo hay 2 trigramas 'AAA'? Yo veo más... Quizás, seis.

por **otronovato** » 2013-09-01 13:06 @588

¡Miér...coles! :roll:

Bueno... Por lo menos el programa falla porque no tengo claro lo que pretendía hacer, no por estar mal programado...
Vuelta a la casilla de salida, o casi.
¡Gracias!

por **otronovato** » 2013-09-01 17:19 @763

Bueno... La función que hace el recuento no he tenido que tocarla. En cambio, la que calcula la frecuencia la he tenido que rehacer de arriba a abajo. De ser una cosa sencilla y limpia tal que así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub frecuencia{
#Recibe una referencia a un array de cadenas de caracteres sin repetir y una cadena con
#el mensaje. Devuelve una referencia a un hash con las frecuencias.
    my %frec; #Estructura a retornar
    %frec = map{$_,0}@{$_[0]};#Iniciamos el hash con los valores a distribuir
    foreach(keys %frec){
        my @control;
        @control=$_[1] =~m/$_/g;
        $frec{$_}=@control;
    }
    return \%frec;
}
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

A este monstruo de tenebroso aspecto:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub frecuencia{
#Recibe una referencia a un array de cadenas de caracteres sin repetir y una cadena con                                                                                                                           
#el mensaje. Devuelve una referencia a un hash con las frecuencias.                                                                                                                                               
#Esta misma función nos puede dar las posiciones, pero para esa tarea he                                                                                                                                          
#desarrollado otra subrutina. En resumidas cuentas, que estoy hoy perezoso para cambios                                                                                                                                                                                    
    my %frec; #Estructura a retornar                                                                                                                                                                              
    %frec = map{$_,0}@{$_[0]};#Iniciamos el hash con los valores a distribuir                                                                                                                                     
    foreach(sort keys %frec){
        my $pos_ant = -1;#inicio al valor de index() "no encontrado"                                                                                                                                              
        my $offset = 0;
        my @posiciones;
        for(my $ind = 0; $ind < length $_[1]; $ind++){
            my $pos = index $_[1], $_, $ind;                                                                                                                  
            if(($pos >= 0) && ($pos_ant != $pos)){
                push @posiciones, $pos;
            }
            $pos_ant = $pos;
        }
        $frec{$_} = scalar @posiciones; #En contexto escalar me da la longitud del array control                                                                                                                  
        undef @posiciones;
    }
    return \%frec;
}
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

El resultado, ahora:

xxxxx@xxxxx:~/Escritorio/scripts_criptografía$ ./frec_calc.pl
Introduce la cadena a considerar
AAAAAAAACCCCCCCG
Hay 5 tríos de caracteres, que son AAA,AAC,ACC,CCC,CCG,
La frecuencia de cada trigrama es:
Trigrama AAA ------>6
Trigrama AAC ------>1
Trigrama ACC ------>1
Trigrama CCC ------>5
Trigrama CCG ------>1
El trigrama AAA se encuentra en los desplazamientos 0,1,2,3,4,5,
El trigrama CCC se encuentra en los desplazamientos 8,9,10,11,12,

¿No habría una forma de hacer lo mismo mediante el operador match, como había hecho en la versión antigua? ¿Ningún modificador mágico?

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

@control=$_[1] =~m/$_/g;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

¡Ayyyy, qué cabeza!

por **explorer** » 2013-09-01 18:57 @831

Claro que se puede hacer con el operador de coincidencia.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use v5.16;
use utf8::all;                  # Turn on UTF-8. All of it.
 
my $cadena = 'AAAAAAAACCCCCCCG';
my $trío   = 'AAA';
my $veces;
 
while ( $cadena =~ /$trío/g) {
    $veces++;
 
    # pos() devuelve la posición SIGUIENTE a donde se encontró el patrón
    # por eso restamos 3, para saber la posición real
    say "Encontrado en ", pos($cadena) - 3;
 
    # reposicionamos el puntero, para que busque en el carácter SIGUIENTE al primero,
    # no queremos que busque desde el final del patrón anterior
    pos($cadena) = pos($cadena) - 2;
}
 
say "Encontrado $veces veces";
 
__END__
Encontrado en 0
Encontrado en 1
Encontrado en 2
Encontrado en 3
Encontrado en 4
Encontrado en 5
Encontrado 6 veces
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

De hecho, esto mismo se hace para el caso de usar index(): modificas el $offset para indicar a partir de dónde quieres reiniciar la búsqueda.

por **otronovato** » 2013-09-02 07:04 @336

"pos" directly accesses the location used by the regexp engine to store the offset, so assigning to "pos" will change that offset

Entiendo que es una especie de función C fseek() pero para el motor de expresiones regulares y que se puede utilizar de manera similar.

De todos modos esta forma de trabajar precisaría de otro bucle para pasar las cadenas de búsqueda, que además habría que determinar en una función previa, por lo que parece, a simple vista, una mala opción. ¿Correcto? (A no ser, claro, que lo que tuviera que buscar fueran expresiones regulares predeterminadas...)

PS: estaba pensando en la manera de detectar bucles que usó Turing para romper Enigma: http://fr.wikipedia.org/wiki/Cryptanalyse_d'Enigma. ¿Cómo de grandes pueden ser las expresiones regulares?

Un saludo

por **explorer** » 2013-09-02 11:20 @514

otronovato escribiste:¿Cómo de grandes pueden ser las expresiones regulares?

El límite es la memoria RAM.

Por ejemplo, en el libro "Mastering Regular Expressions" (séptima edición, diciembre 1998, página 316), aparece una monstruosa exp. reg. de 6598 bytes de longitud, para verificar si una dirección de correo electrónico está correctamente escrita, o no.

:lol:

Foro - Perl en Español

Guardando arrays en un hash (SOLUCIONADO)

Guardando arrays en un hash (SOLUCIONADO)

Publicidad

Re: Guardando arrays en un hash (SOLUCIONADO)

Re: Guardando arrays en un hash (SOLUCIONADO)

Re: Guardando arrays en un hash (SOLUCIONADO)

Re: Guardando arrays en un hash (SOLUCIONADO)

Re: Guardando arrays en un hash (SOLUCIONADO)

Re: Guardando arrays en un hash (SOLUCIONADO)

Re: Guardando arrays en un hash (SOLUCIONADO)

Re: Guardando arrays en un hash (SOLUCIONADO)

¿Quién está conectado?