Foro - Perl en Español

por **sarriaga** » 2015-08-06 11:49 @534

Hola, ¿qué tal? Muchas gracias, compañeros perleros, por todo el apoyo que he recibido de su parte. Nuevamente ando por acá con algo que no he podido resolver. Les platico la problemática:

Quiero mostrar en el navegador una tabla con cierta información que tengo en un array multidimensional, pero quiero crear un hash a partir de este array para agrupar la información de acuerdo a la posición [2] del array y que esta posición sea la llave o clave del hash y el resto del array sean los valores de esa llave.

Tengo el siguiente (muy poquito) código, donde empiezo a crear los datos que necesito:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my @array = ( ['Muestra de 500 pzas.', '64A10|F/I',  'B/A'], ['Defecto en 10 cajas', '65A10|F/I','C/I'], ['Defecto en 30 pzas', '67A10|B/A', 'B/A'] );
 
my %hash;
my @tit_encontrados;
 
my ($valor, $clave);
my ($x,$y);
foreach $x (0..@array-1){
    foreach $y (0..@{$array[$x]}-1){
        ($clave, $valor) = ($array[2], [$array[0],$array[1]]);
        if (!exists $cols{$clave}) {
            push(@tit_encontrados, $clave);
        }
        push @{$cols{$clave}}, $valor;
        print "$array[$x][$y] \n";
       
    }
}
 
#después hay que pasar los datos a una tabla html
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

La verdad, me siento bastante perdida

La tabla que necesito debe quedar de la siguiente manera:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

+--------------+-------------------------------------+

|Identificador |Descripción de reporte               |

+--------------+-------------------------------------+

|              | +---------------------+-----------+ |                     

|              | |Muestra de 500 pzas. | 64A10|F/I | |

|     B/A      | +---------------------+-----------+ |

|              | |Defecto en 30 pzas   | 67A10|B/A | |

|              | +---------------------+-----------+ |

+--------------+-------------------------------------+ 

|              | +---------------------+-----------+ |                     

|              | |Defecto en 10 cajas  | 65A10|F/I | |

|     C/I      | +---------------------+-----------+ |

|              |                                     |

+--------------+-------------------------------------+Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Ojalá que puedan ayudarme :oops:

¡¡Saludos!!

#!/usr/bin/perl
use CGI qw<:standard *table>;                           # importamos rutinas HTML
use feature 'say';                                      # para no tener que usar print
use utf8;                                               # hay algunos caracteres raros en este código
use open OUT => qw':utf8 :std';                         # la salida estándar será en utf8
 
 
my @array =
    ( ['Muestra de 500 pzas.', '64A10|F/I', 'B/A']
    , ['Defecto en 10 cajas',  '65A10|F/I', 'C/I']
    , ['Defecto en 30 pzas',   '67A10|B/A', 'B/A']
    );
 
#+--------------+-------------------------------------+
#|Identificador |Descripción de reporte               |
#+--------------+-------------------------------------+
#|              | +---------------------+-----------+ |                    
#|              | |Muestra de 500 pzas. | 64A10|F/I | |
#|     B/A      | +---------------------+-----------+ |
#|              | |Defecto en 30 pzas   | 67A10|B/A | |
#|              | +---------------------+-----------+ |
#+--------------+-------------------------------------+
#|              | +---------------------+-----------+ |                    
#|              | |Defecto en 10 cajas  | 65A10|F/I | |
#|     C/I      | +---------------------+-----------+ |
#|              |                                     |
#+--------------+-------------------------------------+
 
my %hash;
 
for my $elemento (@array) {                             # pasamos a hash indexado por la $clave
 
    my($concepto, $id, $clave) = @$elemento;
 
    push @{ $hash{$clave} }, [$concepto, $id];
}
 
say start_html(-encoding => 'utf-8');                           # iniciamos una página HTML
say start_table({-border => 3});                                # iniciamos una tabla
 
say Tr(th(['Identificador', 'Descripción de reporte']));       # línea cabecera
 
for my $identificador (sort keys %hash) {                               # para todos los $identificadores
 
    say Tr({-valign => 'center', -align => 'center'},                           # sacamos una línea
            td([                                                                # que contiene
                    $identificador,                                             # el $identificador
                    table({-border => 2, -width => '100%'},                     # y una tabla
                        Tr(                                                     # con una fila
                            [
                                map { td([@$_]) } @{$hash{$identificador}}      # creamos celdas por cada valor
                            ]
                    )),
            ])
    );
}
 
say end_table();                                                # cerramos la tabla
say end_html();                                                 # cerramos el HTML
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Sale:

Sintáxis: [ Descargar ] [ Ocultar ]

Using html4strict Syntax Highlighting

<!DOCTYPE html
        PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
         "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" lang="en-US" xml:lang="en-US">
<head>
<title>Untitled Document</title>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
</head>
<body>
 
<table border="3">
<tr><th>Identificador</th> <th>Descripción de reporte</th></tr>
<tr align="center" valign="center"><td>B/A</td> <td><table border="2" width="100%"><tr><td>Muestra de 500 pzas.</td> <td>64A10|F/I</td></tr> <tr><td>Defecto en 30 pzas</td> <td>67A10|B/A</td></tr></table></td></tr>
<tr valign="center" align="center"><td>C/I</td> <td><table border="2" width="100%"><tr><td>Defecto en 10 cajas</td> <td>65A10|F/I</td></tr></table></td></tr>
</table>
 
</body>
</html>
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

En CPAN hay mejores módulos para generar HTML. Incluso hay alguno especializado en sacar tablas, como el caso de HTML::Table, con lo que te podrás ahorrar un montón de líneas (el código quedaría reducido a una sola línea).

por **explorer** » 2015-08-09 11:00 @500

Bueno, no es una línea más, pero casi

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use CGI qw<:standard>;                                  # importamos rutinas HTML
use HTML::Table;
use feature 'say';                                      # para no tener que usar print
use utf8;                                               # hay algunos caracteres raros en este código
use open OUT => qw':utf8 :std';                         # la salida estándar será en utf8
 
 
my @array =
    ( ['Muestra de 500 pzas.', '64A10|F/I', 'B/A']
    , ['Defecto en 10 cajas',  '65A10|F/I', 'C/I']
    , ['Defecto en 30 pzas',   '67A10|B/A', 'B/A']
    );
 
#+--------------+-------------------------------------+
#|Identificador |Descripción de reporte               |
#+--------------+-------------------------------------+
#|              | +---------------------+-----------+ |                    
#|              | |Muestra de 500 pzas. | 64A10|F/I | |
#|     B/A      | +---------------------+-----------+ |
#|              | |Defecto en 30 pzas   | 67A10|B/A | |
#|              | +---------------------+-----------+ |
#+--------------+-------------------------------------+
#|              | +---------------------+-----------+ |                    
#|              | |Defecto en 10 cajas  | 65A10|F/I | |
#|     C/I      | +---------------------+-----------+ |
#|              |                                     |
#+--------------+-------------------------------------+
 
my %hash;
 
for my $elemento (@array) {                             # pasamos a hash indexado por la $clave
 
    my($concepto, $id, $clave) = @$elemento;
 
    push @{ $hash{$clave} }, [$concepto, $id];
}
 
# Última transformación: de hash a array principal
my @array;
for my $k (sort keys %hash) {
    my $table = HTML::Table->new(
#       -align=>'center',
        -border=>2,
        -data=> $hash{$k},
    );
    push @array, [$k, $table->getTable()];
}
 
 
say start_html(-encoding => 'utf-8');                           # iniciamos una página HTML
 
my $table = HTML::Table->new(
#    -rows=>26,
#    -cols=>2,
    -align=>'center',
#    -rules=>'rows',
    -border=>2,
#    -bgcolor=>'blue',
#    -width=>'50%',
    -spacing=>0,
    -padding=>0,
#    -style=>'color: blue',
#    -class=>'myclass',
#    -evenrowclass=>'even',
#    -oddrowclass=>'odd',
    -head=> ['Identificador', 'Descripción de reporte'],
    -data=> \@array,
);
 
$table->print();
 
say end_html();                                                 # cerramos el HTML
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Crear HASH con ARRAY Multidimensional

Crear HASH con ARRAY Multidimensional

Publicidad

Re: Crear HASH con ARRAY Multidimensional

Re: Crear HASH con ARRAY Multidimensional

¿Quién está conectado?