Foro - Perl en Español

por **pablgonz** » 2016-07-04 07:59 @374

Hola a todos de nuevo, estoy tratando de crear un %hash con algunas frases que necesito cambiar.

Las palabras se encuentran dentro de un array y usando map, agrego un mismo texto a todas las palabras contenidas y luego armo el %hash. El código es el siguiente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use v5.22;
use Data::Dumper;
 
### @array con las palabras de entorno
my @ext_env  = qw (
    postscript tikzpicture pgfpicture ganttchart circuitikz
    forest tikzcd dependency pspicture psgraph
    );
 
### añado \begin{
my $begin_env = join "\n", map { qq/\\begin\{$_/ } @ext_env;
my @begin_env  = split /\n/, $begin_env;
 
### añado \BEGIN{
my $Begin_env = join "\n", map { qq/\\BEGIN\{$_/ } @ext_env;
my @Begin_env  = split /\n/, $Begin_env;
 
### añado \end{
my $end_env = join "\n", map { qq/\\end\{$_/ } @ext_env;
my @end_env  = split /\n/, $end_env;
 
### añado \END{
my $End_env = join "\n", map { qq/\\END\{$_/ } @ext_env;
my @End_env  = split /\n/, $End_env;
 
### ahora creamos %hash con las palabras cambiadas
my %begenv_in;
@begenv_in{@begin_env} = @Begin_env;
my %endenv_in;
@endenv_in{@end_env} = @End_env;
 
### juntamos todo en un solo %hash
my %cambios_in = (%begenv_in, %endenv_in);
 
print Dumper(\%cambios_in);
 
__END__
 
Coloreado en 0.005 segundos,  usando GeSHi 1.0.8.4

logro armar el %hash, pero son muchas líneas (según yo) y repetiré el código con otro array. Sé que con map puedo armar directamente el %hash. ¿Puedo hacer el código más corto?

Saludos,
Pablo

#!/usr/bin/env perl
use v5.22;
 
my @ext_env  = qw (
    postscript    tikzpicture pgfpicture ganttchart circuitikz
    forest tikzcd dependency  pspicture  psgraph
);
 
my %cambios_in;
 
for my $ext_env (@ext_env) {
    for my $prefix (qw(begin end)) {
        $cambios_in{"\\$prefix\{$ext_env"} = "\\\U$prefix\E\{$ext_env";
    }
}
 
use Data::Dumper;
say Dumper \%cambios_in;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **pablgonz** » 2016-07-04 20:45 @906

Genial, tu solución, como siempre, funciona perfecto, me has ahorrado un montón de my

Para variar, un par de consultas:
1. Cuando usas \U$prefix\E, funciona como uc, ¿estoy en lo correcto?
2. Como tengo varios @array sobre los cuales deseo efectuar la misma operación para crear un %hash, ¿Se podría escribir el código como una función? Algo como my %nombre_hash = crearhash(@array);.

Agradecido,
Pablo

por **explorer** » 2016-07-07 16:34 @732

1. En efecto. Perl tiene unas pocas secuencias de escape que hacen ese trabajo. Están descritas en la sección Quote and Quote-like Operators de perlop.

2. Sí que se puede escribir una función, pero hay que tener cuidado de un detalle: cuando pasamos un array como argumento a una función, Perl 5 (pero no Perl 6) "aplana" el contenido del array. Eso quiere decir que, en realidad, estamos pasando como argumentos todos los elementos del array. Si el array tiene centenares o miles de elementos, puede enlentecerse mucho el programa. Y lo mismo a la salida: si queremos un hash, pues eso implica pares de claves/valores. Si son muchos, pues más lentitud.

Si son pequeños, pues puede valer hacerlo de esa manera. Si no, es mejor pasar referencias:

my $nombre_hash_ref = crearhash(\@array);

De esa manera, solo estamos pasando un único valor a la entrada (un escalar, que es una referencia al verdadero array). Y a la salida, devolvemos también un único valor (otro escalar, que es la referencia al hash que hemos creado dentro de la función.

Por ejemplo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use v5.22;
use feature 'signatures';                      # estas dos líneas permiten que las sub tengan parámetros
no warnings "experimental::signatures";        # en la definición (firmas de subrutinas)
 
 
my @ext_env  = qw (
        postscript    tikzpicture pgfpicture ganttchart circuitikz
        forest tikzcd dependency  pspicture  psgraph
);
 
my $cambios_in_ref = crearhash(\@ext_env);     # pasamos el array como referencia
 
say $cambios_in_ref->{'\\begin{forest'};       # ejemplo de acceso al hash desde su ref.
 
my %cambios_in = %{crearhash(\@ext_env)};      # otro ejemplo: convertimos la ref. de hash en hash (más bien, copiamos uno en otro)
 
say $cambios_in{'\\begin{forest'};             # acceso al hash de forma normal
 
 
sub crearhash ($array_ref) {                   # la referencia que recibimos
    my %cambios;                               # aquí guardamos el resultado
 
    for my $item (@{$array_ref}) {             # recorremos el array
        for my $prefix (qw(begin end)) {
            $cambios{"\\$prefix\{$item"} = "\\\U$prefix\E\{$item";
        }
    }
 
    return \%cambios;                          # devolvemos una ref. al hash
}
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

por **pablgonz** » 2016-07-08 14:09 @631

Gracias por la respuesta, la verdad es que los @array con los que voy a trabajar son muy pequeños, como máximo tendrán 50 elementos (en un caso extremo) y la verdad es que el hash creado solo lo usaré en una expresión regular, es decir, no accederé a las claves de este de manera individual.

Estuve buscando un poco de información sobre cómo pasar un @array a una función y devolver un %hash y me topé con las referencias y los prototipos para estos casos, eso sí, el pragma use feature 'signatures'; no lo había visto.

Lo dejé así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use v5.22;
use Data::Dumper;
 
# array 
my @verb_write = qw (
    filecontents tcboutputlisting tcbexternal extcolorbox
    extikzpicture VerbatimOut verbatimwrite
    );
 
my @ext_env  = qw (
        postscript    tikzpicture pgfpicture ganttchart circuitikz
        forest tikzcd dependency  pspicture  psgraph
);
 
# hash
my %cambios_in = crearhash(@verb_write);
 
my %combios_out = crearhash(@ext_env);
 
# subrutina
sub crearhash{
        my %cambios;
 
    for my $aentra(@_){
                for my $prefix (qw(begin end)) {
                $cambios{"\\$prefix\{$aentra"} = "\\\U$prefix\E\{$aentra";
                        }
                }
    return %cambios;
}
 
# regex
my %cambio = (%cambios_in);
my $busco = join "|", map {quotemeta} sort { length($a)<=>length($b) } keys %cambio;
    
print  Dumper $busco;
 
__END__
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

¿Se puede escribir la función pasando referencias sin ocupar use feature 'signatures';?

Saludos,
Pablo

por **explorer** » 2016-07-08 17:03 @752

Claro, accediendo al array especial @_, como siempre.

por **pablgonz** » 2016-07-08 19:58 @873

Entonces, ¿la variable especial @_ ya es una referencia al @array de entrada (o a una lista)?

Pensé que se debía declarar de forma explicita la referencia, evitando usar prototipos, algo como:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

# subrutina dos usando referencias
sub crearhash_dos{
    my %cambios;
    my ($array_ref) = @_;
    my @entrada = @{ $array_ref }; 
    for my $aentra(@entrada){
        for my $prefix (qw(begin end)) {
            $cambios{"\\$prefix\{$aentra"} = "\\\U$prefix\E\{$aentra";
        }
    }
    return %cambios;
}
 
my %cambios_tmp = crearhash_dos(\@ext_env);
print  Dumper \%cambios_tmp;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Si entendí bien, esta subrutina sería equivalente a la primera subrutina que escribí en la cual pasaba el array de entrada a la variable especial @_.

Agradecido por las respuestas y la explicaciones

Pablo

por **explorer** » 2016-07-09 06:12 @300

La variable @_ almacena los argumentos que se pasan a la subrutina.

Si es una referencia, pues es un solo argumento, un solo elemento dentro de @_.
Si es un array (desplegado), pues entonces hay tantos elementos dentro de @_ como elementos hay en el array:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

crearhash(@array);
 
sub crearhash {
    my @array = @_;
    for my $aentra (@array) {
       ...;
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

o incluso, más rápido y directo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

crearhash(@array);
 
sub crearhash {
    for my $aentra (@_) {
       ...;
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **pablgonz** » 2016-07-13 11:48 @533

Muchas gracias por la explicación, ajustaré algunas líneas de otras cosas que he escrito usando esta información.

Saludos,
Pablo

Foro - Perl en Español

Crear un hash a partir de array usando map

Crear un hash a partir de array usando map

Publicidad

Re: Crear un hash a partir de array usando map

Re: Crear un hash a partir de array usando map

Re: Crear un hash a partir de array usando map

Re: Crear un hash a partir de array usando map

Re: Crear un hash a partir de array usando map

Re: Crear un hash a partir de array usando map

Re: Crear un hash a partir de array usando map

Re: Crear un hash a partir de array usando map

¿Quién está conectado?