Foro - Perl en Español

por **angelluigi** » 2016-12-13 04:38 @234

Muy buenas.

Me están pidiendo que dada una fecha sea capaz de dar la fecha del día siguiente usando una subrutina del tipo acción. Yo he hecho una usando referencias que es capaz de hacerla pero no sé si es la forma correcta.

Otro problema que tengo es que, en los meses, si intento poner valores numéricos me da problema el último día del año: si pongo 31-12-4 me da 1-13-4.

Muchas gracias y perdón por las molestias

Este es el código con el mes con número

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub nexdate {
my ($day,$month,$year) = @_;
if(($$month=~/1|3|5|7|8|10/) &&($$day < 31)){
$$day = $$day+1; $$month=$$month;$$year=$$year;}
elsif(($$month=~ /1|3|5|7|8|10/) && ($$day= 31)){
$$day=1 , $$month = $$month+1,$$year=$$year;}
elsif (($$month=~/4|6|9|11/i) && ($$day < 30)){
$$day = $$day+1,$$month =$$month, $$year =$$year;}
elsif (($$month=~/4|6|9|11/i) && ($$day = 30)){
$$day =1,$$month =$$month +1, $$year =$$year;}
 
elsif (($$month=~ /2/)&& ($$day <28)){
$$day =$$day +1,$$month =$$month , $$year =$$year;}
elsif(($$month=~ /2/) && ($$day=28)){
$$day=1 , $$month = $$month+1,$$year=$$year;}
 
elsif (($$month=~ /12/)&& ($$day <31)){
$$day =$$day +1,$$month =$$month , $$year =$$year;}
elsif (($$month=~ /12/)&& ($$day =31)){
$$day =1,$$month=1, $$year=$$year+1;}
 
else {print "La siguiente fecha es errónea: ";}
 
}
print "Enter the date :\n";
print "day :";
my $Day =<STDIN>;
chomp $Day;
print "month :";
$Month =<STDIN>;
chomp $Month;
print "year :";
$Year =<STDIN>;
chomp $Year;
 
nexdate(\$Day,\$Month,\$Year);
print $Day,"-",$Month,"-",$Year;
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

Este es el código con el mes con caracteres

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub nexdate {
my ($day,$month,$year) = @_;
if(($$month=~/January|March|May|July|August|October/i) &&($$day < 31)){
$$day = $$day+1; $$month=$$month;$$year=$$year;}
elsif(($$month=~ /January|March|May|July|August|October/i) && ($$day= 31)){
$$day=1 , $$month = $$month+1,$$year=$$year;}
 
elsif (($$month=~/April|Juny|September|November/i) && ($$day < 30)){
$$day = $$day+1,$$month =$$month, $$year =$$year;}
elsif (($$month=~/April|Juny|September|November/i) && ($$day = 30)){
$$day =1,$$month =$$month +1, $$year =$$year;}
 
elsif (($month=~ /February/i)&& ($day <28)){
$$day =$$day +1,$$month =$$month , $$year =$$year;}
elsif(($$month=~ /February/i) && ($$day=28)){
$$day=1 , $$month = $$month+1,$$year=$$year;}
 
elsif (($$month=~ /December/i)&& ($$day <31)){
$$day =$$day +1,$$month =$$month , $$year =$$year;}
elsif (($$month=~ /December/i)&& ($$day==31)){
$$day =1,$$month=January, $$year=$$year+1;}
 
else {print "The next date isn't correct: ";}
 
 
}
 
 
 
 
 
 
print "Enter the date :\n";
print "day: ";
my $Day =<STDIN>,"\n";
chomp $Day;
print "month: ";
$Month =<STDIN>,"\n";
chomp $Month;
print "year: ";
$Year =<STDIN>;
chomp $Year;
 
nexdate(\$Day,\$Month,\$Year);
print $Day,"-",$Month,"-",$Year;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

use strict;
use warnings;
use Date::Calc qw(Add_Delta_Days check_date);
 
sub nextdate{
        my ($ref_Day, $ref_Month, $ref_Year) = @_;
 
        if ( check_date(${$ref_Year}, ${$ref_Month} , ${$ref_Day} ) ){
 
                (${$ref_Year}, ${$ref_Month} , ${$ref_Day} ) = Add_Delta_Days( ${$ref_Year}, ${$ref_Month} , ${$ref_Day}, 1); # sumas 'delta' días deseados
 
        }
        else{
                print "la fecha es erronea\n";
        }
}
 
system('cls');
 
print "Enter the date :\n";
print "day :";
my $Day =<STDIN>;
chomp $Day;
print "month :";
my $Month =<STDIN>;
chomp $Month;
print "year :";
my $Year =<STDIN>;
chomp $Year;
 
nextdate(\$Day, \$Month, \$Year);
 
print $Day,"-",$Month,"-",$Year;
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Éxitos

por **explorer** » 2016-12-13 12:20 @555

Es demasiado complicado lo que quieres hacer.

Mira una posible solución:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
#
# Calcula el día siguiente a partir de la fecha entrada por el usuario.
#
# Joaquín Ferrero. 2016/12/13
#
use v5.10.1;
 
use Date::Calc qw(Add_Delta_YMD Decode_Date_EU Date_to_Text);
 
if (@ARGV == 1) {
    print "Enter the date: ";
}
chomp($mydate = <>);
 
my ($year, $month, $day) = Decode_Date_EU($date, 1);    # una fecha en el orden día mes año, en inglés
 
if ($year) {
    printf "Day:      %4d-%02d-%02d\n", $year, $month, $day;
 
    my($nyear, $nmonth, $nday) =  Add_Delta_YMD($year, $month, $day, 0, 0, 1);
 
    printf "Next day: %4d-%02d-%02d\n", $nyear, $nmonth, $nday;
 
    say Date_to_Text($nyear, $nmonth, $nday, 4);        # en español
}
else {
    say "ERROR: the date is not correct\n";
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Este código es capaz de entender muchas combinaciones de fecha, siempre que sigan el orden día-mes-año (formato europeo). Por ejemplo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

echo "31-december-2016" | ./dia_siguiente.pl

echo "31/December/2016" | ./dia_siguiente.pl

echo "31-Dec-2016"      | ./dia_siguiente.pl

echo "31, Dec 2016"     | ./dia_siguiente.pl

echo "31:12:2016"       | ./dia_siguiente.pl

...Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

La salida es siempre la misma:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

Day:      2016-12-31

Next day: 2017-01-01

Dom 1-ene-2017Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Si, en cambio, las fechas siguen el orden mes-día-año (formato norteamericano), te basta con cambiar la función Decode_Date_EU por Decode_Date_US.

El problema de tu código es que quieres hacer operaciones como esta:

línea 3: $$month =~ /1|3|5|7|8|10/

y en ese patrón, el primer '1' ya hace coincidir cuando el mes es 10, 11 o 12. Esa es la razón por la cual se ejecuta la línea 4 en lugar de la 20.

Lo correcto es ajustar más lo que estamos buscando:

$$month =~ /^(1|3|5|7|8|10)$/;

con las anclas '^' y '$' ya indicamos que las opciones deben compararse en toda la longitud de $$month, no solo una parte. Por ejemplo, 11 coincide con /1/, pero ya no coincide con /^1$/.

Otra cosa es que tanto la rutina de gestionar el mes con número es casi la misma que gestionarla con nombre. Solo hay que modificar un poco las expresiones regulares.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
 
use v5.14.2;
 
print "Enter the date (day month year): ";
my $Date = <STDIN>;
chomp $Date;
 
my($Day, $Month, $Year) = split " ", $Date;
 
my($NextDay, $NextMonth, $NextYear) = nexdate($Day, $Month, $Year);
 
say join '-' => $NextDay, $NextMonth, $NextYear;
 
 
sub nexdate {
    my ($day, $month, $year) = @_;
 
    my @Days_of_Months = qw(0 31 28 31 30 31 30 31 31 30 31 30 31);
 
    # ver si estamos en año bisiesto: cambia el número de días de febrero
    $Days_of_Months[2]++
        if  $year % 4 == 0                      # tiene que ser divisible por 4
        and (
                $year % 100 != 0                # y si no es divisible por 100
            or
                $year % 400 == 0                # pero sí por 400
    );
 
    # Averiguar el número de mes en caso de venir en forma de nombre
    if ($month + 0 == 0) {
        my @Months_names_rx = (
            qr/XXX/,                            # mes 0 :)
            qr/ene(ro)?|jan(uary)?/i,
            qr/feb(rero|ruary)?/i,
            qr/mar(zo|ch)?/i,
            qr/a(b|p)r(il)?/i,
            qr/mayo?/i,
            qr/jun(io|e)?/i,
            qr/jul(io|y)?/i,
            qr/ago(sto)?|aug(ust)?/i,
            qr/sep(tiembre|tember)?/i,
            qr/oct(ubre|ober)?/i,
            qr/nov(iembre|ember)?/i,
            qr/dic(iembre)?|dec(ember)?/i,
        );
 
        my $month_number = 0;
        for my $month_rx (@Months_names_rx) {
            last if $month =~ /$month_rx/;              # encontrado, salimos
            $month_number++;
        }
 
        if ($month_number > 0 and $month_number < 13) {
            $month = $month_number;
        }
        else {
            die "ERROR: Month name\n";
        }
    }
 
    # Incrementamos fecha
    $day++;
 
    if ($day > $Days_of_Months[$month]) {
        $day = 1;
        $month++;
 
        if ($month > 12) {
            $month = 1;
            $year++;
        }
    }
 
    return $day, $month, $year;
}
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Obviamente, es mucho más cómodo usar Date::Calc (o algún otro de los varios módulos de gestión de fechas que encontrarás en CPAN).

por **angelluigi** » 2016-12-13 12:39 @569

Muchas gracias, Marko, por dedicarle un tiempo. El problema es que no puedo usar módulos, o sea, que no me está permitido.

Gracias a ti también, explorer. Lo que pasa es que me piden una subrutina de tipo acción y tengo que usar referencias para hacer el ejercicio.

por **explorer** » 2016-12-14 06:29 @312

Bueno, la explicación del error ya la tienes. También, una resolución sin módulos y dos con módulos (gracias, MARKO).

Si solo te queda devolver los resultados a través de las propias variables, tienes mejores que opciones que hacer cosas como

$$day, $$month, $$year

que llenan el código de pelos (demasiados caracteres extraños).

Una opción es, al principio de la función, copiar los valores en variables escalares normales:

my($day_ref,$month_ref,$year_ref) = @_;
my($day, $month, $year) = ($$day_ref, $$month_ref, $$year_ref);

y ya podemos hacer el resto de cuentas. Al final, asignamos los valores a las referencias:

($$day_ref, $$month_ref, $$year_ref) = ($day, $month, $year);

Foro - Perl en Español

Obtener la fecha del día siguiente

Obtener la fecha del día siguiente

Publicidad

Re: Obtener la fecha del día siguiente

Re: Obtener la fecha del día siguiente

Re: Obtener la fecha del día siguiente

Re: Obtener la fecha del día siguiente

¿Quién está conectado?