Foro - Perl en Español

por **pablgonz** » 2013-12-04 12:25 @559

Hola a todos, estoy tratando de renombrar algunos ficheros que tengo dentro un directorio, los ficheros son de la siguiente forma:

test-fig-0.pdf,test-fig-1.pdf,test-fig-2.pdf,test-fig-3.pdf,test-fig-4.pdf

y deseo dejarlos así:

test-fig-1.pdf,test-fig-2.pdf,test-fig-3.pdf,test-fig-4.pdf,test-fig-5.pdf

Estoy intentando usar este script:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $dir_consulta = "$tempDir/$imageDir";
my $fichero = '';
my $resultado = '';
my $renNo = 1;
if(opendir(DIRECTORIO,$dir_consulta))
{
  #Leemos el listado de fichero que lo componen
  foreach (readdir DIRECTORIO)
  {
    $fichero = $_;
    #Seleccionamos los ficheros
    if ($fichero =~ /$name-fig-\d+\.pdf/)
    { # quitamos desde la derecha 5 caracteres 0;.;p;d;f, escapando el punto 
      my $nuevo_nombre = substr($fichero,0,-5) . "$renNo\.pdf";
      $resultado = rename("$dir_consulta/$fichero","$dir_consulta/$nuevo_nombre");
      print "Renombrando $fichero a $nuevo_nombre: $resultado : $!\n";
      $renNo = $renNo+1;
    }
  }
  print "FIN\n";
}
else
{
  print "no se abre ".$dir_consulta;
}
closedir DIRECTORIO;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

pero, no me funciona... es más: no renombra en el orden que deseo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using bash Syntax Highlighting

Renombrando test-fig-1.pdf a test-fig-1.pdf: 1 : Función ioctl no apropiada para el dispositivo
Renombrando test-fig-0.pdf a test-fig-2.pdf: 1 : Función ioctl no apropiada para el dispositivo
Renombrando test-fig-2.pdf a test-fig-3.pdf: 1 : Función ioctl no apropiada para el dispositivo
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

¿Cómo ordeno los archivos del directorio para hacer el cambio en la numeración?
Saludos
Pablo

Al parecer, entiendo que lo que quieres es sumar una unida al nombre de los ficheros... Pues yo lo haría de la siguiente forma:

Extraería el número con una expresión regular y le restaría una unidad y obviamente los copiaría a otro directorio no al mismo, dentro de tu ciclo foreach haría algo como:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$fichero =~ /(\d+)/;
$numero_nuevo = $1 + 1; 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

con este nuevo número, ya no importa el orden, o reemplazo el número en el nombre y copio a otro directorio, o como quieras, creo que lo importantes es sumar la unidad.

por **explorer** » 2013-12-04 15:04 @670

El truco está en renombrar desde el último archivo al primero. Pero, entonces, primero hay que averiguar cuál es el último, y luego hacer el renombrado. Ejemplo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use feature 'say';
 
my $i = 0;
 
$i++ while -f "test-fig-$i.pdf";                                # averiguar cuál es el último archivo
 
$i--;                                                           # índice del último
 
for my $i (reverse 0 .. $i ) {                                  # hacemos un bucle al revés
 
    my $siguiente = $i + 1;                                     # apuntamos al siguiente
 
    say "renombrando test-fig-$i.pdf a test-fig-$siguiente.pdf";
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

sale:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

renombrando test-fig-4.pdf a test-fig-5.pdf

renombrando test-fig-3.pdf a test-fig-4.pdf

renombrando test-fig-2.pdf a test-fig-3.pdf

renombrando test-fig-1.pdf a test-fig-2.pdf

renombrando test-fig-0.pdf a test-fig-1.pdfColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

por **pablgonz** » 2013-12-04 16:21 @723

Genial, renombrar de forma inversa, no se me hubiese ocurrido jamás, estaba intentando con int($2)+1, pero, solo fueron palos de ciego, al final lo deje así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $i = 0;
 
$i++ while -f "$tempDir/$imageDir/$name-fig-$i.pdf";            # averiguar cuál es el último archivo
 
$i--;                                                           # índice del último
 
for my $i (reverse 0 .. $i ) {                                  # hacemos un bucle al revés
 
    my $siguiente = $i + 1;                                     # apuntamos al siguiente
 
    rename("$tempDir/$imageDir/$name-fig-$i.pdf","$tempDir/$imageDir/$name-fig-$siguiente.pdf");
 
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Noté que esta vez, no está $i entre {...}, el otro día me percaté (en otra solución respecto a borrar un archivo) que usabas {$i} para hacerlo más restrictivo (supongo). ¡Aaah!, ¿y si los ficheros de entrada son de la misma forma, pero .jpg o .png? ¿repito la rutina? ¿O puedo generalizarla?

Saludos.

Edito: Si la carpeta images/ ya contiene archivos test-fig-1.pdf, es decir, corro el script dos veces, éste creará copias y copias siguiendo el correlativo 1, 2, 3, ..., n.

por **pablgonz** » 2013-12-05 08:01 @375

Me respondo solo...no se si es la mejor forma, pero, me funciona, primero elimino todos los pdf del directorio (si es que existen) y luego creo los pdf y los vuelvo a enumerar, de esta manera, si corro el script más de una vez, no me creara archivos extra, quedo así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $dir = "$tempDir/$imageDir" ;
 
# Abro y leo el directorio donde están las imágenes
 
opendir (DIR, "$dir/");
my @FILES = grep(/.pdf/,readdir(DIR));
closedir (DIR);
 
# Elimino los PDF si es que existen
 
foreach my $FILES (@FILES) {
   if (-e "$dir/$FILES") {
      unlink("$dir/$FILES");
   }
}
# Los creo nuevamente (útil, estoy modificando el archivo de entrada)
system("convert -density $DPI $tempDir/$name-fig.pdf $imageDir/$name-fig-%d.pdf");
 
# Los enumero de nuevo
 
my $i = 0;
 
$i++ while -f "$tempDir/$imageDir/$name-fig-$i.pdf";            # averiguar cuál es el último archivo
 
$i--;                                                           # índice del último
 
for my $i (reverse 0 .. $i ) {                                  # hacemos un bucle al revés
 
    my $siguiente = $i + 1;                                     # apuntamos al siguiente
 
rename("$tempDir/$imageDir/$name-fig-$i.pdf","$tempDir/$imageDir/$name-fig-$siguiente.pdf");
 
                                }
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Creo que greep está de sobra y ¿lo puedo hacer más restrictivo al momento de eliminar los pdf del directorio? así como esta elimina TODOS los pdf y solo deseo que elimine $name-fig-*.pdf.

por **explorer** » 2013-12-05 08:41 @403

Volver a crear los documentos es muy ineficiente. Para evitar que te los renumere dos veces, lo que puedes hacer es comprobar primero si existe el archivo con índice 0. Quedaría así (no probado):

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $dir = "$tempDir/$imageDir";
 
# Miro a ver si los archivos han sido creados
my @FILES = <$dir/*.pdf>;
 
if (not @FILES) {                                                   # si no hay archivos...
    # Los creo nuevamente (útil, estoy modificando el archivo de entrada)
    system("convert -density $DPI $tempDir/$name-fig.pdf $imageDir/$name-fig-%d.pdf");
}
 
# Los enumero de nuevo
my $i = 0;
 
while (1) {                                                     # mientras no encontremos el último
    last if not -f "$tempDir/$imageDir/$name-fig-$i.pdf";       # salimos si no existe ese archivo
 
    $i++;                                                       # pasamos al siguiente
}
 
for my $i (reverse 0 .. $i - 1 ) {                              # hacemos un bucle al revés
    my $siguiente = $i + 1;                                     # apuntamos al siguiente
 
    rename("$tempDir/$imageDir/$name-fig-$i.pdf","$tempDir/$imageDir/$name-fig-$siguiente.pdf");
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

El código contempla el caso de que no exista el archivo con índice 0. Es decir: si no existe ese archivo, con el last salimos inmediatamente del bucle while(), y no se ejecuta ninguna vuelta en el bucle for(), por lo que no realiza ningún renombrado.

por **pablgonz** » 2013-12-05 09:10 @423

explorer escribiste:Volver a crear los documentos es muy ineficiente.

Gracias por la respuesta, y totalmente de acuerdo, en la mayor parte de los casos, pero en este no. Me explico: si modifico algo en el fichero de entrada (es un fichero latex) como un color, por ejemplo, cuando vuelva a correr el script, éste debe volver a generar las imágenes (pdf). Con tu solución, encontrará los ficheros ya enumerados y saldrá, es decir, quedará con los pdf sin las modificaciones.

Por eso la idea de eliminarlos y volver a crearlos es correcta, solo debo hacerla más restrictiva, en algunas ocasiones en directorio donde están las imágenes ya existen otros pdf que no tienen que ver con los generados por script, entonces, necesito una especie de ¿comodín? para eliminar solo <$name-fig-*.pdf>.

Saludos

por **explorer** » 2013-12-05 11:39 @527

Bueno, pues solo tienes que modificar el programa para que compruebe si hay una entrada nueva. Si es así, elimina los archivos anteriores (unlink glob "$name-fig-*.pdf") y ya puedes pasar a la parte de volver a generarlos.

En caso de que la entrada no sea nueva, pues no haces nada.

por **pablgonz** » 2013-12-05 11:47 @532

Un millón de gracias, justo estaba leyendo lo de glob lo cambié a esto:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

foreach my $FILES (@FILES) {
   if (-e "$dir/$FILES") {
     unlink glob "$dir/$name-fig-*.pdf"
   }
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

aún sigo pensando que me sobran cosas en el código, ¿es necesario greep?

por **explorer** » 2013-12-05 14:09 @631

Si usas glob("*.pdf"), no necesitas grep().

¿Seguro que el bucle que has puesto está bien?

@FILES contiene el listado de todos los archivos.
Inicias un bucle, y le das a $FILES el nombre del primer archivo.
Compruebas si existe ese archivo.
Si existe, entonces mandas borrar todos los archivos (nótese la presencia del comodín '*').

Entonces...
1) No necesitas comprobar si existe el archivo: sí existe (siempre), porque lo has leído con <*.pdf> o con readdir.
2) Si mandas borrar todos los archivos, no necesitas recorrer el resto de archivos en el bucle for

Mejor así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

if (@FILES) {      # si hay algún archivo .pdf,
    unlink @FILES; # les borro
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Problema con renombrar archivos en un directorio

Problema con renombrar archivos en un directorio

Publicidad

Re: Problema con renombrar archivos en un directorio

Re: Problema con renombrar archivos en un directorio

Re: Problema con renombrar archivos en un directorio

Re: Problema con renombrar archivos en un directorio

Re: Problema con renombrar archivos en un directorio

Re: Problema con renombrar archivos en un directorio

Re: Problema con renombrar archivos en un directorio

Re: Problema con renombrar archivos en un directorio

Re: Problema con renombrar archivos en un directorio

¿Quién está conectado?