Foro - Perl en Español

por **lis** » 2014-07-03 09:58 @456

Hola, nuevamente necesito de su gran ayuda. Tengo un archivo que contienen 6 columnas y la última tiene la palabra Calma, la cual debo reemplazar por el valor anterior, pero en algunos casos comienza con esta palabra, en ese caso se debe reemplazar por el valor siguiente.

Este es un extracto del archivo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

2 1 0 0.3 Calma

2 1 100 0.2 350

2 1 200 0.6 344

2 1 300 0.4 Calma

2 1 400 0.2 Calma

2 1 500 0.8 352

2 1 600 0.9 347

2 1 700 0.6 159

2 1 800 1.9 179

2 1 900 2.1 184

2 1 1000 3.8 221

2 1 1100 4.7 211

2 1 1200 4.6 211

2 1 1300 4.3 212

2 1 1400 4.3 212

2 1 1500 4.4 212

2 1 1600 4.4 211

2 1 1700 5.2 205

2 1 1800 3.9 211

2 1 1900 2.6 208

2 1 2000 0.4 Calma
Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Por lo que debiera quedar así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

2 1 0 0.3 350

2 1 100 0.2 350

2 1 200 0.6 344

2 1 300 0.4 344

2 1 400 0.2 344

2 1 500 0.8 352

2 1 600 0.9 347

2 1 700 0.6 159

2 1 800 1.9 179

2 1 900 2.1 184

2 1 1000 3.8 221

2 1 1100 4.7 211

2 1 1200 4.6 211

2 1 1300 4.3 212

2 1 1400 4.3 212

2 1 1500 4.4 212

2 1 1600 4.4 211

2 1 1700 5.2 205

2 1 1800 3.9 211

2 1 1900 2.6 208

2 1 2000 0.4 208
Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

He intentado muchas cosas pero no lo consigo. Muchas gracias a todos.

open my $DATOS,    '<', 'archivo.txt' or die $!;
open my $ARCHIVOS, '>', 'salida.txt'  or die $!;
 
while ( my $linea = <$DATOS> ) {
    chop($linea);
    @datos = split( " ", $linea );
    if ( $datos[5] eq 'Calma' ) {
        $datos[5] = next;
    }
 
    print $ARCHIVOS join( ' ', @datos ), "\n";
}
 
close($ARCHIVOS);
close($DATOS);
 
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2014-07-03 13:07 @588

¿ $datos[5] = next ?

Eso no es muy Perl, que digamos...

Perl sobre entiende algunas cosas... pero no tanto como para leernos el pensamiento

por **explorer** » 2014-07-03 16:37 @734

Esta es una solución, sin leer todas las líneas.

Sintáxis: (code_37400.pl) [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl 
#===============================================================================
#
#         FILE: code_37400.pl
#
#        USAGE: ./code_37400.pl  
#
#  DESCRIPTION: Quitar la Calma
#
#       AUTHOR: JOAQUÍN FERRERO (explorer), 
# ORGANIZATION: perlenespanol.com
#      VERSION: 1.0
#      CREATED: 03/07/14 23:17:01
#     REVISION: ---
#===============================================================================
 
use v5.14;
use autodie;
use utf8;
 
open my $ARCHIVO, '<', 'code_37400.txt';                        # abrir archivos
open my $SALIDA,  '>', 'code_37400_out.txt';
 
my $valor_anterior;                                             # recuerdo del valor anterior
 
while (my $línea = <$ARCHIVO>) {                               # para todas las líneas...
    my @columnas = split " ", $línea;                          # las partimos en columnas
 
    if ($columnas[-1] eq 'Calma') {                             # si la última columna es 'Calma'...
 
        if (defined $valor_anterior) {                          # y tenemos un $valor_anterior...
            $columnas[-1] = $valor_anterior;                    # ponemos nuevo valor, que es el anterior
        }
        else {                                                  # estamos en el caso de la primera línea
            my $posición_lectura_archivo = tell $ARCHIVO;      # posición actual de lectura
            $línea = <$ARCHIVO>;                               # leemos la $línea siguiente
            my @columnas_siguiente_línea = split " ", $línea; # partimos
            $columnas[-1] = $columnas_siguiente_línea[-1];     # sacamos el valor
            seek $ARCHIVO, $posición_lectura_archivo, 0;       # reposicionamos
        }
    }
 
    $valor_anterior = $columnas[-1];                            # recordaremos el valor anterior para la siguiente
 
    say $SALIDA join " ", @columnas;                            # salida
}
 
close $ARCHIVO;                                                 # cerrar
close $SALIDA;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2014-07-03 16:56 @747

Esta es otra versión, pero usando Tie::File... que es una de las mejores opciones para cuando tenemos que movernos entre líneas.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl 
#===============================================================================
#
#         FILE: code_37400.pl
#
#        USAGE: ./code_37400.pl  
#
#  DESCRIPTION: Quitar la Calma
#
#       AUTHOR: JOAQUÍN FERRERO (explorer), 
# ORGANIZATION: perlenespanol.com
#      VERSION: 2.0
#      CREATED: 03/07/14 23:54:40
#     REVISION: ---
#===============================================================================
 
use v5.14;
use autodie;
use utf8;
 
use Tie::File;
 
tie my @líneas, 'Tie::File', 'code_37400.txt';
 
 
for (my $i = 0; $i < @líneas; $i++) {          # para todas las líneas
 
    my @columnas = split " ", $líneas[$i];     # la partimos
 
    if ($columnas[-1] eq 'Calma') {
 
        if ($i != 0) {                                          # si no estamos en la primera línea
            $columnas[-1] = (split " ", $líneas[$i-1])[-1];    # la nueva última columna será la de la línea anterior
        }
        else {                                                  # si estamos en la primera
            $columnas[-1] = (split " ", $líneas[$i+1])[-1];    # la nueva última columna será la de la siguiente
        }
 
        $líneas[$i] = join " ", @columnas;
    }
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2014-07-03 17:07 @755

Y esta es una tercera versión, uniendo los dos trucos:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl 
#===============================================================================
#
#         FILE: code_37400.pl
#
#        USAGE: ./code_37400.pl  
#
#  DESCRIPTION: Quitar la Calma
#
#       AUTHOR: JOAQUÍN FERRERO (explorer), 
# ORGANIZATION: perlenespanol.com
#      VERSION: 3.0
#      CREATED: 04/07/14 00:03
#     REVISION: ---
#===============================================================================
 
use v5.14;
use autodie;
use utf8;
 
use Tie::File;
 
tie my @líneas, 'Tie::File', 'code_37400.txt';
 
my $valor_anterior;
 
for (my $i = 0; $i < @líneas; $i++) {          # para todas las líneas
 
    my @columnas = split " ", $líneas[$i];     # la partimos
 
    if ($columnas[-1] eq 'Calma') {             # si estamos en calma
 
        $columnas[-1]                           # la nueva última columna
            = $i == 0                           # si es la primera línea
            ? (split " ", $líneas[$i+1])[-1]   # la tomamos de la siguiente
            : $valor_anterior                   # el resto, es el valor leído anterior
            ;
 
        $líneas[$i] = join " ", @columnas;     # cambiamos la línea
    }
 
    $valor_anterior = $columnas[-1];            # recordar para la siguiente
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **lis** » 2014-07-11 15:30 @688

Muchas, muchas gracias, explorer, por la ayudada brindada, y gracias también porque a pesar de que trato de estudiar Perl me cuesta llevarlo a la práctica y con tus códigos me es más fácil aplicarlos y entenderlos.

Foro - Perl en Español

Reemplazar por el dato siguiente

Reemplazar por el dato siguiente

Publicidad

Re: Reemplazar por el dato siguiente

Re: Reemplazar por el dato siguiente

Re: Reemplazar por el dato siguiente

Re: Reemplazar por el dato siguiente

Re: Reemplazar por el dato siguiente

Re: Reemplazar por el dato siguiente

Re: Reemplazar por el dato siguiente

¿Quién está conectado?