Foro - Perl en Español

por **jimr1984** » 2017-06-06 18:14 @801

Saludos. Por favor, si pueden ayudarme.
No entiendo lo que está sucediendo.

Mi código es:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
 
my $var = "[email protected]";
 
print $var."\n";
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

resultado:

perl mail.pl

prueba.com

Por favor, si pueden corregirme. Muchas gracias.

El problema es que Perl está viendo un carácter '@' dentro de unas comillas dobles, así que está realizando una interpolación de la variable que sigue, en este caso, sería @demo.

Si hubieras puesto 'use strict;' y 'use warnings;' en el programa, el propio Perl te avisaría de esto.

Hay dos soluciones: cambiar las comillas dobles por simples, o escapar el carácter de la arroba.

Más información, en tu propio ordenador con el comando perldoc perldata, y en la Web (traducido al español, en la sección Interpolación de arrays).

por **jimr1984** » 2017-06-06 23:05 @003

El problema de no usar comilla simples es que tengo un arreglo de N direcciones de correo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my @arreglo = ("[email protected]","[email protected]", ...);
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

y esto se lo quiero pasar al programa mail de Linux para enviar un correo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

foreach (@arreglo) {
    system(sh enviarmail.sh  $_ );
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

El programa para enviar correos es un bash que tiene una sola línea, por ejemplo, el cual acepta un argumento:

Sintáxis: [ Descargar ] [ Ocultar ]

Using bash Syntax Highlighting

#!/bin/bash
echo "test" | mail -s "asunto"  $1
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

¿Cómo podría resolver este problema, por favor?

Gracias.

por **explorer** » 2017-06-09 18:47 @824

Te complicas demasiado. Con Perl puedes hacer eso sin tanto nivel de profundidad.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use v5.14;
use utf8;
use strict;
use warnings;
use autodie;
 
my @direcciones = qw(
    demo@hol.com
    otro@mas.com
);
 
my $texto = <<'EOT';
    En un lugar de la Mancha, de cuyo nombre no quiero acordarme, no ha mucho
    tiempo que vivía un hidalgo de los de lanza en astillero, adarga antigua,
    rocín flaco y galgo corredor. Una olla de algo más vaca que carnero, salpicón
    las más noches, duelos y quebrantos los sábados, lentejas los viernes, algún
    palomino de añadidura los domingos, consumían las tres partes de su hacienda.
    El resto della concluían sayo de velarte, calzas de velludo para las fiestas
    con sus pantuflos de lo mismo, los días de entre semana se honraba con su
    vellori de lo más fino. Tenía en su casa una ama que pasaba de los cuarenta, y
    una sobrina que no llegaba a los veinte, y un mozo de campo y plaza, que así
    ensillaba el rocín como tomaba la podadera. Frisaba la edad de nuestro hidalgo
    con los cincuenta años, era de complexión recia, seco de carnes, enjuto de
    rostro; gran madrugador y amigo de la caza. Quieren decir que tenía el
    sobrenombre de Quijada o Quesada (que en esto hay alguna diferencia en los
    autores que deste caso escriben), aunque por conjeturas verosímiles se deja
    entender que se llama Quijana; pero esto importa poco a nuestro cuento; basta
    que en la narración dél no se salga un punto de la verdad.
EOT
 
for my $direccion (@direcciones) {
 
    open my $MAIL, "|-", qq(mail -s "asunto" $direccion);
    print   $MAIL $texto;
    close   $MAIL;
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Incluso hasta te puedes ahorrar llamar al comando mail, con lo que no tienes el problema de tenerlo instalado o no:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use Email::MIME;
use Email::Sender::Simple qw(sendmail);
use Email::Sender::Transport::SMTP qw();
use Try::Tiny;
use utf8;
 
my $correo = Email::MIME->create(
                attributes => {
                    content_type => 'multipart/alternative',
                },
                header_str => [
                    From    => '[email protected]',
                    To      => '[email protected]',
                    Subject => 'Asunto: pruebas',
                ],
                parts => [
                    Email::MIME->create(
                        attributes => {
                            content_type => 'text/plain' ,
                            # encoding     => 'quoted-printable',
                            charset      => 'utf-8',
                        },
                        body => "Este es el cuerpo. áéíóúñÁÉÍÓÚÑ",
                    ),
                    Email::MIME->create(
                        attributes => {
                            content_type => 'text/html'
                        },
                        body => '<h1>Test</h1>',
                    )
                ],
);
 
try {
    sendmail(
        $correo,
        {
            transport => Email::Sender::Transport::SMTP->new(
                            host     => 'correo.mi.servidor.es',
                            helo     => 'explorer.ddns.vodafone.es',
                            port     => 25,
                            username => 'usuario',
                            password => 'contraseña',
                            debug    => 1,
            )
        }
    );
}
catch {
    print "Error enviando datos: $_";
};
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

P.D.: estamos en el foro Intermedio

Foro - Perl en Español

Error al imprimir variable

Error al imprimir variable

Publicidad

Re: Error al imprimir variable

Re: Error al imprimir variable

Re: Error al imprimir variable

¿Quién está conectado?