Foro - Perl en Español

por **sisifo80** » 2014-02-24 09:47 @449

Hola,

Estoy intentando crear un script que modifique ciertas características de un texto escrito en XML. El texto 'input' sería algo así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using xml Syntax Highlighting

<etiqueta1>
   <etiqueta2>text texto texto. PS6000</etiqueta2>
</etiqueta1>
Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

El texto contenido en <etiqueta2> siempre termina con un código del tipo "PS + cuatro dígitos" (por ejemplo, PS6000).

Lo que necesito es un script que convierta el texto 'input' en el siguiente texto 'output':

Sintáxis: [ Descargar ] [ Ocultar ]

Using xml Syntax Highlighting

<etiqueta1 n="PS6000">
   <etiqueta2>text texto texto. PS6000</etiqueta2>
</etiqueta1>
Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Es decir, un script que reconozca el código que aparece al final de <etiqueta2> y lo repita como valor del atributo "n" dentro de <etiqueta1>.

Concretamente, lo que no sé es cómo decir en Perl que si encuentra determinada cadena la imprima en un lugar determinado. Mi propuesta:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use warnings;
use strict;
my $filename = shift;
open F, $filename or die "Usa: $0 FILENAME\n";
while (<F>) {
    if (/(PS\d\d\d\d)<\/etiqueta2>/) {
        print $1;
    }                                  # si encuentra "PS + cuatro dígitos + </etiqueta2>" imprima "PS + cuatro dígitos"
}
close F;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Cuando se trata de modificar una línea que está antes de la que estamos leyendo, no nos vale la opción de ir leyendo el archivo línea a línea, ya que al leer la segunda línea, olvidamos la primera.

Una opción es leer todo el archivo en memoria, y aplicar una expresión regular, ya que, el cambio que quieres hacer se puede expresar fácil como un patrón:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use File::Slurp;
 
my $xml = read_file('code_36827.xml');                                      # leemos todo el archivo
 
$xml =~ s{<etiqueta1\K(>\s+<etiqueta2>.+(PS\d+)</etiqueta2>)}{ n="$2"$1}g;  # hacemos cambios
 
print $xml;                                                                 # resultado
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

La expresión regular quiere decir:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$xml =~ s{                      # operación de sustitución
    <etiqueta1                  # buscamos esto
    \K                          # si lo encontramos, nos olvidamos de él, y miramos resto del patrón
    (                           # capturar en $1 lo que sigue
        >                       # buscamos un '>'
        \s+                     # seguido por uno o más caracteres de espacio (fines de línea incluidos)
        <etiqueta2>             # seguido por esta etiqueta
        .+                      # seguido por uno o más caracteres cualesquiera
        (                       # capturar en $2 lo que sigue
            PS                  # seguido por 'PS'
            \d+                 # seguido por un conjunto de dígitos
        )                       # fin de captura $2: es el código que queremos poner
        </etiqueta2>            # seguido por la etiqueta de cierre
    )
}
{ n="$2"$1}gx;                  # si hemos encontrado un texto que coincida con lo anterior, lo cambiamos por esto
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Otra forma de hacerlo es usando las facilidades de Tie::File, que nos relaciona las líneas del archivo con un array, por lo que ya podemos usar el concepto "línea anterior":

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use Tie::File;
 
tie my @xml, 'Tie::File', 'code_36827.xml';                     # enlazamos el archivo con el array @xml
 
for(my $i = 0; $i < @xml; $i++) {                               # para todas las líneas
 
    if ($xml[$i] =~ m{ (PS\d+)</etiqueta2>}) {                  # si la línea tiene un código
 
        my $codigo = $1;
 
        $xml[$i-1] =~ s{<etiqueta1>}{<etiqueta1 n="$codigo">};  # hacemos el cambio en la línea anterior
    }
}
 
untie @xml;                                                     # final de enlazado (al archivo queda modificado)
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **sisifo80** » 2014-02-24 11:55 @538

¡Muchas gracias, explorer!

Antes de leer tu respuesta, yo había intentado una solución mucho más "chapucera":

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use warnings;
use strict;
my $filename = shift;
open F, $filename or die "Usa: $0 FILENAME\n";
while (<F>) {
if (/(PS\d\d\d\d)<\/etiqueta2>/) {print "<etiqueta1 n=\"$1\">\n";next}
}
close F;
open F, $filename or die "Usa: $0 FILENAME\n";
while (<F>) {
if (/<etiqueta2>/) {print;next}
}
close F;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Es decir, abrir el archivo, encontrar el patrón e imprimirlo dentro de "etiqueta1", cerrar el archivo, abrir de nuevo, imprimir "etiqueta2.

Pero, obviamente, tus sugerencias son mucho mejores. ¡Gracias de nuevo!

Foro - Perl en Español

Imprimir texto en un lugar determinado

Imprimir texto en un lugar determinado

Publicidad

Re: Imprimir texto en un lugar determinado

Re: Imprimir texto en un lugar determinado

¿Quién está conectado?