Foro - Perl en Español

por **korsakof** » 2016-04-14 03:25 @184

Hola.

Gracias por tu respuesta. Tengo varias listas, ¿crearías un módulo o varios?

¿A niveles de rendimiento se notaría? El tema es que tiene que leer bastantes GB de líneas.

Un saludo.

Hola.

Así quedó mi módulo pero tengo unos cuantos problemas a la hora de llamarlo ya que por cada lista tengo que tener un fichero de estos ya que accedo por el package (SecIP::getNumeroElementos(), por ej., para hacer uso de un método) y al tener varias listas tengo que ir cambiando el nombre al package SecIP1, SecIP2, etc... ya que cada package apunta a un fichero diferente. No sé cómo solucionar esto.

Paquete que uso:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

package SecIP;
use strict;
use warnings;
require Exporter;
our @ISA = qw(Exporter);
 
our $VERSION   = 1.00;
our @EXPORT_OK = qw(build_ip_table %lista getNumeroElementos existeElemento getHash);
 
our %lista;
 
sub build_ip_table {
    my ($ruta) = @_;
    if ( !open( URL, $ruta ) ) {
        return;
    }
    else {
        my (@url) = <URL>;
        chomp(@url);
        close(URL);
        %lista = map { $_ => 1 } @url;
    }
}
 
1;
 
sub getNumeroElementos {
    return keys %lista;
}
1;
 
sub existeElemento {
    my ($elemento) = @_;
    return exists $SecIP::lista{$elemento};
}
1;
 
sub getHash {
    return \%lista;
}
1;
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Aparte, programando el módulo me han surgido un par de dudas de conceptos de Perl.

Duda 1: El siguiente código lo he visto en todos los módulos y no sé exactamente lo que realizan esas líneas. Me he leído varias veces la documentación de Perl y sigo sin entender por qué hay que usarlas.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

our @ISA = qw(Exporter);
our $VERSION = 1.00;
our @EXPORT_OK = qw(build_ip_table %lista getNumeroElementos existeElemento getHash);
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Duda 2:
La siguiente es, qué diferencia hay entre las variable my, our, $, @... ¿por qué existen tantos tipos? ¿En qué se diferencian?

Muchas gracias por la ayuda. Un saludo.

por **explorer** » 2016-04-24 11:48 @533

Yo creo que lo estás complicando demasiado: no necesitas crear módulos para ir almacenando las URL que vas leyendo de los archivos. Todo eso lo puedes hacer desde el propio programa, metiéndolo todo en un único hash.

El array especial @ISA muestra la relación padre-hijo entre nuestro módulo y otros. En tu caso, estás heredando las funciones y métodos del módulo Exporter (ver secciones "Perl Classes y Perl Modules" en tu propio ordenador en perldoc perlmod, y en la Web (traducido al español)).

La variable $VERSION indica a la gente de fuera (otros programas y módulos) en qué versión está nuestro programa o módulo.

La variable @EXPORT_OK indica la relación de variables y funciones que, opcionalmente, otros programas y módulos pueden importar desde el nuestro.

Lo que las líneas 1 y 3 están haciendo es indicar que esto es un módulo del que podemos exportar una serie de variables y funciones, a otros programas y módulos, y así no es necesario poner el nombre completo para acceder a ellos.

Ejemplo, si en un programa ponemos

use SecIP qw(%lista);

entonces en ese programa podemos acceder a %lista de forma directa:

say $lista{$clave};

Si no lo hiciéramos así, estaríamos obligados a escribirlo así:

say $SecIP::lista{$clave};

my() y our() son dos funciones que declaran variables. my() declara variables en un ámbito léxico (local a un contexto), mientras que our() declara variables globales al paquete en donde nos encontremos. La diferencia entre los dos es que, mientras que my() declara nuevas variables, our() crea alias a variables globales preexistentes. Más información en perldoc -f my y perldoc -f our

'$' es el sigilo de las variables escalares. '@' es el sigilo de las variables array. '%' es el sigilo de las variables hash. Más información en tu propio ordenador en perldoc perldata, y en la Web (traducido al español).

Otro detalle: los '1' que aparecen repetidos en tu código.

Cuando Perl carga un módulo, lo ejecuta, por si resulta que dentro de él existe algún código de inicialización. Si, la última instrucción ejecutada dentro del módulo es 'verdadera', se dice entonces que la carga del módulo es correcta y se sigue adelante. Si no, se para con un error.

Como la mayoría de los módulos no tiene código de inicialización, o ese código no sabemos qué va a devolver o si no nos importa lo que haga, tenemos que asegurarnos que la carga del módulo devuelva siempre un valor 'verdadero'. Esa es la razón por la cual muchos módulos terminan con un '1;'. Como es una sentencia que se puede ejecutar, y estará hacia el final, estamos enviando ese valor 'verdadero' al módulo o programa que ha cargado nuestro módulo.

Por eso, en tu código... sobran todos los '1;', excepto el último

Otra forma, en lugar de usar módulos, es usar objetos:

Sintáxis: (SecIP.pm) [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
package SecIP;
use strict;
use warnings;
use autodie;
 
sub new {
    my $clase = shift;
    my $ruta  = shift;
 
    open my $URL, '<', $ruta;
    my (@url) = <$URL>;
    chomp(@url);
    close $URL;
 
    my %lista = map { $_ => 1 } @url;
    my $self  = \%lista;
 
    bless $self, $clase;
 
    return $self;
}
 
sub getNumeroElementos {
    my $self = shift;
 
    return scalar keys %{$self};
}
 
sub existeElemento {
    my $self     = shift;
    my $elemento = shift;
 
    return exists $self->{$elemento};
}
 
sub getHash {
    my $self = shift;
 
    return {%{$self}};
}
 
1;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Sintáxis: (SecIP.pl) [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use v5.14;
use Data::Dumper;
 
use SecIP;
 
for my $archivo (glob "lista*txt") {
    my $secip = SecIP->new($archivo);           # creamos un objeto
 
    say $secip->getNumeroElementos();           # número de elementos leídos
 
    my $hash_ref = $secip->getHash();           # obtenemos el hash construido
 
    say Dumper $hash_ref;                       # lo volcamos en pantalla, para ver qué aspecto tiene
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Pero... para este problema, yo creo que no es necesario usar ni módulos ni objetos.

por **korsakof** » 2016-04-26 01:58 @123

Hola.

¡¡¡Muchas gracias por la ayuda!!!

Sí que necesito que sean independientes entre sí ya que cada fichero almacena datos para una función. De esta forma podré crear objetos y usarlos a lo largo del código.

Por último, un par de líneas que no entendí.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

 my $self  = \%lista; # --> ¿referencia a la lista creada?
 
    bless $self, $clase; # --> Asocia ese objeto a la clase desde la cual se está generado, ¿no?
 
#En la función get_Hash la orden en el return
  return {%{$self}}; #--> ¿Referencia al hash o una copia?
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Gracias de nuevo. Un saludo.

por **explorer** » 2016-04-26 05:29 @270

korsakof escribiste:

Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using perl Syntax Highlighting

my $self = \%lista; # --> ¿referencia a la lista creada? Sí

bless $self, $clase; # --> Asocia ese objeto a la clase desde la cual se está generado, ¿no?

# Más bien, es algo así: bautizamos el objeto $self con el nombre de $clase.

# A partir de ese momento, $self es una instancia (un objeto) de la $clase

#En la función get_Hash la orden en el return

return {%{$self}}; #--> ¿Referencia al hash o una copia?

# Bueno, esto es algo complicado... y un poco sucio. Seguro que se puede mejorar.

# $self es un objeto de la $clase.

# Como $self realmente es una referencia a un hash, pues lo desreferenciamos con %{...}.

# El resultado es un hash (lista de elementos, pares de claves/valores).

# Dentro de unas llaves, lo que estamos haciendo es crear un hash anónimo,

# cuyos contenidos son los mismos que los que los del hash del objeto.

# Como es un hash anónimo, return devuelve la referencia a ese hash.

# se pondría pensar que la línea equivale a

return $self;

# ya que estamos devolviendo una referencia a un hash... pero no es del todo exacto.

# Realmente estamos devolviendo una ref. a un hash, que está bautizada como $clase, así que

# es una ref. a un objeto. Si le hacemos un Dump, saldrá el contenido del hash,

# junto con una marca que indica que pertenece al espacio de nombres $clase

# En situaciones normales, valdría, pero si queremos ->exclusivamente<- el hash -los datos-

# entonces una forma es sacarlos así. Otra hubiera sido crear un accesor más claro (recorrer el hash, por ejemplo).

Coloreado en 0.002 segundos, usando GeSHi 1.0.8.4

por **korsakof** » 2016-05-26 04:11 @216

Muchas gracias, creo que entendí todo.

Foro - Perl en Español

Manejar varios ficheros de texto

Re: Manejar varios ficheros de texto

Publicidad

Re: Manejar varios ficheros de texto

Re: Manejar varios ficheros de texto

Re: Manejar varios ficheros de texto

Re: Manejar varios ficheros de texto

Re: Manejar varios ficheros de texto

Re: Manejar varios ficheros de texto

¿Quién está conectado?