Foro - Perl en Español

por **dacons** » 2006-05-22 16:03 @710

Hola de nuevo, estoy intentando meter un fichero dentro de una lista asociativa, pero no hay forma.

El fichero tiene este formato:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

Tipo: color

Precio: 3 €

Cantidad: 7 unidadesColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

He hecho lo siguiente pero no funciona:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub informe{
    if (open(VAR,"fichero.txt")) {
        @texto=<VAR>;
    }
    %lista=@texto;
    print "$lista{Tipo}";
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Con el vector sí va bien pero con la lista hash, no. ¿Por qué? Y una vez los he sacado ¿cómo puedo incrementarlos, por ejemplo las unidades?

sub informe {
    if ( -x "fichero.txt" ) ) {
            open( VAR, "fichero.txt" ) or die "No se pudo abrir el archivo: $!\n";
            my @texto = <VAR>;
            close VAR;
            my %hash;
            foreach my $line (@texto) {
                my @todo = split /:\s/, $line;
                $hash{"$todo[0]"} = "$todo[1]";
            }
    }
    else {
            die "El archivo \"fichero.txt\" no existe\n";
    }
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2006-05-22 16:57 @748

Perl es listo, pero no tanto como para saber el formato de tu fichero.

Hay que darle un poco de ayuda...

Supongamos que tu fichero es de la estructura que muestras: Una palabra, seguida de ':' y luego del valor.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -l
use strict;
use warnings;
 
my %lista;
my ( $clave, $valor );
 
sub informe {
    open( VAR, "fichero.txt" ) or die "ERROR: No pude abrir el fichero.txt: $!\n";
    while ( my $linea = <VAR> ) {
        if ( ( $clave, $valor ) = $linea =~ /^(\w+):\s*(.+)\s*$/ ) {
            $lista{$clave} = $valor;
        }
    }
    close VAR;
}
 
informe;
 
foreach ( keys %lista ) {
    print $_, " ", $lista{$_};
}
 
print $lista{Tipo};
 
$lista{Cantidad}++;
print $lista{Cantidad};
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

En la línea 10 hacemos un bucle por todo el fichero y vamos leyendo una $linea cada vez
En la 11, con la ayuda de la expresión regular extraemos la clave y el valor, que está separada por los ':'. Lo que hacemos es que nos quedamos con la primera (^) palabra ((\w+)), seguida de ':', posiblemente algún espacio en blanco (\s*) y nos quedamos con el resto ((.+)), menos los últimos ($) espacios en blanco (\s*)
De la 20 a 22, pintamos todo lo que hemos conseguido leer del fichero
En la 26, incrementamos el valor de Cantidad, y luego lo pintamos.

El resultado es:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

Cantidad 7 unidades

Precio 3 €

Tipo color

color

8Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Como ves, al aumentar en uno el valor de '7 unidades', Perl lo pasa de cadena de caracteres a valor numérico. Se encuentra con el 7. Lo incrementa (8) y ese es el nuevo valor de $lista{Cantidad}. Pero NO '8 unidades'. Lo mismo le pasaría a $lista{Precio}.

Perl user · por **Perl user** » 2006-05-22 17:29 @770

dacons escribiste:Hola de nuevo, estoy intentando meter un fichero dentro de una lista asociativa, pero no hay forma.

El fichero tiene este formato:
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using text Syntax Highlighting
Tipo: color
Precio: 3 €
Cantidad: 7 unidades
Coloreado en 0.000 segundos, usando GeSHi 1.0.8.4

¿Qué tal?

Te recomiendo utilizar el módulo Config::Simple o en su defecto Config::Tiny, es muy útil y puedes generar esquemas de configuración dentro del mismo archivo, échale un vistazo.

Sino, entonces una solución podría ser esta:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
 
use strict;
use warnings;
 
sub parse_file {
    my ( $filename ) = @_;
    open my $fh, $filename or die $!;
    my @output;
    while ( <$fh> ) {
        chomp;
        push @output, split /\s*:\s*/, $_, 2;
    }
    close $fh;
    return @output;
}
 
my %params = parse_file( $ARGV[0] );
# ya puedes utilizar %params como gustes
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Saludos,

por **creating021** » 2006-05-22 17:50 @785

¡Oops!

Otro más:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub informe {
    my $file = shift;
    open FL, $file or die "Error: $!";
    my @lineas = <FL>;
    my %hash;
    foreach my $lineas (@lineas) {
        $lineas =~ s/://g;
        my @todo = split / /, $lineas;
        $hash{ $todo[0] } = $todo[1];  # supongo que es de tan solo dos datos.
    }
    return %hash;
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Perl user · por **Perl user** » 2006-05-23 07:21 @348

creating021 escribiste:

Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using perl Syntax Highlighting

sub informe {

my $file = shift;

open FL, $file or die "Error: $!";

my @lineas = <FL>;

my %hash;

foreach my $lineas (@lineas) {

$lineas =~ s/://g;

my @todo = split / /, $lineas;

$hash{ $todo[0] } = $todo[1]; # supongo que es de tan solo dos datos.

}

return %hash;

}

Coloreado en 0.001 segundos, usando GeSHi 1.0.8.4

¿Qué tal?

Esta implementación no funciona realmente por lo siguiente:

Un split() sobre un espacio "vacío" literal es completamente incorrecto y no portátil; es mejor un patrón como tal
Si no le dices que solo quieres partir la línea en dos partes, partirá tus valores en más ( en el caso de los valores que tienen espacios en ellos )
Estás metiendo valores incompletos al hash gracias al punto anterior
Si el archivo fuera lo suficientemente grande, meterlo todo a un array pega un poco en la eficiencia del programa
Hay otros aspectos de estilo que hicieron falta, pero creo que con lo anterior basta para que no funcione

Saludos,

por **creating021** » 2006-05-23 15:10 @673

Eso es lo que pasa cuando no se usa strict :oops:

Me da pena con ustedes, pero gracias por lo dicho.

¡Ustedes son los que saben!

por **dacons** » 2006-05-24 13:42 @612

Muchísimas gracias a todos, me ayudaron mucho y la explicación de explorer es buenísima.

Un saludo

Foro - Perl en Español

Ficheros pasados a hash

Ficheros pasados a hash

Publicidad

Re: Ficheros pasados a hash

¿Quién está conectado?