Foro - Perl en Español

por **pablgonz** » 2020-04-27 22:47 @991

Hola a todos. Estoy intentando crear un archivo .log bastante simple para un pequeño script y me asaltaron algunas dudas sobre cómo hacerlo de manera correcta y sin módulos extra (solo los que trae la distribución básica).

El código que poseo es el siguiente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use v5.26;
use Getopt::Long qw(:config bundling_values require_order no_ignore_case);
use FileHandle;
use File::Copy;
use POSIX qw(strftime);
use File::Temp qw(tempdir);
use Cwd;
use autodie;
 
my $verbose  = 0; # verbose
my $debug;        # debug
 
my $result = GetOptions (
    'debug!'         => \$debug,   # debug
    'verbose!'       => \$verbose, # verbose
    ) or die "No es una opción valida\n";
 
### Mensajes de error extendidos
sub exterr () {
    chomp(my $msg_errno = $!);
    chomp(my $msg_extended_os_error = $^E);
    if ($msg_errno eq $msg_extended_os_error) {
        $msg_errno;
    }
    else {
        "$msg_errno/$msg_extended_os_error";
    }
}
 
### Nombre del script
chomp(my $scriptname = `basename $0`);
$scriptname =~ s/\.pl$//;
 
### Directorios y archivos
my $tempDir = tempdir( CLEANUP => 1);
my $workdir = cwd;
my $LogFileName = "$tempDir/$scriptname.log";
my $Log_file = new FileHandle;
my $StampTime = strftime ("%y/%m/%d %H:%M:%S", localtime);
 
### Abrimos
$Log_file->open("> $LogFileName");
$Log_file->print("[$StampTime] * Se inicio $scriptname en $workdir\n");
$Log_file->print("[$StampTime] * Se creo el directorio $tempDir\n");
$Log_file->print("[$StampTime] * Se creo el archivo $tempDir/$scriptname.log\n");
 
### Log simple
sub Log {
  my $msg = shift;
  my $now  = strftime ("%y/%m/%d %H:%M:%S", localtime);
  $Log_file->print(sprintf  "[%s] %s\n", $now, $msg);
  print "$msg\n" if $verbose;
  return 0
}
 
### Captura y ejecución de comandos
sub RUNOSCMD {
  my $cmdname = shift;
  my $argcmd  = shift;
  my $captured = $cmdname." ".$argcmd;
  Log("* Runing: $captured");
  $captured = qx{$captured};
  if ($? == -1) {
    $cmdname = "* Error!!: ".$cmdname." failed to execute (%s)!\n";
    $Log_file->print(sprintf  "$cmdname", exterr);
    die sprintf "$cmdname", exterr;
  } elsif ($? & 127) {
    $cmdname = "* Error!!: ".$cmdname." died with signal %d!\n";
    $Log_file->print(sprintf  "$cmdname", ($? & 127));
    die sprintf "$cmdname", ($? & 127);
  } elsif ($? != 0 ) {
    $cmdname = "* Error!!: ".$cmdname." exited with error code %d!\n";
    $Log_file->print(sprintf  "$cmdname", $? >> 8);
    die sprintf "$cmdname",$? >> 8;
  } else {
   $Log_file->print($captured);
   print($captured) if $verbose;
  }
}
 
### Agregamos algunas líneas a nuestro log
Log("Una línea agregada al log");
Log("Otra línea agregada al log");
 
### Definimos un comando
my $cmd = "ls";
 
say "Ejecutando $cmd";
RUNOSCMD($cmd, "-lh");
 
Log("Otra línea agregada al log");
 
### Definimos otro comando (no existente)
my $newwcmd = "XX";
 
say "Ejecutando $newwcmd";
RUNOSCMD($newwcmd, "-lh");
 
Log("Esta línea no se agrega porque XX a dado un error");
 
END {
  $Log_file->print("[$StampTime] * Se cierra el archivo $LogFileName");
  close $Log_file;
  ### Movemos el archivo al directorio de trabajo
  if ($debug) {
    move("$tempDir/$scriptname.log", "$workdir/$scriptname.log")
    or die "* Error!!: No puedo mover $scriptname.log";
    }
  say "Sayonara";
}
 
__END__
 
Coloreado en 0.005 segundos,  usando GeSHi 1.0.8.4

En él he definido dos funciones Log que sólo agrega líneas al archivo .log y RUNOSCMD que se encarga de ejecutar un comando de sistema capturando la salida y analizando los valores.

Al ejecutar el script con las opciones correctas todo parece ir bien, pero, si se pasa una opción desconocida, --k, por ejemplo, se obtiene:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

Unknown option: k

No es una opción valida

Can't call method "print" on an undefined value at mylog.pl line 103.

END failed--call queue aborted.Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Y aquí es donde empieza mi problema. Las líneas:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

Can't call method "print" on an undefined value at mylog.pl line 103.

END failed--call queue aborted.Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

no deberían aparecer, al pasar --k el script debería salir, asumo que es por el uso de END {, pero, si muevo el código de lugar, uso la opción --debug y ocurre algún error, no obtengo el archivo .log en el directorio de trabajo.

¿Existe una forma mejor de lograr esto?

Saludos.

#!/usr/bin/env perl
use v5.26;
use Getopt::Long qw(:config bundling_values require_order no_ignore_case);
use FileHandle;
use File::Copy;
use POSIX qw(strftime);
use File::Temp qw(tempdir);
use Cwd;
use autodie;
 
my $verbose  = 0; # verbose
my $debug;        # debug
 
my $result = GetOptions (
    'debug!'         => \$debug,   # debug
    'verbose!'       => \$verbose, # verbose
    ) or die "No es una opción valida\n";
 
### Mensajes de error extendidos
sub exterr () {
    chomp(my $msg_errno = $!);
    chomp(my $msg_extended_os_error = $^E);
    if ($msg_errno eq $msg_extended_os_error) {
        $msg_errno;
    }
    else {
        "$msg_errno/$msg_extended_os_error";
    }
}
 
### Nombre del script
chomp(my $scriptname = `basename $0`);
$scriptname =~ s/\.pl$//;
 
### Directorios y archivos
my $tempDir = tempdir( CLEANUP => 1);
my $workdir = cwd;
my $LogFileName = "$workdir/$scriptname.log";
my $Log_file = FileHandle->new("> $LogFileName");
my $StampTime = strftime ("%y/%m/%d %H:%M:%S", localtime);
 
### Abrimos
$Log_file->print("[$StampTime] * Se inició $scriptname en $workdir\n");
$Log_file->print("[$StampTime] * Se creo el directorio $tempDir\n");
$Log_file->print("[$StampTime] * Se creo el archivo $tempDir/$scriptname.log\n");
 
### Log simple
sub Log {
  my $msg = shift;
  my $now  = strftime ("%y/%m/%d %H:%M:%S", localtime);
  $Log_file->print(sprintf  "[%s] %s\n", $now, $msg);
  print "$msg\n" if $verbose;
  return 0
}
 
### Captura y ejecución de comandos
sub RUNOSCMD {
  my $cmdname = shift;
  my $argcmd  = shift;
  my $captured = $cmdname." ".$argcmd;
  Log("* Runing: $captured");
  $captured = qx{$captured};
  # Guardamos la salida del comando en el archivo .log
  $Log_file->print($captured);
  if ($? == -1) {
    $cmdname = "* Error!!: ".$cmdname." failed to execute (%s)!\n";
    $Log_file->print(sprintf  "$cmdname", exterr);
    die sprintf "$cmdname", exterr;
  } elsif ($? & 127) {
    $cmdname = "* Error!!: ".$cmdname." died with signal %d!\n";
    $Log_file->print(sprintf  "$cmdname", ($? & 127));
    die sprintf "$cmdname", ($? & 127);
  } elsif ($? != 0 ) {
    $cmdname = "* Error!!: ".$cmdname." exited with error code %d!\n";
    $Log_file->print(sprintf  "$cmdname", $? >> 8);
    die sprintf "$cmdname",$? >> 8;
  }
   # Si pasamos --verbose mostramos la salida
   print($captured) if $verbose;
}
 
### Agregamos algunas líneas a nuestro log
Log("Una línea agregada al log");
Log("Otra línea agregada al log");
 
### Definimos un comando
my $cmd = "ls";
 
say "Ejecutando $cmd";
RUNOSCMD($cmd, "-lh");
 
Log("Otra línea agregada al log");
 
### Definimos otro comando (no existente)
my $newwcmd = "XX";
 
say "Ejecutando $newwcmd";
RUNOSCMD($newwcmd, "-R");
 
Log("Esta línea no se agrega porque XX a dado un error");
 
### Si todo esta correcto
$Log_file->print("[$StampTime] * Se cierra el archivo $scriptname.log");
close $Log_file;
 
### Si no necesitamos el archivo, lo movemos el archivo al directorio temporal
if (!$debug) {
    move("$workdir/$scriptname.log", "$tempDir/$scriptname.log")
    or die "* Error!!: No puedo mover $scriptname.log";
}
 
__END__
 
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

Al ejecutar el script sin opciones genera el archivo .log:

Sintáxis: [ Descargar ] [ Ocultar ]

[20/04/28 10:46:22] * Se inició nuevo en /home/pablo/GitHub
[20/04/28 10:46:22] * Se creo el directorio /tmp/cX49C_N8TR
[20/04/28 10:46:22] * Se creo el archivo /tmp/cX49C_N8TR/nuevo.log
[20/04/28 10:46:22] Una línea agregada al log
[20/04/28 10:46:22] Otra línea agregada al log
[20/04/28 10:46:22] * Runing: ls -lh
total 24K
drwxrwxr-x. 5 pablo pablo 4,0K abr 13 12:10 demopkg-jw
drwxrwxr-x. 7 pablo pablo 4,0K may 31 2019 ltxcole
drwxrwxr-x. 4 pablo pablo 4,0K abr 27 05:56 ltximg
-rw-rw-r--. 1 pablo pablo 3,1K abr 28 01:44 mylog.pl
-rw-rw-r--. 1 pablo pablo 320 abr 28 10:46 nuevo.log
-rw-rw-r--. 1 pablo pablo 3,1K abr 28 10:38 nuevo.pl
[20/04/28 10:46:22] Otra línea agregada al log
[20/04/28 10:46:22] * Runing: XX -R
* Error!!: XX failed to execute (No such file or directory)!

y la siguiente salida:

Sintáxis: [ Descargar ] [ Ocultar ]

Ejecutando ls
Ejecutando XX
* Error!!: XX failed to execute (No such file or directory)!

Si paso una opción invalida no crea el archivo ni genera errores inesperados, pero no escribe la salida del comando que ha fallado, en mi caso al ejecutar XX -R obtengo la salida

Sintáxis: [ Descargar ] [ Ocultar ]

bash: XX: orden no encontrada

y me gustaría que ésta quedara escrita en el .log ¿Puedo guardar esta salida?

por **explorer** » 2020-04-28 12:22 @557

Mueve las líneas 14 a 17 (tratamiento de GetOptions) después de abrir los archivos log (línea 46).

Luego, en la línea del die(), se puede poner algo así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

}ordo{ Log("No es una opción válida");die"No es una opción válida\n";}Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **pablgonz** » 2020-04-28 12:50 @576

Genial, hice los cambios que has propuesto:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

    ) or do { Log("No es una opción válida"); die "No es una opción válida\n"; };
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

pero aún no puedo capturar :(

Sintáxis: [ Descargar ] [ Ocultar ]

bash: XX: orden no encontrada

¿Me falta alguna instrucción en RUNOSCMD o no se puede capturar esto?

por **explorer** » 2020-04-28 14:42 @654

Creo que te refieres a capturar ese mensaje de error.

Ese mensaje sale por el canal STDERR, que no es capturado por qx().

Hay formas, en Perl, para capturar el STDOUT y el STDERR por separado, pero la primera solución sería recibir los errores que salen, en lugar de STDERR, por STDOUT.

El truco sería poner

2>&1

después del comando, para que shell (ejecutado por qx()) redirija un canal a otro. Sería algo así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $captured = "$cmdname $argcmd 2>&1";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Pero si, el número de errores (y advertencias), es muy grande entonces puede ser un lío porque saldrá mezclado con la salida normal del comando. En ese caso es cuando es mejor mirar otras opciones, como puede ser la función tap() del módulo Sysadm::Install (ejemplo).

Usa el sistema de búsqueda en estos foros y busca por STDERR para más ideas de cómo capturar esa salida.

por **pablgonz** » 2020-04-28 15:09 @673

Creo que lo de capturar errores es muy avanzado para lo que deseo, la solución que propones es la más factible, conozco cuales son los programas y las salidas esperadas. He agregado esto para portabilidad (Windows/Linux) que usaré en la implementación:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use File::Spec::Functions qw(catfile devnull);
my $null     = devnull();
my $captured = "$cmdname $argcmd >$null";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

que creo que es equivalente a 2>&1.

Consulta (no relacionada): ¿Por qué desde mi móvil me dice que la página del foro no es segura?

Agradecido por la respuesta.
Pablo

por **explorer** » 2020-04-28 18:43 @821

No, no es equivalente.

Lo que has hecho es mandar todos los mensajes de error al dispositivo /dev/null, es decir, obviarlos.

El navegador te avisa de que la página usa una comunicación no cifrada (protocolo HTTP normal). Eso no significa que la página no sea segura. Es un abuso del lenguaje. Una página es segura si su contenido es seguro. Otra cosa es que se transmita de forma segura, que es lo que tu navegador está advirtiendo.

Desde hace unos meses los navegadores avisan de forma explícita cuando te conectas a páginas que usan el protocolo HTTP en lugar del HTTPS, como una medida de seguridad (se supone que si la página es con protocolo HTTPS, es porque su dueño ha pagado por tener un certificado digital que acredite que él es él) pero el caso es que cualquiera puede hacerse pasar por "sitio legal" comprando un dominio con un certificado digital cualquiera (incluso gratuito).

por **pablgonz** » 2020-04-28 19:09 @840

explorer escribiste:No, no es equivalente.

Lo que has hecho es mandar todos los mensajes de error al dispositivo /dev/null, es decir, obviarlos.

Ya entiendo, manejar errores y salidas es más complicado de lo que pensé.

explorer escribiste:Desde hace unos meses los navegadores avisan de forma explícita cuando te conectas a páginas que usan el protocolo HTTP en lugar del HTTPS, como una medida de seguridad (se supone que si la página es con protocolo HTTPS, es porque su dueño ha pagado por tener un certificado digital que acredite que él es él) pero el caso es que cualquiera puede hacerse pasar por "sitio legal" comprando un dominio con un certificado digital cualquiera (incluso gratuito).

Gracias por la aclaración, me había percatado de que por defecto Google me mostraba/enviaba a direcciones HTTPS por sobre las HTTP, pensé que era un problema con mi navegador, es extraño que Google no me envíe directo a https://perlenespanol.com y me envíe a http://perlenespanol.com

por **explorer** » 2020-04-28 20:23 @891

Yo siempre uso HTTP salvo cuando quiero hacer una compra. La transferencia es más rápida que con HTTPS.

Foro - Perl en Español

Archivo log simple y captura de errores (sin módulos extra)

Archivo log simple y captura de errores (sin módulos extra)

Publicidad

Re: Archivo log simple y captura de errores (sin módulos ext

Re: Archivo log simple y captura de errores (sin módulos ext

Re: Archivo log simple y captura de errores (sin módulos ext

Re: Archivo log simple y captura de errores (sin módulos ext

Re: Archivo log simple y captura de errores (sin módulos ext

Re: Archivo log simple y captura de errores (sin módulos ext

Re: Archivo log simple y captura de errores (sin módulos ext

Re: Archivo log simple y captura de errores (sin módulos ext

Re: Archivo log simple y captura de errores (sin módulos ext

¿Quién está conectado?