Foro - Perl en Español

por **lis** » 2017-06-13 20:42 @904

Hola a todos.

Tengo el siguiente código que lee un rango de celdas fijo de un archivo Excel con datos del índice de radiación ultravioleta (UV). Tiene escrito las palabras: Bajo, Moderado, Alto, Muy Alto y Extremo.

El asunto es que no logro que imprima una celda en particular y le asocie un color y un rango de números. Por ejemplo: si la celda que está en la columna 3 y fila 25 tiene escrito "Moderado" que también imprima el rango (en este caso 3 - 5) y el color que le corresponde, es decir el amarillo. Hasta ahora solo puedo hacer que lea el contendido de una celda pero no asociarlo al color y rango respectivo. Les agradezco mucho su ayuda.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
 
use strict;
use warnings;
use Spreadsheet::Read;
 
my $ref   = ReadData("Libro1.xls");
my $sheet = $ref->[1]->{cell};
 
#
my ( $rango, $color, $rangos, $colors, @rango, @color, $uv );
 
@rango = ( "1 - 2", "3 - 5",    "6 - 7",   "8 - 10", "11+" );
@color = ( 'verde', 'amarillo', 'naranjo', 'rojo',   'purpura' );
 
for my $columna ( 3, 6, 9 ) {
    for my $fila ( 25, 39, 53 ) {
 
        $uv = $sheet->[$columna]->[$fila];
 
        if ( $uv eq 'Bajo' )     { $rangos = $rango[0] and $colors = $color[0]; }
        if ( $uv eq 'Moderado' ) { $rangos = $rango[1] and $colors = $color[1]; }
        if ( $uv eq 'Alto' )     { $rangos = $rango[2] and $colors = $color[2]; }
        if ( $uv eq 'Muy_Alto' ) { $rangos = $rango[3] and $colors = $color[3]; }
        if ( $uv eq 'Extremo' )  { $rangos = $rango[4] and $colors = $color[4]; }
    }
}
 
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

#!/usr/bin/perl
use strict;
use warnings;
use Spreadsheet::Read;
 
my $ref   = ReadData("Libro1.xls");
my $sheet = $ref->[1]{cell};
 
my %rango = (
        Bajo            => "1 - 2",
        Moderado        => "3 - 5",
        Alto            => "6 - 7",
        Muy_Alto        => "8 - 10",
        Extremo         => "11+",
);
my %color = (
        Bajo            => 'verde',
        Moderado        => 'amarillo',
        Alto            => 'naranjo',
        Muy_Alto        => 'rojo',
        Extremo         => 'purpura',
);
 
for my $columna ( 3, 6, 9 ) {
    for my $fila ( 25, 39, 53 ) {
 
        my $uv = $sheet->[$columna][$fila];
 
        my $rangos = $rango{ $uv };
        my $colors = $color{ $uv };
 
        ...;
    }
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Incluso aún más breve:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use Spreadsheet::Read;
 
my $ref   = ReadData("Libro1.xls");
my $sheet = $ref->[1]{cell};
 
my %rango_color = (
        Bajo            => [ "1 - 2",   'verde'         ],
        Moderado        => [ "3 - 5",   'amarillo'      ],
        Alto            => [ "6 - 7",   'naranjo'       ],
        Muy_Alto        => [ "8 - 10",  'rojo'          ],
        Extremo         => [ "11+",     'purpura'       ],
);
 
for my $columna ( 3, 6, 9 ) {
    for my $fila ( 25, 39, 53 ) {
 
        my $uv = $sheet->[$columna][$fila];
 
        my($rangos, $colors) = @{ $rango_color{$uv} };
    }
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Asociar rango y color a celdas de archivo Excel

Asociar rango y color a celdas de archivo Excel

Publicidad

Re: Asociar rango y color a celdas de archivo Excel

¿Quién está conectado?