Foro - Perl en Español

por **explorer** » 2016-01-25 16:59 @749

Sí, sí que se entiende.

En realidad te puedes ahorrar la primera consulta para saber el espacio que necesitas reservar.

Perl incrementa de forma automática el tamaño de los array a medida que vamos metiendo elementos (con push() o unshift()).

Entonces, una forma sencilla de hacerlo sería:

vamos leyendo registro por registro
según el tipo de registro, lo metemos con push() en un array distinto (suponemos que trabajamos con pocas columnas)
al final, con scalar(@array) puedes saber el "tamaño" de @array, y de ahí deduces el mayor, y de ahí, lo puedes rellenar con valores nulos.
presentación

Hay otras formas... Con módulos como Text::Table se puede trabajar con datos en forma de tablas.

Mis soluciones propuestas intentan hacer la salida de forma inmediata, es decir, sacar la información en cuanto sea posible, sin esperar a leer toda la información a memoria.

## Conectarse a la base de datos
$dbh = DBI->connect( "DBI:mysql:$dbname;host=$dbhost", $dbuser, $dbpwd )
    or die "Error de conexion: $DBI::errstr";
 
## Leer los registros de la tabla
 
$sth = $dbh->prepare("select miembro, nombre, apellido1, apellido2 from miembros");
$sth->execute();
 
while ( my @data = $sth->fetchrow_array() ) {
 
    my $tipo = $data[0] -= 2;
    my $nombre = $data[1] . "" . $data[2] . "" . $data[3];
 
    if ( $tipo == 0 ) {
        push @{ $arrayM[$tipo] }, $nombre;
    }
    elsif ( $tipo == 1 ) {
        push @{ $arrayM[$tipo] }, $nombre;
    }
    else {
    }
 
    @arrayI = shift @{ $arrayM[0] };
    @arrayC = shift @{ $arrayM[1] };
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

¿Alguna idea de cómo hacer que la función scalar() funcione?

Un saludo,
gonzalo

por **explorer** » 2016-02-15 18:48 @825

Con

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

@arrayI = shift @{ $arrayM[0] };
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

estás extrayendo el primer elemento del array apuntado por $arrayM[0], y lo que contiene $arrayM[0] es una ref. a un array donde se guardan los elementos leídos del tipo 2.

Lo que no entiendo es porqué luego asignas ese elemento al array @arrayI.

¿Qué es lo que quieres hacer? ¿Puedes describir el procedimiento que quieres seguir?

por **gonzalos** » 2016-02-16 03:30 @188

Hola, explorer.

Eso viene de un mensaje anterior que entendí mal, y en el que me indicabas que guardara los datos del array en uno diferente y luego usara la función scalar(), para determinar cuál era mayor y así de esta manera asignar los espacios vacíos, allí donde se necesitaran.

Lo que quiero es, que una vez leídos y discriminados los datos de acuerdo a su tipo, determinar qué columna tiene mayor número de valores, para rellenar con espacios vacíos aquella que tenga menor número de datos.

Hasta igualar el número de celdas de las dos columnas.

Un saludo,
Gonzalo

por **explorer** » 2016-02-18 16:37 @734

Si usas

push @{ $arrayM[$tipo] },... ;

para guardar en la columna $tipo, entonces puedes saber el número de elementos con

scalar( @{ $arrayM[$tipo] } );

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

$ perl -E 'push @{$array[1]}, 42; say scalar @{$array[1]}; say $array[1][0]'

1

42
Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

por **gonzalos** » 2016-02-19 09:51 @452

Hola, explorer.

Ya había probado a hacerlo de esa forma

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

 print scalar (@{$arrayM[0]})
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Y obtengo una cosa, bastante reducida pero, tal que así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

111111333333666666666666666666777777778888888888888Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

No sé si es debido a que la versión de Perl que uso es la 5.14.2 del 2011. O es que algo estoy haciendo mal y que no alcanzo a comprender.

Un saludo
Gonzalo

por **explorer** » 2016-02-19 15:08 @672

Suena a que tienes metida la llamada a scalar() dentro del bucle de lectura de las filas.

¿No deberías llamarlo al final de la lectura? Me temo que no tienes claro los pasos que debes hacer para resolver el problema...

Te aconsejo que uses lápiz y papel hasta que consigas resolverlo de forma teórica (o sea, lápiz, papel y goma de borrar), y luego lo pasas a Perl. A lo mejor solo tienes que mover unas pocas líneas de sitio, pero debes saber qué líneas son.

por **gonzalos** » 2016-02-23 03:20 @181

Hola, explorer.

Gracias, tenías razón, se me había perdido un paréntesis de la vista y eso hacía que tuviera la llamada a la función dentro del bucle de lectura.

Seguimos hacia delante con el reto.

Un saludo,
Gonzalo

por **gonzalos** » 2016-02-25 09:35 @441

Hola a todos.

Después de darle algunas vueltas he encontrado una solución temporal:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!"C:\xampp\perl\bin\perl.exe"
use CGI qw<:standard *table>;
 
use strict;
use warnings;
use DBI;
use Data::Dumper;
 
 
my @tipo;
my @arrayM;
my $colaboradores;
my $total;
my $i;  
my $dbname = 'bd_ui_grupos_investigacion_2014';
my $dbhost = '127.0.0.1';
my $dbuser = 'root';
my $dbpwd = 'gonzalo';  
my ($sentencia, $dbh,$sth,$rv, $resultado,$r_row);
    
    
#pintar cabecera tabla
  print header;
  print start_html(
        -title      => 'Miembros',
        -encoding   => 'utf-8',
        -border => '2px',
    );
     
   print start_table({-border=>'1', -align=>'center'});
     
   print Tr(th(['Miembro principal', 'Miembro ayudante']));
     
     
 
## Conectarse a la base de datos
   $dbh = DBI->connect("DBI:mysql:$dbname;host=$dbhost", $dbuser, $dbpwd)
                     or die "Error de conexion: $DBI::errstr"; 
                     
# Leemos sus miembros constituyentes
   $sentencia = "SELECT  miembro,nombre,apellido1,apellido2
                 FROM miembros";
 
  $rv = $dbh->prepare($sentencia);
  $resultado=$rv->execute;  # Chequear el resultado
        
 
               
  if ($resultado>0){
      
     $r_row=$rv->fetchall_arrayref();
        
         foreach my $dato (@$r_row){
          
             my $tipo=$dato->[0]-=2;
             my $nombre=$dato->[1]." ".$dato->[2]." ".$dato->[3];   
              
                    if ($tipo==0){
                        push @{$arrayM[$tipo]},$nombre;
                    }elsif ($tipo==1){
                        push @{$arrayM[$tipo]},$nombre;
                    }else{
          
                    }         
        }
  }
 
## Desconectarse de la base de datos
 
  if (! $dbh->disconnect) {
     warn "Error al desconectarse de la base de datos: $DBI::errstr";
 }     
  
  
 # Asignar miembros y colaboradores
 
  if ($tipo==1){ 
     
       $colaboradores=@{$arrayM[1]};  
  }else{
      $colaboradores=undef;
  }
    my $miembros=@{$arrayM[0]};
  
  
# Determinar la variable con mayor número de datos
 
  if ($miembros > $colaboradores){
     
      $total=$miembros;
  }else{
      $total=$colaboradores;
  }
  for ($i=0; $i<=$total; $i++){
    
    print "<tr>";
    if ( @{$arrayM[0]} or @{$arrayM[1]}){
     
      my $columna1=shift @{$arrayM[0]};
      my $columna2=shift @{$arrayM[1]
      print "<td>$columna1</td><td>$columna2</td>";
    
    }else{   
    }
   print "</tr>";
 }
   
  print end_table;
  print end_html;
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Un saludo,
Gonzalo

por **explorer** » 2016-02-26 15:17 @678

Hay una serie de problemas, o curiosidades...

en las líneas 10 a 19 declaras las variables @tipo y $sth, pero luego no las usas (o sea, que sobran)
en la línea 27, dudo que exista un atributo 'border' para toda la página HTML, pero, podría ser
¿no te has dado cuenta de que las líneas 58 a 64 se reducen a solo la línea 59?
en la línea 77 haces referencia a la variable 77, pero nunca ha sido declarada ni inicializada, así que seguro que strict y warnings te estará sacando unos bonitos mensajes de error
en el for de la línea 94, $i está recorriendo los valores entre 0 y $total... con lo que entonces estamos dando $total+1 vueltas... Hummm... a mi me sobra una
falta una llave de cierre al final de la línea 100
si estás importando las funciones de generación de marcas HTML con la ayuda del módulo CGI, es un poco no usarlas en las líneas 96, 101 y 105

Esta es mi versión (no probada, claro). Si ves algo que no entiendas, por favor, pregunta.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!C:\xampp\perl\bin\perl.exe
 
use strict;
use warnings;
 
use DBI;
use CGI qw<:standard>;
 
## Acceso a la base de datos
my $dbname = 'bd_ui_grupos_investigacion_2014';
my $dbhost = '127.0.0.1';
my $dbuser = 'root';
my $dbpwd  = 'gonzalo';
 
 
## Conectarse a la base de datos
my $dbh
    = DBI->connect("DBI:mysql:$dbname;host=$dbhost", $dbuser, $dbpwd)
    or die "Error de conexion: $DBI::errstr"; 
 
# Leemos sus miembros constituyentes
my $sentencia
    = "
        SELECT
            miembro,nombre,apellido1,apellido2
        FROM
            miembros
    ";
 
my $rv = $dbh->prepare($sentencia);
my $resultado = $rv->execute();
 
my @personas;
 
if ($resultado > 0) {
    my $rows_ref = $rv->fetchall_arrayref();
 
    for my $row_ref (@$rows_ref) {
        my $tipo   = $row_ref->[0];
        my $nombre = join ' ', @{$row_ref}[1..3];
 
        push @{ $personas[$tipo - 2] }, $nombre;
    }
}
        
## Desconectarse de la base de datos
if (! $dbh->disconnect) {
    warn "Error al desconectarse de la base de datos: $DBI::errstr";
}
 
## Cálculo del valor de la columna más alta
my $total = @{$personas[0]} > @{$personas[1]}           # nos quedamos con el mayor resultado
          ? @{$personas[0]} : @{$personas[1]}
          ;
 
## Líneas de la tabla
my $tabla = Tr(th(['Miembro principal', 'Miembro ayudante'])) . "\n";
 
for my $i (0 .. $total-1) {
 
    my $miembro     = shift @{ $personas[0] };
    my $colaborador = shift @{ $personas[1] };
 
    $miembro     = 'null' if not defined $miembro;      # los shift() devuelven 'undef' si no hay más datos
    $colaborador = 'null' if not defined $colaborador;
 
    $tabla .= Tr(td([ $miembro, $colaborador])) . "\n";
}
 
## Tabla
$tabla = table({-border => '1', -align => 'center'}, "\n" . $tabla) . "\n";
 
## Salida
print
    header(),
    start_html(
        -title      => 'Miembros',
        -encoding   => 'utf-8',
    ),
    $tabla,
    end_html()
    ;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Tabla dinámica HTML

Re: Tabla dinámica HTML

Publicidad

Re: Tabla dinámica HTML

Re: Tabla dinámica HTML

Re: Tabla dinámica HTML

Re: Tabla dinámica HTML

Re: Tabla dinámica HTML

Re: Tabla dinámica HTML

Re: Tabla dinámica HTML

Re: Tabla dinámica HTML

Re: Tabla dinámica HTML

¿Quién está conectado?