Foro - Perl en Español

por **abraham03** » 2016-08-05 16:30 @729

Hola.

¿Cómo hago para agregar una búsqueda y extracción de diferentes combinaciones de palabras?

Tengo un archivo de texto como este:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

#name_file

Bacteria;WS3;PRR-12;SSS58A      0.0     0.12    0.6

Bacteria;WS3;PRR-12;Sediment-1  0.5     0.1     0.3

Bacteria;Terrabacteria_group;Firmicutes;Bacilli; unclassified_Bacillales;Bacillaceae;Vulcanibacillu     0.2     0.2     0.6

Bacteria;Terrabacteria_group;Firmicutes;Bacilli;Bacillales;Bacillaceae;Vulcanibacillu   0.2     0.2     0.6

Bacteria;Terrabacteria_group;Firmicutes;Bacilli;Bacillales;Bacillales_incertae_sedis;Bacillales_Family_X        0.1     0.3     0.5

Bacteria;Terrabacteria_group;Firmicutes;Bacilli;Bacillales;Bacillales_incertae_sedis;Bacillales_Family_X._Incertae_Sedis;Thermicanus    0.4     0.13    0.9

Bacteria;Nitrospirae;Nitrospira;Nitrospirales;Thermodesulfovibrionaceae 0.1     0.2     0.6

Bacteria;Nitrospirae;Nitrospira;Nitrospirales;Thermodesulfovibrionaceae;BD2-6   0.0     0.0     0.6

Bacteria;PVC_group;Lentisphaerae;Lentisphaeria;Lentisphaerales  0.7     0.2     0.1Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

y quiero extraer la primera, y si existe, una segunda palabra (pero no la tercera) que tenga la terminación en 'ales' de cada línea y que se imprima como

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

 Bacillales

 Bacillales;Bacillales_incertae_sedis 

 Bacillales;Bacillales_incertae_sedis

 Nitrospirales

 Nitrospirales

 LentisphaeralesColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

La segunda siempre termina como estos ejemplos:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

Bacillales_incertae_sedis, Nitrospirales_incertae_sedis Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

es decir: \w*ales_incertae_sedis
Ignorar si presenta una tercera como aparece en Bacillales_Family.

El problema que tengo es una coincidencia con múltiples opciones en la línea

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my (@orden) = ($taxon=~ m/(\w*ales)[\;]?/g)
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Este es el código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use strict;
 
use warnings;
 
use Getopt::Long;
 
GetOptions( 'i=s' => \$infile, );
 
open INFILE, '<', "$infile", or die "cant open file $infile";
 
open OUTFILE, '>', "$results.txt" or die "cant open";
 
while (<INFILE>) {
    my $line = $_;
    chomp($line);
 
    if ( $line =~ m/^#/g ) {
        next;
    }
 
    elsif ( $line =~ m/^$/g ) {
        next;
    }
 
    elsif ($line) {
        my @taxonomic = $_;
        foreach (@taxonomic) {
            ( $taxon, $val1, $val2, $val3 ) = split( /\t/, $_ );
        }
 
        # here is the problem
        my (@orden) = ( $taxon =~ m/(\w*ales)[\;]?/g );
        foreach (@orden) {
            if ( $_ =~ m/^$/g ) {
                next;
            }
            elsif ( $_ =~ m/^unclassified/g ) {
                next;
            }
 
            else {
                print OUTFILE "$_\n";
            }
        }
        close INFILE;
        close OUTFILE;
        exit;
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

He intentado esto:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

    my (@orden) = ($taxon=~ m/(\w*ales)[\;]?(;\w*ales_incertae_sedis)/g);
    my (@orden) = ($taxon=~ m/(\w*ales[;\w*ales_incertae_sedis]?)[\;]?/g);
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

pero no me resuelve el problema.

Muchas gracias.

#!/usr/bin/env perl
use strict;
use warnings;
use autodie;
 
open my $INFILE, '<', "taxones.txt";
 
while (my $linea = <$INFILE>) {
    chomp $linea;
    next if not $linea  or  $linea =~ /^#/;
 
    my ($taxon, $val1, $val2, $val3) = split /\t/, $linea;
 
    my @ordenes = split /[;]/, $taxon;
 
    my @interesa;
 
    for my $orden (@ordenes) {
        if ($orden =~ /^\w+ales(?:_incertae_sedis)?$/) {
            push @interesa, $orden;
        }
    }
 
    # print "[$linea]\n";
    print join(";", @interesa), "\n" if @interesa;
}
 
close $INFILE;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Recorremos las distintas partes de @ordenes, que es la parte del $taxon, pero partíendolo por los ';'.
Por cada uno de ellos, comprobamos si satisface la expresión regular, que es $orden =~ /^\w+ales(?:_incertae_sedis)?$/, que quiere decir:

desde el principio (^) hasta el final ($), $orden debe consistir en
uno o más caracteres alfanuméricos (\w+) seguidos por 'ales'
opcionalmente (?) seguidos por '_incertae_sedis' (la expresión '?:' indica que los paréntesis no capturan, solo agrupan)

Si encontramos lo que queremos, lo guardamos en @interesa. La salida es idéntica a lo que mostrabas.

Pero no sé si he interpretado bien algunas cosas, como por ejemplo, "quiero extraer la primera, y si existe, una segunda palabra (pero no la tercera)".

por **abraham03** » 2016-08-09 11:06 @504

Muchas gracias, lo voy a implementar

Sí, de hecho interpretaste bien: sale justo como lo quería.

Oye: siempre he seguido tus comentarios en el foro. Cuando respondes a otras personas siempre se me ha hecho muy limpio y sencillo tu manera de programar.

¿De casualidad tendrás algún manual hecho por ti mismo que me pudieras facilitar? Creo que me sería de gran utilidad.

Saludos y muchas gracias.

Abraham

por **explorer** » 2016-08-10 07:12 @342

Mi forma de programar es el resultado de:

leer mucho código de otras personas, y fijarme en cómo lo han hecho. Aprender de los aciertos de los buenos y de los errores de los malos
leer el libro "Perl Best Practices", de Damian Conway.

Foro - Perl en Español

Extraer palabras con múltiples opciones

Extraer palabras con múltiples opciones

Publicidad

Re: Extraer palabras con múltiples opciones

Re: Extraer palabras con múltiples opciones

Re: Extraer palabras con múltiples opciones

¿Quién está conectado?