Foro - Perl en Español

por **seafree** » 2014-06-03 08:39 @402

Hola, explorer, estoy un poco obstruida con algunas modificaciones, te muestro el código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$sql_eventos:="SELECT id,descrip_comp,fecha_sale,fecha_entra,dispositivo,medidas,causa,id_causa,id_anexo FROM t_eventos te, c_tipo_componentes ctc, c_componentes cc WHERE te.subestacion='CIE' AND tipo_evento like 'D-C%' AND (fecha_sale BETWEEN '2013-01-01 00:00:00' AND '2013-12-31 23:59:59') AND indice='S' AND te.id_tipo_componente=ctc.id_tipo_componente AND ctc.id_componente=cc.id_componente GROUP BY id,descrip_comp,fecha_sale,fecha_entra,dispositivo,medidas,causa,id_causa,id_anexo ORDER BY fecha_sale,descrip_comp"
 
$sth= $dbh->prepare($sql_eventos) or die $DBI::errstr;
$sth->execute();
$fetchall_arrayref = $sth->fetchall_arrayref();
$tuplas = $sth->rows;
print "TUPLAS: -->$tuplas<-- <br>"; #Efectivamente trae 3 registros
my $fetchall_arrayref = $sth->fetchall_arrayref();
for my $i (0 .. $#$fetchall_arrayref) {
    print "Registro $i\n";
    my $registro_ref = $fetchall_arrayref->[$i];        # El elemento $i apuntado por $fechall_arrayref contiene una referencia a un array
          for my $columna (@$registro_ref) {                  # Mostrar todos los registros
              print "\t$columna\n";
          }
}
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

¿Me puedes apoyar, por favor, a encontrar cuál es el error? No doy con él y solo muestra:

SQL_EVENTO: SELECT id,descrip_comp,fecha_sale,fecha_entra,dispositivo,medidas,causa,id_causa,id_anexo FROM t_eventos te, c_tipo_componentes ctc, c_componentes cc WHERE te.subestacion='EDO' AND tipo_evento like 'DISPARO-RECIERRE%' AND (fecha_sale BETWEEN '2013-01-01 00:00:00' AND '2013-12-31 23:59:59') AND indice='S' AND te.id_tipo_componente=ctc.id_tipo_componente AND ctc.id_componente=cc.id_componente GROUP BY id,descrip_comp,fecha_sale,fecha_entra,dispositivo,medidas,causa,id_causa,id_anexo ORDER BY fecha_sale,descrip_comp
TUPLAS: -->3<--

$sql_eventos
    = "SELECT id,descrip_comp,fecha_sale,fecha_entra,dispositivo,medidas,causa,id_causa,id_anexo FROM t_eventos te, c_tipo_componentes ctc, c_componentes cc WHERE te.subestacion='INI' AND tipo_evento like 'D-R%' AND (fecha_sale BETWEEN '2013-01-01 00:00:00' AND '2013-12-31 23:59:59') AND indice='S' AND te.id_tipo_componente=ctc.id_tipo_componente AND ctc.id_componente=cc.id_componente GROUP BY id,descrip_comp,fecha_sale,fecha_entra,dispositivo,medidas,causa,id_causa,id_anexo ORDER BY fecha_sale,descrip_comp";
 
$sth = $dbh->prepare($sql_eventos) or die $DBI::errstr;
$sth->execute();
$fetchall_arrayref = $sth->fetchall_arrayref();
$tuplas            = $sth->rows;       # Muestra 3 tuplas
print start_table( { -border => 3 } );
for my $i ( 0 .. $#$fetchall_arrayref ) {
    my $rowspan = 1;
    my $reg     = $fetchall_arrayref->[$i];
    my $id           = ${$reg}[0];     # UTILICÉ ESTA SENTENCIA PORQUE $id=$reg->{'id'} no la acepta (postgres V5.8.8)
    my $descrip_comp = ${$reg}[1];
    my $fecha_sale   = ${$reg}[2];
    my $fecha_entra  = ${$reg}[3];
    my $dispositivo  = ${$reg}[4];
    my $medidas      = ${$reg}[5];
    my $causa        = ${$reg}[6];
    my $id_causa     = ${$reg}[7];
    my $id_anexo     = ${$reg}[8];
    print
        "ID: $id - DESCRIP_COMP: $descrip_comp - FECHA_SALE: $fecha_sale - FECHA_ENTRA: $fecha_entra - DISPOSITIVO: $dispositivo - MEDIDAS: $medidas - ID_ANEXO: $id_anexo<br><br>";
 
    # SOLO VISUALIZO HASTA ESTA LÍNEA DE CÓDIGO PORQUE DE OTRA MANERA NO EJECUTA LO SIGUIENTE:
 
    if ($descrip_comp) {                                        # buscar campo diferente en el resto de líneas
        my $j;
        for ( $j = $i + 1; $j <= $#$fetchall_arrayref; $j++ ) { # recorremos desde la siguiente línea, hasta el final
            last
                if $fetchall_arrayref->[$j]->{'descrip_comp'}
                ne $descrip_comp;                               # salimos si hemos encontrado una celda distinta
 
            $fetchall_arrayref->[$j]->{'descrip_comp'} = '';    # la celda es igual, así que la limpiamos
        }
        $rowspan = $j - $i;                     # tamaño del rowspan
    }
    my $celda_descrip;
    if ( $rowspan == 1 ) {                      # puede que sea celda normal, o abreviada
        if ($descrip_comp) {
            $celda_descrip = td($descrip_comp); # celda normal
        }
        else {
            $celda_descrip = '';                # abreviada: no hay celda
        }
    }
    else {                                      # demás casos: rowspan
        $celda_descrip = td( { -rowspan => $rowspan }, $descrip_comp );
    }
    print " <tr><td>$i $celda_descrip, <td>$fecha_sale-$medidas-$causa-$id_causa";
}
print end_table;
print end_html;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

¿Qué omití, explorer?

por **explorer** » 2014-06-03 15:35 @691

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$fetchall_arrayref = $sth->fetchall_arrayref();
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Cuando se llama a fetchall_arrayref() así, sin indicar ningún argumento, es lo mismo que se llamara así: fetchall_arrayref([]) Es decir: es como si le pasáramos una referencia a un array vacío. En ese caso, el resultado es una referencia a un array en que cada elemento es una referencia a otro array, que guarda los datos de cada fila del resultado de la consulta.

Esta es la razón por la cual no te funciona, en la línea 12, la expresión $id = $reg->{'id'}. No se ha creado un hash en esa fila, sino un array, así que estás obligada a poner índices numéricos (${$reg}[0]).

Y por esa razón, también, no te funcionan las líneas 26 y siguientes. Estás intentando acceder a elementos de un hash, pero no lo hay. Es un array.

La solución es llamar a fetchall_arrayref() pero con una referencia a un hash vacío.

El programa quedaría así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $sql_eventos = "
        SELECT
                id, descrip_comp, fecha_sale, fecha_entra, dispositivo, medidas, causa, id_causa, id_anexo
        FROM
                t_eventos te, c_tipo_componentes ctc, c_componentes cc
        WHERE
                        te.subestacion ='INI'
                AND
                        tipo_evento like 'D-R%'
                AND
                        (fecha_sale BETWEEN '2013-01-01 00:00:00' AND '2013-12-31 23:59:59')
                AND
                        indice = 'S'
                AND
                        te.id_tipo_componente = ctc.id_tipo_componente
                AND
                        ctc.id_componente = cc.id_componente
        GROUP BY
                id, descrip_comp, fecha_sale, fecha_entra, dispositivo, medidas, causa, id_causa, id_anexo
        ORDER BY
                fecha_sale, descrip_comp
";
 
my $sth = $dbh->prepare($sql_eventos) or die $DBI::errstr;
 
$sth->execute();
 
my $fetchall_arrayref = $sth->fetchall_arrayref({});    # <= cambio
 
my $tuplas = $sth->rows;
 
print start_table( { -border => 3 } );
 
for my $i ( 0 .. $#$fetchall_arrayref ) {
    my $rowspan = 1;
 
    my $reg             = $fetchall_arrayref->[$i];
 
    my $id              = $reg->{'id'           };
    my $descrip_comp    = $reg->{'descrip_comp' };
    my $fecha_sale      = $reg->{'fecha_sale'   };
    my $fecha_entra     = $reg->{'fecha_entra'  };
    my $dispositivo     = $reg->{'dispositivo'  };
    my $medidas         = $reg->{'medidas'      };
    my $causa           = $reg->{'causa'        };
    my $id_causa        = $reg->{'id_causa'     };
    my $id_anexo        = $reg->{'id_anexo'     };
 
    if ($descrip_comp) {                                        # buscar campo diferente en el resto de líneas
        my $j;
        for ( $j = $i+1; $j <= $#$fetchall_arrayref; $j++ ) {   # recorremos desde la siguiente línea, hasta el final
 
                                                                # salimos si hemos encontrado una celda distinta
            last
                if $fetchall_arrayref->[$j]->{'descrip_comp'}
                ne $descrip_comp;
 
            $fetchall_arrayref->[$j]->{'descrip_comp'} = '';    # la celda es igual, así que la limpiamos
        }
 
        $rowspan = $j - $i;                                     # tamaño del rowspan
    }
 
    my $celda_descrip;
 
    if ($rowspan == 1) {                                        # puede que sea celda normal, o abreviada
        if ($descrip_comp) {
            $celda_descrip = td($descrip_comp);                 # celda normal
        }
        else {
            $celda_descrip = '';                                # abreviada: no hay celda
        }
    }
    else {                                                      # demás casos: rowspan
        $celda_descrip = td( { -rowspan => $rowspan }, $descrip_comp );
    }
 
    print " <tr><td>$i $celda_descrip, <td>$fecha_sale-$medidas-$causa-$id_causa";
}
 
print end_table;
print end_html;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

seafree escribiste:¿Qué omití, explorer?

Quizás leer el manual de DBI.

Una cosa... estás haciendo consulta de cosas que luego no muestras, como por ejemplo el valor de 'id'. Así que podrías hacerla un poco más simple.

por **seafree** » 2014-06-04 12:31 @563

Gracias, explorer, y sí voy a leer el manual de DBI.

Foro - Perl en Español

rowspan dinámico

Re: rowspan dinámico

Publicidad

Re: rowspan dinámico

Re: rowspan dinámico

Re: rowspan dinámico

Re: rowspan dinámico

¿Quién está conectado?