Foro - Perl en Español

por **alperez** » 2014-10-08 03:49 @200

Hola.

Estoy intentando obtener datos de mensajes de error que vienen con la siguiente forma:

"Sat Jul 13 16:13 Encl 1 (8F45751042) A power supply module is either faulty or unpowered. Another failure will make the system inoperative. Rectify problem immediately"

De momento he hecho un split() para obtener todos los datos hasta el mensaje de texto que genera la alarma:

A power supply module is either faulty or unpowered. Another failure will make the system inoperative. Rectify problem immediately

La duda que me surge es, ¿Cómo puedo obtener el mensaje de texto de la alarma sin tener que fraccionarlo trozo a trozo? Esto es porque todas las alarmas tienen los mismos campos hasta el mensaje de la alarma, pero claro, luego cada alarma tendrá un tamaño distinto.

Muchas gracias.

#!/usr/bin/perl -l
 
my $texto = "Sat Jul 13 16:13 Encl 1 (8F45751042) A power supply module is either faulty or unpowered. Another failure will make the system inoperative. Rectify problem immediately";
 
my($preambulo, $msg_error) = split /[)] /, $texto, 2;
 
print "[$preambulo)]";
print "[$msg_error]";
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Sale:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

[Sat Jul 13 16:13 Encl 1 (8F45751042)]

[A power supply module is either faulty or unpowered. Another failure will make the system inoperative. Rectify problem immediately]Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

por **alperez** » 2014-10-08 08:30 @395

Jope,

Muchas gracias, no lo había pensado en coger de esta manera.

por **Aceitunas** » 2014-10-20 16:55 @746

Hola,

Por colaborar un poco pongo otra posible solución con expresiones regulares.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $texto = "Sat Jul 13 16:13 Encl 1 (8F45751042) A power supply module is either faulty or unpowered. Another failure will make the system inoperative. Rectify problem immediately";
 
$texto =~ /\)(.*)/;
 
print $1;
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

saludos.

por **explorer** » 2014-10-21 04:58 @248

Ahora que me doy cuenta, hay una solución más obvia y rápida: no usar expresiones regulares.

Si lo que estamos buscando es una cadena de texto fija (un paréntesis de cierre), podemos usar la función index() o rindex() para localizarla, y cortar el texto con substr():

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $texto = 'Sat Jul 13 16:13 Encl 1 (8F45751042) A power supply module is either faulty or unpowered. Another failure will make the system inoperative. Rectify problem immediately';
 
my $msg_error = substr $texto, 2 + index $texto, ')';
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

El '+2' es para saltar al segundo carácter a partir del lugar donde está el paréntesis de cierre.

Gracias a Aceitunas me he dado cuenta.

por **Aceitunas** » 2014-10-21 05:18 @262

Pero, explorer, eso es básicamente lo que hace split internamente, ¿no?

por **explorer** » 2014-10-21 10:45 @489

No, no es lo mismo.

El split() realiza una búsqueda repetida de un patrón de exp. reg., mientras que index() busca una cadena literal, con lo que la búsqueda es mucho más rápida.

En concreto, es el DOBLE de rápida:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use Benchmark qw(cmpthese) ;
 
my $texto = "Sat Jul 13 16:13 Encl 1 (8F45751042) A power supply module is either faulty or unpowered. Another failure will make the system inoperative. Rectify problem immediately";
 
cmpthese( -3,
    {
        'split' => sub {
                    my(undef, $msg_error) = split/[)] /, $texto, 2;
        },
        'index' => sub {
                    my $msg_error = substr $texto, 2 + index $texto, ')';
        },
        'regex' => sub {
                    my($msg_error)= $texto =~ /[)](.*)/;
        },
    }
);
 
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

sale

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

           Rate regex split index

regex  973939/s    --  -49%  -75%

split 1926301/s   98%    --  -51%

index 3891800/s  300%  102%    --Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

por **Aceitunas** » 2014-10-21 12:51 @577

Cierto... es incluso más lento que la expresión regular.

Foro - Perl en Español

Obtener mensaje de una cadena de texto

Obtener mensaje de una cadena de texto

Publicidad

Re: Obtener mensaje de una cadena de texto

Re: Obtener mensaje de una cadena de texto

Re: Obtener mensaje de una cadena de texto

Re: Obtener mensaje de una cadena de texto

Re: Obtener mensaje de una cadena de texto

Re: Obtener mensaje de una cadena de texto

Re: Obtener mensaje de una cadena de texto

Re: Obtener mensaje de una cadena de texto

Re: Obtener mensaje de una cadena de texto

¿Quién está conectado?