Foro - Perl en Español

por **CrisPerl** » 2018-02-19 12:10 @548

Hola a todos y en especial a explorer por su respuesta rápida de antemano.

Quiero comparar la columna 0 del archivo cath con la columna modificada 1 del archivo 3tpoA2 y si coinciden que agregue la columna 1 del cath al último del archivo modificado 3tpoA2.

Debe quedar así en las filas donde coinciden los id.

3tpoA 3tpoA 30 406 435.00 1.25.10.10 1.25.10.10

Adjunto archivos originales

#!/usr/bin/perl

open (CATH,"./cath_min2.txt");
while ($catch = <CATH>) {
chomp $catch;
@catch=split(/\s+/,$catch);
$id=@catch[0];
$classcatch=join ("\.",@catch[1..4]);
}
open (LOG,"./3tpoA2.log");

while ($log = <LOG>) {
next if $log =~ /^\D/;
chomp $log;
@log=split(/\t/,$log);
@nwlog=@log[0..2, 6, 5];
print "@nwlog[0..$#nwlog]";
foreach $p (@nwlog[1..$#nwlog]) {
if ($p=~/^\d[a-z]{3}[A_Z]/) {
push (@nwlog,$classcatch);
} else {$nwlog[1]="NF"}
} print"\n";
}

Hay que usar hashes para almacenar la información que vamos leyendo, y luego, al leer línea por línea el otro archivo, ver si existe una coincidencia.

Primero guardamos la información del archivo cath en una estructura hash cuyas claves son los id, y los valores son arrays, cuyos elementos son los que siguen a los id.

Segundo, leemos el archivo de log línea a línea. Si existe alguna clave del hash que coincide con el id de la segunda columna, pues pintamos la información de los dos archivos.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use v5.14;
use strict;
use warnings;
use autodie;
 
my %classcatch;
 
open my $CATH, '<', 'cath_min2.txt';
 
while (my $catch = <$CATH>) {
    chomp $catch;
    my @catch = split " " , $catch;
    $catch[0] =~ s/\d+$//;                      # quitamos los dígitos del final
 
    # guardamos el valor en un array que cuelga de un valor hash
    push @{ $classcatch{ $catch[0] } }, join '.', @catch[1..4];
}
 
close $CATH;
 
#use Data::Dumper;
#say Dumper \%classcatch;                       # aspecto de la estructura creada
 
open my $LOG, '<', '3tpoA2.log';
my $log = <$LOG>;                               # leemos la línea de cabecera
 
while ($log = <$LOG>) {
    chomp $log;
 
    my @log = split /\t/, $log;
 
    if (exists $classcatch{ $log[1] }) {        # si existe un id igual a la segunda columna
 
        say join " ", @log[0 .. 2, 6, 5], @{ $classcatch{ $log[1] } };
    }
    else {
        say "$log[0] no encontrado";
    }
}
 
close $LOG;
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

por **CrisPerl** » 2018-02-20 01:04 @086

Muchas gracias, explorer.

Veo que aun no consigo asimilar bien lo de los hash y sacarle provecho en su uso. ¿Y si se quisiera mantener toda la información de las columnas incluso donde no coincida? Que aparezca, por ejemplo, "no encontrado".

Saludos.

por **explorer** » 2018-02-20 10:14 @468

Si no hay ninguna clave que no coincida con lo que estamos buscando, vale con poner un else{} para contemplar el caso de qué hacer cuando no hay ninguna coincidencia. Es lo bueno de los hash: sus claves son únicas.

Ya he modificado el código original para tener en cuenta ese caso.

por **CrisPerl** » 2018-02-21 04:20 @222

¡gracias, explorer!

Foro - Perl en Español

Error al juntar dos columnas de dos archivos diferentes

Error al juntar dos columnas de dos archivos diferentes

Publicidad

Re: Error al juntar dos columnas de dos archivos diferentes

Re: Error al juntar dos columnas de dos archivos diferentes

Re: Error al juntar dos columnas de dos archivos diferentes

Re: Error al juntar dos columnas de dos archivos diferentes

¿Quién está conectado?