Foro - Perl en Español

por **sisifo80** » 2014-05-19 07:15 @344

Hola,

Quisiera saber si en Perl es posible trabajar con dos archivos de entrada simultáneamente para crear un archivo de salida.

Es decir, tengo varios archivos llamados ????_header.XML y varios archivos llamados ????_text.xml. Para cada par "_header.xml" y "_text.xml" quisiera crear un archivo .txt a partir de los datos de entrada de los dos archivos .xml (header y text).

Ese script de conversión estaría compuesto de varias órdenes de sustitución y otras cosas, pero lo que no sé es cómo decir en Perl (o en la consola de comandos) que algunas sustituciones las haga a partir de un archivo de entrada y otras sustituciones las haga a partir del otro archivo de entrada. Por supuesto, siempre podría crear dos script. Pero, ¿es posible hacerlo en uno solo?

Perdón por lanzar una pregunta tan general.

Gracias.

Pues sí que se puede hacer. Cada vez que haces un readline() o pones el operador diamante (<>) estás leyendo una línea del archivo correspondiente, así que es cuestión de leer las líneas en el orden en que las necesites.

Otra opción es leer los dos archivos a memoria, guardarlos en array, y así se puede avanzar o retroceder por los contenidos de los dos archivos.

Una solución intermedia es la de usar Tie::File, que "enlaza" un array local con las líneas de un archivo. Se puede hacer otro nudo con el otro archivo, y así tienes dos array independientes.

En el hilo Sustituir datos de un archivo a otro encontrarás un ejemplo de lectura sincronizada entre dos archivos (se lee de cada vez una línea de cada archivo, se procesan, y el resultado se graba en un tercero).

por **sisifo80** » 2014-05-19 10:26 @476

Muchas gracias, explorer.

Supongamos que estoy interesado en tu segunda opción (leer los dos archivos a memoria guardándolos en array). Supongamos que todos mis archivos de entrada (los que acaban en header.xml y los que acaban en text.xml) los guardo en una carpeta llamada "input". He probado lo siguiente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use strict;
use warnings;
 
opendir IN, 'input';
my @lines1 = grep { /header.xml$/ } readdir IN;
my @lines2 = grep { /text.xml$/ } readdir IN;
closedir IN;
 
for my $lines1 (@lines1) {
  open IN, '<', "input/$lines1" || next;
  open OUT, '>', "output/$lines1" || die "can't open file output/$lines1";
  while(<IN>) {
  #hacer toda una serie de operaciones
  print OUT;
  }
  close OUT;
  close IN;
}
 
for my $lines2 (@lines2) {
  open IN,  '<', "input/$lines2" || next;
  open OUT, '>', "output/$lines2" || die "can't open file output/$lines2";
  while(<IN>) {
  #hacer toda una serie de operaciones
  print OUT;
  }
  close OUT;
  close IN;
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Pero lo que obtengo en la carpeta "output" es simplemente los archivos "...header.xml" con las modificaciones correspondientes. Y lo que yo querría es un archivo de salida por cada par "...header.xml" + "...text.xml" que conservase las modificaciones hechas en ambos archivos de entrada. ¿Es posible con la estrategia que estoy siguiendo?

He conseguido que me lea los dos tipos de archivos de entrada:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use strict;
use warnings;
 
opendir IN, 'input';
my @lines1 = grep { /header.xml$/ } readdir IN;
closedir IN;
 
for my $lines1 (@lines1) {
  open IN, '<', "input/$lines1" || next;
  open OUT, '>', "output/$lines1" || die "can't open file output/$lines1";
  while(<IN>) {
  #hacer toda una serie de operaciones
  }
  close OUT;
  close IN;
}
 
opendir IN, 'input';
my @lines2 = grep { /text.xml$/ } readdir IN;
closedir IN;
 
for my $lines2 (@lines2) {
  open IN, '<', "input/$lines2" || next;
  open OUT, '>', "output/$lines2" || die "can't open file output/$lines2";
  while(<IN>) {
  #hacer toda una serie de operaciones
  print OUT;
  }
  close OUT;
  close IN;
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Pero ahora el problema es que las modificaciones realizadas no se imprimen todas en un único archivo de salida, sino que se crea una archivo de salida ...header.xml y otro ...text.xml, cada uno con sus respectivas modificaciones.

por **explorer** » 2014-05-19 15:11 @674

Lo que has hecho hasta ahora es leer los nombres de los archivos y guardarlos en array, pero no el contenido de los mismos.

¿Puedes publicar un ejemplo -mínimo- de lo que quieres hacer?

por **sisifo80** » 2014-05-19 17:10 @757

Mis disculpas. La verdad es que mi explicación no fue muy clara. Lo vuelvo a intentar.

Tengo dos tipos de archivos de entrada. Los archivos del tipo1 se llaman de la siguiente manera:

0001_header.xml
0002_header.xml
0003_header.xml
...

Los archivos del tipo2 se llaman de la siguiente manera:

0001_text.xml
0002_text.xml
0003_text.xml
...

De los archivos tipo1 necesito imprimir el contenido de la etiqueta <title></title>.
De los archivos tipo2 necesito varias cosas, pero para simplificar diremos que necesito imprimir el contenido de la etiqueta <text></text>.

Todos estos archivos están guardados en una carpeta llamada input/.

El objetivo es que en la carpeta llamada output/ se creen archivos .txt (0001.txt, 0002.txt, 0003.txt, ...) que muestren el resultado conjunto de ambas impresiones. Por ejemplo:

Imaginemos que en el archivo "0001_header.xml" se incluye la siguiente información:

<title>Esto es un título</title>

Imaginemos que en el archivo "0001_text.xml" se incluye la siguiente información:

<text>Esto es texto</text>

El archivo creado 0001.txt debería contener:

TITULO: esto es un título
TEXTO: Esto es texto

Propuesta 1:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use strict;
    use warnings;
     
    opendir IN, 'input';
    my @lines1 = grep { /header.xml$/ } readdir IN;
    closedir IN;
     
    for my $lines1 (@lines1) {
      open IN, '<', "input/$lines1" || next;
      open OUT, '>', "output/$lines1" || die "can't open file output/$lines1";
          print OUT "TITULO: ";
      while(<IN>) {
      if (/<title>(.+?)<\/title>/) {print OUT "$1\n"};
      }
      close OUT;
      close IN;
    }
     
    opendir IN, 'input';
    my @lines2 = grep { /text.xml$/ } readdir IN;
    closedir IN;
     
    for my $lines2 (@lines2) {
      open IN, '<', "input/$lines2" || next;
      open OUT, '>', "output/$lines2" || die "can't open file output/$lines2";
          print OUT "TEXTO: ";
      while(<IN>) {
      if (/<text>(.+?)<\/text>/) {print OUT "$1\n"};
      }
      close OUT;
      close IN;
    }
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

En este caso no sé cómo hacer que los archivos de salida creados sean txt y que combinen en un único txt ambas modificaciones (ambos print).

Otra opción que probé fue crear una variable que incluya el contenido de las dos entradas, para poder trabajar a partir de ahí:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use strict;
use warnings;
 
my $content;
local $/ = undef;
open(IN, "<0001_header.xml");
$content = <IN>;
close(IN);
open(IN, "<0001_text.xml");
$content .= <IN>;
close(IN);
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Pero en este caso no sé cómo aplicar el script a varios archivos a la vez para crear los respectivos .txt.

por **explorer** » 2014-05-20 06:34 @315

Sí, se puede hacer lo segundo, pero algo que falta en los programas es la "sincronización". Quiero decir que hay que fijarse que estamos procesando los archivos 00001, y luego los 00002, y así. Si los lees tal cual llegan por el readdir(), te arriesgas a recibirlos desordenados (dependerá de cómo estén grabados en el sistema de archivos).

Entonces, lo que se puede hacer es: leemos los nombres de todos los archivos header. Por cada uno de ellos, le sacamos el número, y ese número lo usamos para localizar el archivo text correspondiente y grabar el resultado en un .txt.

Algo así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use v5.14;
use autodie;
use File::Slurp;
 
my @archivos_header = <*_header.xml>;                   # leemos los nombres de todos los archivos header
 
for my $archivo_header (@archivos_header) {             # para cada uno de ellos
 
    my($indice)= $archivo_header =~ /^(\d+)/;           # le sacamos el número
    
    my $header = read_file($archivo_header);            # leemos el archivo header
    my $text   = read_file($indice . '_text.xml');      # y su correspondiente text
 
    my $salida;                                         # aquí almacenaremos el contenido del archivo de salida
    
    ## header
    my($titulo)= $header =~ m{<title>(.+?)</title>};    # extracción del título
    if($titulo) {                                       # si lo hay
        $salida .= "TITULO: $titulo\n";                 # lo agregamos a la $salida
    }
    
    ## text
    my($texto) = $text   =~ m{<text>(.+?)</text>};      # extracción del texto
    if($texto) {                                        # si lo hay
        $salida .= "TEXTO: $texto\n";                   # lo agregamos a la $salida
    }
    
    open my $OUTPUT, '>', "$indice.txt";                # grabación del resultado
    print   $OUTPUT $salida;
    close   $OUTPUT;
}
 
__END__
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

por **sisifo80** » 2014-05-21 04:57 @248

Muchas gracias, explorer. Tu script funciona perfectamente y, gracias a las explicaciones que incluiste, lo puedo utilizar como base para futuros scripts que necesito. ¡Mil gracias!

Foro - Perl en Español

Sustituciones sobre dos archivos de entrada

Sustituciones sobre dos archivos de entrada

Publicidad

Re: Sustituciones sobre dos archivos de entrada

Re: Sustituciones sobre dos archivos de entrada

Re: Sustituciones sobre dos archivos de entrada

Re: Sustituciones sobre dos archivos de entrada

Re: Sustituciones sobre dos archivos de entrada

Re: Sustituciones sobre dos archivos de entrada

¿Quién está conectado?