Foro - Perl en Español

por **jimr1984** » 2016-02-19 15:10 @674

Hola a todos por favor si pueden ayudarme, con una expresión regular o alguna forma de extraer cierto contenido. Paso a detallar.

URL que utilizo, método POST: http://www.cual-es-mi-ip.net/geolocalizar-ip-mapa direccion-ip = 200.58.44.25

NOTA: no he visto que pueda ser algo ilegal lo que se está solicitando.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub GEOLOCALIZAR {
   my ($ipd) = @_;
   my $url = "http://www.cual-es-mi-ip.net/geolocalizar-ip-mapa";
   my $ua = LWP::UserAgent->new();
   my $req = HTTP::Request->new(POST => $url) ;
   my $post_data = "direccion-ip=".$ipd;
      $req->content_type('application/x-www-form-urlencoded');
      $req->content($post_data);
 
   my $resp = $ua->request($req);
   my $message = $resp->content();  # <---- el contenido de la web lo guardo en $message   ¡OJO! tiene multilíneas
   &EXTRAER_INFORMACION($message);
}
 
sub EXTRAER_INFORMACION
{
    my ($contenido) = @_;
   my ($pais,$ciudad,$latitud,$longitud,$isp);
    if ($contenido =~ / AQUI EL FILTRO/)
    {
     print $pais = $1;
     print $ciudad= $2;
     print $latitud= $3;
     print $longitud= $4;
     print $isp= $5;
    }
}
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

El código fuente de la web es:

Sintáxis: [ Descargar ] [ Ocultar ]

Using html4strict Syntax Highlighting

<div class="panel panel-default">
                    <div class="panel-body">
                        <div class="row">
                            <div class="col-md-12">
                                <table class="table table-striped">
                                    <tbody>
                                    <tr>
                                        <td>País</td>
                                        <td><strong>United States</strong></td>
                                    </tr>
                                    <tr>
                                        <td>Ciudad</td>
                                        <td><strong></strong></td>
                                    </tr>
                                    <tr>
                                        <td>Latitud</td>
                                        <td id="latitud" data-latitud="38"><strong>38</strong></td>
                                    </tr>
                                    <tr>
                                        <td>Longitud</td>
                                        <td id="longitud" data-longitud="-97"><strong>-97</strong></td>
                                    </tr>
                                    <tr>
                                        <td>ISP</td>
                                        <td><strong>Verizon Business</strong></td>
                                    </tr>
                                    </tbody>
                                </table>
                            </div>
                        </div>
                    </div>
                </div>
            </div>
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Por favor, necesito extraer la información que devuelve la página, solo los valores de los campos que señalé.
¿Cómo puedo hacerlo o resolverlo?

Muchas gracias.

#!/usr/bin/env perl
use feature 'say';
 
my $HTML = <<EOHTML;
<div class="panel panel-default">
    <div class="panel-body">
        <div class="row">
            <div class="col-md-12">
                <table class="table table-striped">
                    <tbody>
                        <tr>
                            <td>País</td>
                            <td><strong>United States</strong></td>
                        </tr>
                        <tr>
                            <td>Ciudad</td>
                            <td><strong></strong></td>
                        </tr>
                        <tr>
                            <td>Latitud</td>
                            <td id="latitud" data-latitud="38"><strong>38</strong></td>
                        </tr>
                        <tr>
                            <td>Longitud</td>
                            <td id="longitud" data-longitud="-97"><strong>-97</strong></td>
                        </tr>
                        <tr>
                            <td>ISP</td>
                            <td><strong>Verizon Business</strong></td>
                        </tr>
                    </tbody>
                </table>
            </div>
        </div>
    </div>
</div>
EOHTML
 
my($pais, $ciudad, $latitud, $longitud, $isp) =
    $HTML =~
            m{
                <td .+? >
                <strong>
                (.*?)
                </strong>
                </td>
            }msxg;
 
say "$pais, $ciudad, $latitud, $longitud, $isp";  # United States, , 38, -97, Verizon Business
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **jimr1984** » 2016-02-24 14:52 @661

Muchas gracias por la ayuda, pero NO comprendo esta parte:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$HTML =~
            m{
                <td .+? >
                <strong>
                (.*?)
                </strong>
                </td>
            }msxg;   # <... esto no comprendo  ¿ msxg ?
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

¿esto sería de otra forma?

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$HTML =~ m/\<td.+?\>\<strong\>(.*?)\<\/strong\>\<\/td\>/g
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2016-02-24 16:33 @731

Sí, es lo mismo, pero usas demasiadas \barras \diagonales \inversas :wink:

Más en concreto: en Perl no necesitas "escapar" con barras a los caracteres '<' y '>', con lo que tu exp. reg.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$HTML =~ m/\<td.+?\>\<strong\>(.*?)\<\/strong\>\<\/td\>/g;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

se queda en

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$HTML =~ m/<td.+?><strong>(.*?)<\/strong><\/td>/g;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Aún tenemos que usar un par de barras diagonales inversas debido a la presencia de barras normales '/' que se podrían confundir con los delimitadores del patrón, lo cual es... un fastidio. Y como somos programadores de Perl, no nos gusta eso. Así que... rompemos las reglas, cambiando los delimitadores:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$HTML =~ m{<td.+?><strong>(.*?)</strong></td>}g;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Ahora, con las llaves, Perl ya sabe que las barras diagonales son puro texto, no delimitadores. Pero... ahora hay otro tipo de problemas.

¿Estamos completamente seguros que entre los caracteres con los que los comodines '.' coinciden no debería haber caracteres de fin de línea? A fin de cuentas, esto es HTML, y puede haber caracteres de fin de línea en cualquier parte, sin que la presentación visual -para el usuario- cambie.

Entonces, podemos tener la precaución de decir que los '.' también coincidan con los caracteres de fin de línea. Eso lo conseguimos añadiendo la opción '/s' al final del patrón. Además, solo por costumbre, es también bueno poner la opción '/m', que le da un significado nuevo a las anclas '^' y '$', aunque en este patrón ni aparezcan. Pero es bueno porque así le es más fácil de aprender exp. reg. a los novatos.

La opción '/g' es para que aplique el patrón de forma repetida, a lo largo de todo $HTML. El resultado de la exp. reg. será una lista de elementos, cada uno de los cuales contendrá lo capturado por los paréntesis.

Finalmente, queda la opción '/x', que permite escribir el patrón con espacios, para que quede mejor formateado, más bonito. Incluso hasta podemos poner comentarios:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$HTML =~
        m{
            <td .+? >   # buscamos una marca de inicio de celda de tabla
            <strong>    # que contenga una marca de negrita
            (.*?)       # capturamos todo lo que haya, hasta la próxima
            </strong>   # marca de fin de negrita
            </td>       # que preceda a una marca de fin de celda
         }msxg;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Ahora que lo veo... sobra la parte '</td>'. De hecho, se puede quedar así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$HTML =~ m/<td.+?><strong>(.*?)</sg;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Para terminar... si quieres puedes aumentar la robustez de la exp. reg., por si en el futuro cambiase un poco el formato HTML de esa página. Supongamos que le añaden espacios en blanco, a veces, por descuido, entre las marcas HTML. Entonces es mejor prevenirlo con algo así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$HTML =~ m/<td.+?>\s*<strong>\s*(.*?)\s*</sg;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Extraer contenido específico

Extraer contenido específico

Publicidad

Re: Extraer contenido específico

Re: Extraer contenido específico

Re: Extraer contenido específico

¿Quién está conectado?