Foro - Perl en Español

use strict;
use warnings;

#!/usr/bin/perl
use strict;
use warnings;

# Primero, unas inicializaciones
# Las letras son 26, desde la 'A' a la 'Z'
my @letras = ('A' .. 'Z');
@letras == 26 or die "ERROR de la aplicación: no hay 26 letras de la 'A' a la 'Z'\n";

# Transformación de letras a números en base 1: A=1, B=2, etc.
my %letras = map { $letras[$_] => $_+1 } 0 .. $#letras;

# Tamaño máximo de la matriz
my $maxima_dimension = 115;

# Cómo se usa este programa
sub uso {
    print <<USO;
Uso: $0 <rango al estilo Excel> fichero [fichero [...]]
El rango debe ser del tipo <columna><fila>:<columna><fila>

USO
}

#################
# Leemos el rango
my $rango = shift @ARGV;
if ( !$rango ) {
    uso();
    die "ERROR: No me has indicado el rango\n";
}

# Interpretamos el rango para convertilo a números
my @esquinas = split q{:}, $rango;
if ( @esquinas != 2 ) {
    uso();
    die "ERROR: el rango no está bien formado\n";
}

# Convertimos una esquina a un número de columna y fila
# en base (0,0): la esquina superior izquierda será la (0,0)
sub esquina_a_numero {
    my $esquina = shift;

    $esquina = uc $esquina;  # Lo pasamos a mayúsculas
                             # por si acaso

    # La esquina se compone de unas letras (columna)
    # y un número (fila)
    my ($columna,$fila) = $esquina =~ /([A-Z]+)([0-9]+)/;
    if ( !$columna or !$fila ) {
        uso();
        die "ERROR: el rango no está bien formado\n";
    }

    # Convertimos la columna, de letra a número
    # Recorremos la $columna, cada letra, y vamos pasando
    # a número
    my $numero = 0;
    foreach my $letra ( split q{}, $columna ) {
        # Aunque somos de letras, hay que echar números
        $numero = $numero * @letras + $letras{$letra};
    }
    $columna = $numero;

    # ¿Estamos dentro del rango?
    if ( $columna < 1 or $columna > $maxima_dimension ) {
        die "ERROR: la columna ($columna) es superior al ancho máximo\n";
    }

    # ¿Y la fila?
    if ( $fila < 1 or $fila > $maxima_dimension ) {
        die "ERROR: la fila ($fila) es superior al alto máximo\n";
    }

    # Devolvemos los valores, en base 0
    return $columna-1, $fila-1;
}

# Ahora sí, convertimos las dos esquinas a posiciones X e Y
my ($x1, $y1) = esquina_a_numero($esquinas[0]);
my ($x2, $y2) = esquina_a_numero($esquinas[1]);

# Tenemos que ordenar las posiciones para que vayan de
# izquierda a derecha
if ( $x1 > $x2 ) {
    ($x1, $x2) = ($x2, $x1);
}
# y de arriba a abajo
if ( $y1 > $y2 ) {
    ($y1, $y2) = ($y2, $y1);
}

# Informamos
print "Procesamos ficheros en el rango ($x1,$y1)x($x2,$y2)\n";


###############################
# Procesamiento de los ficheros
@ARGV or die "ERROR: no hay ficheros que procesar";

# Por cada fichero
foreach my $fichero ( @ARGV ) {

    print "$fichero\n";

    # Nos leemos el fichero a memoria
    my @lineas = do {
        open FH,"<$fichero" or die "ERROR: No puedo leer fichero $fichero: $!\n";
        <FH>;
    };

    # Comprobamos la altura de la tabla leída
    if ( @lineas < $maxima_dimension ) {
        die "ERROR: Hay menos líneas que la altura esperada: $maxima_dimension\n";
    }

    # Creamos la tabla
    my @tabla;
    foreach my $linea ( @lineas ) {

        my @columnas = split q{ }, $linea;
        if ( @columnas < $maxima_dimension ) {
            die "ERROR: Hay menos columnas que el ancho esperado: $maxima_dimension\n";
        }

        # Vamos creando una lista de listas de elementos
        push @tabla, [ @columnas ];
    }

    # Estadísticas
    my $suma  = 0;
    my $suma2 = 0;
    my $N     = 0;
    my $x;
    for (my $i = $x1; $i <= $x2; $i++) {
    for (my $j = $y1; $j <= $y2; $j++) {

        $N++;

        $x = $tabla[$j][$i];   # Es muy sencillo el acceso,
                               # gracias a la forma de guardar los datos,
                               # anteriormente

        $suma  += $x;
        $suma2 += $x * $x;
    }
    }

    my $media      = $suma / $N;
    my $varianza   = ($suma2 - $N * $media * $media) / ($N - 1);
    my $desviacion = sqrt( $varianza );

    print "\tPuntos  : $N\n";
    print "\tSuma    : $suma\n";
    print "\tMedia   : $media\n";
    print "\tVarianza: $varianza\n";
    print "\tDesviac.: $desviacion\n";
    print "\n";
}