Foro - Perl en Español

por **situ** » 2010-01-29 09:39 @444

Estoy tratando de armar un script el cual me entrega los servidores DNS de un dominio y luego consulta la zona de transferencia pero no me funciona.

El script no está del todo bien programado ya que no soy programador. Como verán, lee un archivo externo con los dns que fueron descubiertos en las primeras líneas. Mi idea en realidad era que lea los dns de una variable donde se van a guardar los dns apenas descubiertos pero la verdad que no sé cómo realizar este paso.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
 
use Net::DNS;
 
open (F,">> dns.conf");
$addr  = shift || "dominio.com";
$res   = Net::DNS::Resolver->new();
$query = $res->query($addr, "NS");
 
if ($query) {
    foreach  $rr (grep { $_->type eq 'NS' } $query->answer) {
        print F $rr->nsdname, "\n";
    }
else {
    warn "query failed: ", $res->errorstring, "\n";
}
 
open  $FILE, '<', "dns.conf" or die $!;
@archivos = <$FILE>;
 
for $archivo(@archivos) {
    chomp $archivo;
 
    $res = Net::DNS::Resolver->new(
        nameservers => [qw($archivo)],
    );
    @zone = $res->axfr('dominio.com');
 
    if (@zone) {
        foreach  $rr (@zone) {
            $rr->print;
        }
    }
    else {
        print 'Zone transfer failed: ', $res->errorstring, "\n";
    }
}
 
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

$res = Net::DNS::Resolver->new( nameservers => [ @archivos ] );
 
my @zone = $res->axfr('perlenespanol.com');
 
if (@zone) {
    foreach my $rr (@zone) {
        $rr->print;
    }
}
else {
    print 'Zone transfer failed: ', $res->errorstring, "\n";
}
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Y de esa manera obtenemos la zona.

Otro tema distinto es que quieras obtener la misma zona usando todos los servidores DNS encontrados, que entonces sí que debes hacer un bucle por @archivos, y crear un nuevo objeto del módulo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$res = Net::DNS::Resolver->new( nameservers => [ $archivo ] );
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **situ** » 2010-01-29 13:44 @614

Como siempre un lujo =)

Dejo el script por si alguna persona lo necesita.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
# Obtener una zona de un dominio,
# a partir de sus propios servidores DNS
 
# Compruebo que esté el modulo instalado
BEGIN {
    eval "use Net::DNS";
    if ( $@ ) {
        warn  "Error al cargar el módulo: Net::DNS\n"
        . "Instalar módulo:\n"       
        . "\t\tcpan\n"
        . "\t\tcpan> install Net::DNS\n";
 
        exit ();
    }
}
 
# Compruebo que esté el argumento pasado
if ( @ARGV != 1 ) {
    die "\nUso: $0 <dominio> \n\n"
      . "   <dominio>  Dominio [ej -> dominio.com]\n"
      ;
}
 
$dominio = $ARGV[0];
chomp $dominio;
 
use Net::DNS;
$addr = shift || "$dominio";
$res   = Net::DNS::Resolver->new;
$query = $res->query($addr, "NS");
 
if ($query) {
    foreach  $rr (grep { $_->type eq 'NS' } $query->answer) {
        push @archivos, $rr->nsdname;
    }
}
else {
    warn "query failed: ", $res->errorstring, "\n";
}
 
$res = Net::DNS::Resolver->new( nameservers => [ @archivos ] );
 
my @zone = $res->axfr($dominio);
 
if (@zone) {
    foreach my $rr (@zone) {
         $rr->print;
    }
}
else {
    print 'Fallo en la transferencia de la zona: ', $res->errorstring, "\n";
}
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Saludos.

por **explorer** » 2010-01-29 14:51 @661

Unos comentarios...

* Si estás haciendo una prueba, dentro del BEGIN{}, para comprobar la existencia del módulo Net::DNS, luego ya no es necesaria la línea 28

* No es necesario crear un nuevo objeto Net::DNS::Resolver para agregar los servidores de nombres encontrados. Basta con usar la función nameserver() para actualizarlos

* En la mayoría de las ocasiones, "$dominio" es igual $dominio. Es decir, no es necesario entrecomillar una variable si solo es esa la variable que hay entre las comillas

* Aparte de entrar en el shell de cpan, se puede instalar el módulo de varias maneras. Si se quiere seguir usando el comando cpan, se puede usar de forma directa: cpan Net::DNS.

Se podría quedar así (por ejemplo).

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
#
# Obtener la zona de un dominio,
# a partir de los servidores de nombres
# del propio dominio.
#
#use strict;
#use warnings;
#use diagnostics;
 
# Comprobar la existencia del módulo Net::DNS
BEGIN {
    eval "use Net::DNS";
    die "ERROR al cargar el módulo Net::DNS. Instalarlo con el comando\n  cpan Net::DNS\n\n"
        if $@;
}
 
 
# Argumentos: un nombre de dominio
die "  Uso: $0 <dominio>\n\n"
    if ! @ARGV;
 
 
# Dominio y objeto Net::DNS::Resolver
my $dominio  = $ARGV[0];
my $resolver = Net::DNS::Resolver->new();
 
 
# Obtener los servidores de nombres del $dominio
my @servidores_encontrados;
my $query = $resolver->query($dominio, 'NS');
 
die "Falló la obtención de servidores de DNS: ", $resolver->errorstring, "\n"
    if !$query;
 
push @servidores_encontrados,    # almacenamos
    map  { $_->nsdname      }    # el servidor de nombre
    grep { $_->type eq 'NS' }    # que es un registro de tipo NS
    $query->answer;              # extraído de la respuesta
 
 
# Los vamos a usar para obtener la zona
$resolver->nameservers( @servidores_encontrados );
 
 
# Obtención de la zona
my @zona = $resolver->axfr($dominio);
 
die 'Falló la transferencia de zona: ', $resolver->errorstring, "\n" 
    if ! @zona;
 
$_->print for @zona;
 
exit 0;
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Transferencia de zonas DNS con Net::DNS::Resolver

Transferencia de zonas DNS con Net::DNS::Resolver

Publicidad

Re: Net::DNS

Re: Net::DNS

Re: Transferencia de zonas DNS con Net::DNS::Resolver

¿Quién está conectado?