Foro - Perl en Español

por **seafree** » 2015-03-02 13:32 @605

Hola, explorer. Respecto a tu pregunta respecto a la versión del CGI, es:

perl -MCGI -le 'print $CGI::VERSION'
3.15

Realizo la actualización de Perl:

perl-5.20.2]# ./Configure -des -Dprefix=$HOME/localperl
make test
make install

Vuelvo a verificar la versión del CGI:

# perl -MCGI -le 'print $CGI::VERSION'
3.15

Y el resultado es el mismo, ¿qué estoy haciendo mal?

Gracias por tu atención, explorer.

La versión más moderna de CGI es la 4.13, pero perl v5.20.2 ya no lo trae (Perl v5.20.0 trae la versión v3.65).

En mi ordenador, con Perl v5.18.2, trae el CGI v3.63.

La instalación de Perl en un directorio local te recomiendo que no lo hagas de esa manera. Es mucho mejor usar perlbrew para esas tareas.

Recuerda que si quieres ejecutar el perl instalado en tu directorio local, debes luego acordarte de poner la ruta del nuevo Perl con una opción -I al llamar a perl. Por ejemplo:

perl -Iperl5/lib/perl5 -MJSON::PP -E 'say $INC{"JSON/PP.pm"}'

O usar local::lib. O mejor aún... usa perlbrew.

Yo no sé dónde está el problema. Repasando:
* si la terminal está en UTF-8, que sí lo hemos visto
* si el código está codificado en UTF-8 (NO lo hemos visto, pero es de suponer)
* si el CGI está programado para sacar código UTF-8 (que así es)
* entonces el resultado debería ser en UTF-8.

Si no sale... repasando el archivo CHANGES de CGI, vemos que es en la v3.43 de CGI donde se arregló el problema de la doble codificación de los parámetros, que es lo que veo que te puede pasar.

Te aconsejo que uses el comando cpan o cpanp o cpanm para que instales una versión más moderna del CGI. O instalar Perl v5.20.1.

por **seafree** » 2015-03-03 15:12 @675

explorer, continúo con el problema de caracteres, analizando un poco más mi situación. Hallé:

1) Que el encoding de la base de datos está en SQL_ASCII

2) Los registro de la base de datos SÍ están acentuados

3) Logré que el charset del meta fuera utf8 (lo veo al compilar el script), pero al visualizar el código generado desde el navegador, este se genera como ISO-8859

Ojalá tengas alguna idea de lo que ocurre. Gracias.

por **explorer** » 2015-03-03 15:57 @706

En ese caso, debes transformar los textos que sacas de la base de datos, al formato Unicode interno de Perl (con la función decode() del módulo Encode). Y como el programa ya tiene definido el 'use open' a utf-8, pues ya sale en utf-8.

por **seafree** » 2015-03-04 12:51 @577

Configuré mi terminal a UTF-8:
# echo $LANG
es_ES.UTF-8

Creé una prueba
------------------------------------------------
#!/usr/bin/perl -w
use strict;
use warnings;
use CGI ":all";
use Encode;

my $cgi = new CGI;

$cgi->charset('utf-8');
print $cgi->header(-type=> 'text/html',
-charset=>'utf-8');
print $cgi->start_html(-title =>'PRUEBA',
-head => meta({-http_equiv => 'Content-Type',
-content => 'text/html; charset=utf-8'}));
my $hola='HELLO XÓCHITL';

decode::from_to($hola, 'latin1', 'utf8');
print $cgi->p($hola);
print $cgi->end_html;
------------------------------------------------

RESULTADO
---------------------------------------------------
#perl -w test1.pl
Content-Type: text/html; charset=utf-8

<!DOCTYPE html
PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
"http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" lang="en-US" xml:lang="en-US">
<head>
<title>PRUEBA</title>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1" />
</head>
<body>
<p>HELLO XÃCHITL</p>
</body>
</html>
--------------------------------------------------------------------------
¿Por qué no devuelve los caracteres UTF-8?

GRACIAS.

por **explorer** » 2015-03-04 15:39 @693

Por favor, repasa los ejemplos que ya te he dado. Te faltan cosas.

Viendo el código que muestras:

* el método charset() sirve para hacer un auto-escapado de los textos que salen en las cajas de texto de los formularios. O sea, que no te sirve en este ejemplo tan sencillo.

* luego haces una llamada correcta al método header(). Y de hecho, sale bien en las cabeceras HTTP y HTML

* luego llamas a start_html(), y allí vuelves a llamar a head, que sobra completamente

* luego haces la decodificación de los datos de $hola (suponiendo que ese texto que vemos está escrito en latin1), pero a mi no me funciona como lo has escrito. Abajo lo pongo de forma correcta

* luego haces un print de un p(). Como el contenido de $hola ya contiene algo en utf8, pues eso es lo que emitimos

Lo siguiente me funciona:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
 
use CGI ":all";
use Encode 'from_to';
 
my $cgi = CGI->new();
 
print $cgi->header(
    -type    => 'text/html',
    -charset => 'utf-8',
);
 
print $cgi->start_html(
    -title => 'PRUEBA',
);
 
my $hola = 'HELLO XÓCHITL';             # este código está escrito en latin1
 
from_to( $hola, 'latin1', 'utf8' );     # lo pasamos a UTF8
 
print $cgi->p($hola);
print $cgi->end_html;
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

La salida es:

Sintáxis: [ Descargar ] [ Ocultar ]

Using html4strict Syntax Highlighting

Content-Type: text/html; charset=utf-8
 
<!DOCTYPE html
        PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
         "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" lang="en-US" xml:lang="en-US">
<head>
<title>PRUEBA</title>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
</head>
<body>
<p>HELLO XÓCHITL</p>
</body>
</html>
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Aclaraciones:
* el código del programa está escrito en latin1, NO en utf8, ya que quieres imitar la llegada de datos desde la base de datos
* la salida se ve bien en mi terminal configurada en UTF-8

Pero... la clave está en por qué aparece un content-type iso-8859-1. Yo no veo ninguna línea donde se vea esa doble salida.

Según el archivo Changes del CGI, esa doble línea podría ser debido a la presencia de CGI::Carp cuando se usa la opción 'FatalsToBrowser', pero yo no lo veo ahora en tu nuevo código.

Me temo que es debido a que usas un CGI muy viejo.

Esta es otra forma de hacerlo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
 
use CGI ":all";
use Encode 'decode';
 
use open qw(:utf8 :std);
 
 
my $cgi = CGI->new();
 
print $cgi->header(
    -type    => 'text/html',
    -charset => 'utf-8',
);
 
print $cgi->start_html(
    -title => 'PRUEBA',
);
 
my $hola = 'HELLO XÓCHITL';             # este código está escrito en latin1
 
$hola = decode('latin1', $hola);        # lo pasamos a Unicode, formato interno de Perl
 
 
print $cgi->p($hola);                   # la capa del 'open' pasa de Unicode interno a utf8
print $cgi->end_html;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

El resultado es el mismo.

por **seafree** » 2015-03-05 10:16 @469

Sí, explorer, gracias por tu apoyo.

Saludos.

Foro - Perl en Español

Unicode (UTF-8) en la salida de CGI

Re: Unicode (UTF-8) en la salida de CGI

Publicidad

Re: Unicode (UTF-8) en la salida de CGI

Re: Unicode (UTF-8) en la salida de CGI

Re: Unicode (UTF-8) en la salida de CGI

Re: Unicode (UTF-8) en la salida de CGI

Re: Unicode (UTF-8) en la salida de CGI

Re: Unicode (UTF-8) en la salida de CGI

¿Quién está conectado?