Foro - Perl en Español

por **Javier** » 2017-06-27 04:12 @217

Buenos días:

Tengo un HASH con esta estructura:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my %EW =
(
'a' =>
                {
                'b'=> {},
                'c' => {},
                'd' => {},
                'e' => {},
                'f' => 
                        {
                        'g' => {},
                        'h' => {},
                        'i' => {}
                        },
                'j' => {}
                }
);
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Quiero pasar cada llave a otro hash, poniendo cada llave asociada a la ruta que lleva hasta ella:
a = a
b = a/b
...
g = a/f/g

Puedo hacerlo con una solución poco elegante (anidando bucles que leen las llaves):

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

foreach my $n1 (keys %EW)
{
        $ET{$n1} = "$n1/";
        
        foreach my $n2 (keys $EW{$n1})
        {
                $ET{$n2} = "$n1/$n2/";
                
                foreach my $n3 (keys $EW{$n1}{$n2})
                {
                        $ET{$n3} = "$n1/$n2/$n3/";      
                }
        }
 
 }
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

¿Habría alguna forma de recorrerlo hasta la profundidad que fuese? Con los bucles foreach doy por hecho que hay hasta 3 niveles de anidamiento pero no siempre será así.

He pensado en hacerlo con referencias y con una función pero no sé si voy bien encaminado.

Un saludo

Gracias
Un saludo

sub R
{       
        my $a = shift;
        foreach my $b (keys $a)
        {
                if (ref $a->{$b} eq 'HASH')
                {
                        $et{$b} = $b;
                        $a = $a->{$b};
                        R($a);
                }
        }
 
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

¿Dónde acumulo las rutas?

por **explorer** » 2017-06-27 21:12 @925

Creo que el problema está en la línea

keys $a

que debería ser

keys %$a

(Si $a contiene una referencia a un hash, %$a es el hash, con lo que ya podemos pedirle sus claves con keys. Bueno, según la versión que tengas de Perl, podría hacerlo de forma automática).

Pero, quizás, el mayor problema es la línea 9: estás modificando el valor de $a. Cuando se regrese de la llamada de la línea 10, la siguiente vuelta del bucle foreach lo estará haciendo sobre un $a modificado, y el if de la línea 6 fallará antes de tiempo.

Quita la línea 9 y cambia la línea 10 por

R($a->{$b});

La ruta yo la almaceno en un array, que también paso por parámetro. Pero, atención, creo un nuevo array antes de cada llamada recursiva, para evitar que las distintas llamadas interfieran sobre el mismo array, y creen rutas cada vez más grandes.

por **Javier** » 2017-06-30 04:12 @216

Hola:

Yo también lo saco a array, pero sólo consigo que me lo guarde por niveles y además me crea algunos vacíos:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub R
{       
        my $a = shift;
        my @ab = shift;
        my @ac;
        push @ab , @ac;
        foreach my $b (keys %$a)
        {
                
                if (ref $a->{$b} eq 'HASH')
                {
                        push @ac , $b;
                        R($a->{$b} , @ac);
                }
        }
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

¿¿Cómo podría hacer que cada llave acumule su ruta?

por **explorer** » 2017-06-30 17:50 @784

Hay un error.

En la línea 13 estás llamando a R, con dos argumentos. El primero es una referencia (lo has comprobado en la línea 10). Y el segundo, realmente, son TODOS los elementos del array @ac. Es decir, Perl "despliega" el contenido del array, y le pasa a R() un argumento por cada elemento del array.

Y... ahora viene el problema. En la línea 4 pones que el siguiente argumento a la referencia, es un solo elemento (lo sacas con un shift) y lo metes en el nuevo array @ab.

O sea... que no lees el resto de argumentos, el resto de elementos del array de la llamada.

La solución es pasar el array como referencia:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

        my @ab = @_;    # este es el array que almacena los argumentos que quedan después del shift anterior
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

                        R($a->{$b}, \@ac);
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Aquí te pongo mi solución:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use v5.20;                      # para usar las nuevas características de desreferencia. Ver perlref
use experimental 'signatures';  # usar la característica experimental de signatures en las sub
 
my %EW = (
    'a' => {
        'b' => {},
        'c' => {},
        'd' => {},
        'e' => {},
        'f' => {
            'g' => {},
            'h' => {},
            'i' => {}
        },
        'j' => {},
    },
);
 
my %ET;
my @ruta;
 
procesa_hash(\%EW, []);
 
sub procesa_hash($hash_ref, $ruta_ref) {
 
    while (my($clave, $valor) = each $hash_ref->%*) {
 
        next if ref $valor ne 'HASH';
 
        my @nueva_ruta = ( $ruta_ref->@*, $clave);      # creamos una nueva ruta a esa clave
 
        $ET{ $clave } = join "/", @nueva_ruta;          # la guardamos
 
        procesa_hash($valor, \@nueva_ruta);             # procesamos el nuevo hash
    }
}
 
use Data::Dumper;
say Dumper \%ET;
 
__END__
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

La salida es:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

$VAR1 = {

          'b' => 'a/b',

          'a' => 'a',

          'd' => 'a/d',

          'h' => 'a/f/h',

          'i' => 'a/f/i',

          'c' => 'a/c',

          'f' => 'a/f',

          'j' => 'a/j',

          'e' => 'a/e',

          'g' => 'a/f/g'

        };Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Leer recursivamente un HASH

Leer recursivamente un HASH

Publicidad

Re: Leer recursivamente un HASH

Re: Leer recursivamente un HASH

Re: Leer recursivamente un HASH

Re: Leer recursivamente un HASH

Re: Leer recursivamente un HASH

¿Quién está conectado?