Foro - Perl en Español

por **pablgonz** » 2020-05-16 22:20 @972

Hola a todos.

Hace días que estoy tratando de resolver un problema con el uso de .. y un reemplazo usando hash. Trataré de explicarme de la manera más clara posible.

Intento modificar algunas palabras dentro un archivo LaTeX para extraerlas con una expresión regular, para que todo quede en forma y no extraiga contenido donde no debo, hago algunos cambios dentro de algunos entornos (verbatim y verbatim write). Los entornos donde deseo hacer los cambios siempre están emparejados (aunque estén anidados), es decir inician \begin{entorno} y terminan \end{entorno}. Los nombres de estos entornos los tengo guardados en un par de array, si está todo ordenado funciona bien, pero si se cruzan las palabras mi truco falla.

Para ser más preciso, este es mi código de ejemplo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use v5.26;
use Data::Dumper;
 
### Entornos reservados
my @reservados = qw (preview nopreview);
 
### Entornos que deseo extraer por defecto
my @extr_tmp = qw ( pspicture psgraph PSTexample);
 
### Otros entornos que deseo extraer (pasado como argumento)
my @otros = qw ( Otro );
 
push (@extr_tmp,@otros,@reservados); # los junto todos
 
my $entornos = join "|", map quotemeta, sort { length $a <=> length $b } @extr_tmp;
$entornos = qr/$entornos/x;
my $extraer = qr /
                (
                    (?:
                        \\begin\{$entornos\*?\}
                      (?:
                        (?>[^\\]+)|
                        \\
                        (?!begin\{$entornos\*?\})
                        (?!end\{$entornos\*?\})|
                        (?-1)
                      )*
                      \\end\{$entornos\*?\}
                    )
                )
                /x;
 
### Entornos verbatim que conozco
my @verb_tmp = qw (verbatim Verbatim BVerbatim SaveVerbatim PSTcode);
my $verbatim = join "|", map quotemeta, sort { length $a <=> length $b } @verb_tmp;
$verbatim = qr/$verbatim/x;
 
### Entornos verbatim write que conozco
my @verbw_tmp = qw (scontents filecontents tcboutputlisting extikzpicture);
my $verbatim_w = join "|", map quotemeta, sort { length $a <=> length $b } @verbw_tmp;
$verbatim_w = qr/$verbatim_w/x;
 
### Función para crear el hash begin -> BEGIN, end -> END
sub crearhash {
    my %cambios;
    for my $aentra(@_){
        for my $initend (qw(begin end)) {
            $cambios{"\\$initend\{$aentra"} = "\\\U$initend\E\{$aentra";
            }
        }
    return %cambios;
}
 
### Función para eliminar repetidos
sub uniq {
    my %seen;
    grep !$seen{$_}++, @_;
}
 
### Función para restar
sub array_minus(\@\@) {
    my %e = map{ $_ => undef } @{$_[1]};
    return grep( ! exists( $e{$_} ), @{$_[0]} );
}
 
### Array y hash para los cambios
my %iniciofin = (
# begin/end para verbatim write
    '\begin{document}' => '\BEGIN{document}',
    '\end{document}'   => '\END{document}',
    );
 
 
 
my @noverbatimw; # tiene todo menos verbatim write
push(@noverbatimw, @extr_tmp, @verb_tmp);
@noverbatimw = uniq(@noverbatimw);
my %reemplazo_en_write = crearhash(@noverbatimw);
#print Dumper \%reemplazo_en_write; #__END__
 
my @noverbatim; # tiene todo menos verbatim
push(@noverbatim, @extr_tmp, @verbw_tmp);
@noverbatim = uniq(@noverbatim);
my %reemplazo_en_normal = crearhash(@noverbatim);
#print Dumper \%reemplazo_en_normal; #__END__
 
my $document = '
\documentclass{article}
% Usando filecontents
\begin{filecontents*}{temp.tex}
Aquí puede ir cualquier cosa escrita
\begin{document}   % cambia
\begin{Verbatim}   % cambia
\end{preview}      % cambia
\begin{preview}    % cambia
\begin{PSTexample} % cambia
\end{enumerate}
\end{filecontents*} % cierra
 
\usepackage{tikz,fvextra}
\begin{document}
 
Aquí inicia el documento real
 
\begin{Verbatim}
Aquí va cualquier cosa
\begin{filecontents*} % cambia
\begin{enumerate}
  \item First
  \begin{enumerate}
    \item Second
    \item Third
  \end{enumerate}
  \item Fourth
\end{enumerate}
\end{Verbatim} % cierra
 
Aquí otro
\begin{Verbatim}
\end{filecontents*} % cambia
Texto
\end{Verbatim} % cierra
 
Texto \begin{verbatim}
% Inicia
\begin{document}     % cambia
\begin{filecontents} % cambia
\end{PSTexample}     % cambia
\begin{preview}      % cambia
% Termina
\end{verbatim} % cierra
 
Este lo sacaré
\begin{PSTexample}
% Esto es example 1
\pspicture(4,6)
\psset{unit=2cm}
\pslineByHand[linecolor=red](0,0)(0,2)(2,2)
(2,0)(0,0)(2,2)(1,3)(0,2)(2,0)
\endpspicture
\end{PSTexample}
 
Este también lo sacaré
\begin{pspicture}(4,6)
\psset{unit=2cm}
\pslineByHand[linecolor=red](0,0)(0,2)(2,2)
(2,0)(0,0)(2,2)(1,3)(0,2)(2,0)
\end{pspicture}
 
Esto No lo sacaré
\begin{nopreview}
\begin{verbatim}
\begin{filecontents} % cambia
\begin{preview}      % cambia
\end{verbatim}
\end{nopreview}
 
Más texto
Esto igual lo sacaré
XXX\begin{preview}
\begin{verbatim}
\begin{filecontents} % cambia
\begin{preview}      % cambia
\end{verbatim}
 
\end{preview}YYYY
\end{document}
';
 
### Divido por líneas y hacemos los cambios
my @lineas = split /\n/, $document;
my %replace = (%reemplazo_en_normal,%iniciofin);
my $find    = join "|", map {quotemeta} sort { length($a)<=>length($b) } keys %replace;
my $DEL;
for (@lineas) {
    if (/\\begin\{($verbatim\*?)(?{ $DEL = "\Q$^N" })\}/ .. /\\end\{$DEL\}/) {
        s/($find)/$replace{$1}/g;
    }
    if (/\\begin\{($verbatim_w\*?)(?{ $DEL = "\Q$^N" })\}/ .. /\\end\{$DEL\}/) {
         %replace = (%reemplazo_en_write,%iniciofin); #
         $find    = join "|", map {quotemeta} sort { length($a)<=>length($b) } keys %replace;
        s/($find)/$replace{$1}/g;
    }
}
 
### Unimos y miramos
$document = join("\n", @lineas);
say $document;
 
Coloreado en 0.005 segundos,  usando GeSHi 1.0.8.4

El cual genera esta salida:

Sintáxis: [ Descargar ] [ Ocultar ]

Using latex Syntax Highlighting

\documentclass{article}
% Usando filecontents
\begin{filecontents*}{temp.tex}
Aquí puede ir cualquier cosa escrita
\BEGIN{document}   % cambia
\BEGIN{Verbatim}   % cambia
\END{preview}      % cambia
\BEGIN{preview}    % cambia
\BEGIN{PSTexample} % cambia
\end{enumerate}
\end{filecontents*} % cierra
 
\usepackage{tikz,fvextra}
\BEGIN{document}
 
Aquí inicia el documento real
 
\BEGIN{Verbatim}
Aquí va cualquier cosa
\begin{filecontents*} % cambia
\begin{enumerate}
  \item First
  \begin{enumerate}
    \item Second
    \item Third
  \end{enumerate}
  \item Fourth
\end{enumerate}
\END{Verbatim} % cierra
 
Aquí otro
\BEGIN{Verbatim}
\end{filecontents*} % cambia
Texto
\END{Verbatim} % cierra
 
Texto \BEGIN{verbatim}
% Inicia
\BEGIN{document}     % cambia
\begin{filecontents} % cambia
\END{PSTexample}     % cambia
\BEGIN{preview}      % cambia
% Termina
\END{verbatim} % cierra
 
Este lo sacaré
\BEGIN{PSTexample}
% Esto es example 1
\pspicture(4,6)
\psset{unit=2cm}
\pslineByHand[linecolor=red](0,0)(0,2)(2,2)
(2,0)(0,0)(2,2)(1,3)(0,2)(2,0)
\endpspicture
\END{PSTexample}
 
Este también lo sacaré
\BEGIN{pspicture}(4,6)
\psset{unit=2cm}
\pslineByHand[linecolor=red](0,0)(0,2)(2,2)
(2,0)(0,0)(2,2)(1,3)(0,2)(2,0)
\END{pspicture}
 
Esto No lo sacaré
\BEGIN{nopreview}
\BEGIN{verbatim}
\begin{filecontents} % cambia
\BEGIN{preview}      % cambia
\END{verbatim}
\END{nopreview}
 
Más texto
Esto igual lo sacaré
XXX\BEGIN{preview}
\BEGIN{verbatim}
\begin{filecontents} % cambia
\BEGIN{preview}      % cambia
\END{verbatim}
 
\END{preview}YYYY
\END{document}
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Pero, yo espero que sea algo así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using latex Syntax Highlighting

\documentclass{article}
% Usando filecontents
\begin{filecontents*}{temp.tex}
Aquí puede ir cualquier cosa escrita
\BEGIN{document}   % cambia
\BEGIN{Verbatim}   % cambia
\END{preview}      % cambia
\BEGIN{preview}    % cambia
\BEGIN{PSTexample} % cambia
\end{enumerate}
\end{filecontents*} % cierra
 
\usepackage{tikz,fvextra}
\begin{document}
 
Aquí inicia el documento real
 
\begin{Verbatim}
Aquí va cualquier cosa
\BEGIN{filecontents*} % cambia
\begin{enumerate}
  \item First
  \begin{enumerate}
    \item Second
    \item Third
  \end{enumerate}
  \item Fourth
\end{enumerate}
\end{Verbatim} % cierra
 
Aquí otro
\begin{Verbatim}
\END{filecontents*} % cambia
Texto
\end{Verbatim} % cierra
 
Texto \begin{verbatim}
% Inicia
\BEGIN{document}     % cambia
\BEGIN{filecontents} % cambia
\END{PSTexample}     % cambia
\BEGIN{preview}      % cambia
% Termina
\end{verbatim} % cierra
 
Este lo sacaré
\begin{PSTexample}
% Esto es example 1
\pspicture(4,6)
\psset{unit=2cm}
\pslineByHand[linecolor=red](0,0)(0,2)(2,2)
(2,0)(0,0)(2,2)(1,3)(0,2)(2,0)
\endpspicture
\end{PSTexample}
 
Este tambien lo sacaré
\begin{pspicture}(4,6)
\psset{unit=2cm}
\pslineByHand[linecolor=red](0,0)(0,2)(2,2)
(2,0)(0,0)(2,2)(1,3)(0,2)(2,0)
\end{pspicture}
 
Esto No lo sacaré
\begin{nopreview}
\begin{verbatim}
\BEGIN{filecontents} % cambia
\BEGIN{preview}      % cambia
\end{verbatim}
\end{nopreview}
 
Más texto
Esto igual lo sacaré
XXX\begin{preview}
\begin{verbatim}
\BEGIN{filecontents} % cambia
\BEGIN{preview}      % cambia
\end{verbatim}
 
\end{preview}YYYY
\end{document}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

El operador rango .. hace lo correcto, ejecuta los cambios, pero no obtengo el resultado esperado. Después de mirar bien el asunto, asumo que el problema es porque tengo palabras cruzadas entre un entorno y otro, lo cual hace que el reemplazo no sea el correcto.

No sé cómo hacer que lea el archivo y decida cuál cambio se debe efectuar primero o quizás una mejor forma de hacer esto.

Saludos.

Tengo una idea que quizás sirva de algo.

Sé que los entornos deben aparecer en líneas distintas y son disjuntos (es verbatim o verbatim write, pero no ambos), así que puedo saber con cual empezar: bastaría con capturar el número de línea en el cual hace la primera aparición en el archivo y guardarlo, algo como:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $vwNolinea; # verbatim write
my $vsNolinea; # verbatim normal
 
if ($document =~ /\\begin\{$verbatim_w\*?\}.+?/ms) {
  # Añadimos 1 a la primera línea y la guardamos
  $vwNolinea = 1 + substr($document, 0, $-[0]) =~ tr/\n//;
  #say $vwNolinea;
}
 
if ($document =~ /\\begin\{$verbatim\*?\}.+?/ms) {
  # Añadimos 1 a la primera línea y la guardamos
  $vsNolinea = 1 + substr($document, 0, $-[0]) =~ tr/\n//;
  #say $vsNolinea;
}
 
### Divido por líneas y hacemos los cambios
my @lineas = split /\n/, $document;
my %replace = (%reemplazo_en_normal,%iniciofin);
my $find    = join "|", map {quotemeta} sort { length($a)<=>length($b) } keys %replace;
my $DEL;
 
if ($vwNolinea < $vsNolinea) {
    say "Verbatim write está primero";
    for (@lineas) {
        if (/\\begin\{($verbatim_w\*?)(?{ $DEL = "\Q$^N" })\}/ .. /\\end\{$DEL\}/) {
            %replace = (%reemplazo_en_write,%iniciofin);
            $find    = join "|", map {quotemeta} sort { length($a)<=>length($b) } keys %replace;
            s/($find)/$replace{$1}/g;
        }
        last if (/\\begin\{$verbatim\*?\}/);
    }
}
 
### Unimos y miramos
$document = join("\n", @lineas);
say $document;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

y hacer que salte si la línea que encuentra es \\begin\{$verbatim\*?\} hasta que ésta cierre (\\end\{$verbatim\*?\}) y luego volver a empezar. last if no es lo correcto (creo que redo es lo que busco), seguiré intentando

por **pablgonz** » 2020-05-20 07:48 @367

Creo que he dado con la solución, al parecer mi primer enfoque usando for y el operador rango no eran las herramientas adecuadas para esto. Cambiando a while y con un par de expresiones regulares ya obtengo la salida que buscaba. El código quedó así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use v5.26;
use Data::Dumper;
 
### Función para crear el hash begin -> BEGIN, end -> END
sub crearhash {
    my %cambios;
    for my $aentra(@_){
        for my $initend (qw(begin end)) {
            $cambios{"\\$initend\{$aentra"} = "\\\U$initend\E\{$aentra";
            }
        }
    return %cambios;
}
 
### Función para eliminar repetidos
sub uniq {
    my %seen;
    return grep !$seen{$_}++, @_;
}
 
### Función para restar
sub array_minus(\@\@) {
    my %e = map{ $_ => undef } @{$_[1]};
    return grep ! exists( $e{$_} ), @{$_[0]} ;
}
 
### Entornos reservados
my @reservados = qw (preview nopreview);
 
### Entornos que deseo extraer por defecto
my @extr_tmp = qw ( pspicture psgraph PSTexample);
 
### Otros entornos que deseo extraer (pasado como argumento al script)
my @otros = qw ( Otros );
 
push @extr_tmp,@reservados,@otros; # los junto todos
@extr_tmp = uniq(@extr_tmp);
 
my $entornos = join q{|}, map {quotemeta} sort { length $a <=> length $b } @extr_tmp;
$entornos = qr/$entornos/x;
my $extraer = qr {
                   (
                    (?:
                        \\begin\{$entornos\*?\}
                      (?:
                        (?>[^\\]+)|
                        \\
                        (?!begin\{$entornos\*?\})
                        (?!end\{$entornos\*?\})|
                        (?-1)
                      )*
                      \\end\{$entornos\*?\}
                    )
                   )
                 }x;
 
### Entornos verbatim que conozco
my @verb_tmp = qw (verbatim Verbatim BVerbatim SaveVerbatim PSTcode);
 
### Entornos verbatim write que conozco
my @verbw_tmp = qw (scontents filecontents tcboutputlisting extikzpicture);
 
### Hash para algunos cambios
my %iniciofin = (
# begin/end para verbatim write
    '\begin{document}' => '\BEGIN{document}',
    '\end{document}'   => '\END{document}',
    );
 
my @noverbatimw; # tiene todo menos verbatim write
push @noverbatimw, @extr_tmp, @verb_tmp;
@noverbatimw = uniq(@noverbatimw);
my %reemplazo_en_write = crearhash(@noverbatimw);
 
my @noverbatim; # tiene todo menos verbatim normal
push @noverbatim, @extr_tmp, @verbw_tmp;
@noverbatim = uniq(@noverbatim);
my %reemplazo_en_normal = crearhash(@noverbatim);
 
my $document = '\documentclass{article}
% Usando filecontents
\begin{filecontents*}{temp.tex}
Aquí puede ir cualquier cosa escrita
\begin{document}   % cambia
\begin{Verbatim}   % cambia
\end{preview}      % cambia
\begin{preview}    % cambia
\begin{PSTexample} % cambia
\end{enumerate}
\end{filecontents*} % cierra
 
\usepackage{tikz,fvextra}
\begin{document}
 
Aquí inicia el documento real
 
\begin{Verbatim}
Aquí va cualquier cosa
\begin{filecontents*} % cambia
\begin{enumerate}
 \item First
 \begin{enumerate}
   \item Second
   \item Third
 \end{enumerate}
 \item Fourth
\end{enumerate}
\end{Verbatim} % cierra
 
Aquí otro
\begin{Verbatim}
\end{filecontents*} % cambia
Texto
\end{Verbatim} % cierra
 
Texto \begin{verbatim}
% Inicia
\begin{document}     % cambia
\begin{filecontents} % cambia
\end{PSTexample}     % cambia
\begin{preview}      % cambia
% Termina
\end{verbatim} % cierra
 
Este lo sacaré
\begin{PSTexample}
% Esto es example 1
\pspicture(4,6)
\psset{unit=2cm}
\pslineByHand[linecolor=red](0,0)(0,2)(2,2)
(2,0)(0,0)(2,2)(1,3)(0,2)(2,0)
\endpspicture
\end{PSTexample}
 
Este también lo sacaré
\begin{pspicture}(4,6)
\psset{unit=2cm}
\pslineByHand[linecolor=red](0,0)(0,2)(2,2)
(2,0)(0,0)(2,2)(1,3)(0,2)(2,0)
\end{pspicture}
 
Esto No lo sacaré
\begin{nopreview}
\begin{verbatim}
\begin{filecontents} % cambia
\begin{preview}      % cambia
\end{verbatim}
\end{nopreview}
 
Más texto
Esto igual lo sacaré
XXX\begin{preview}
\begin{verbatim}
\begin{filecontents} % cambia
\begin{preview}      % cambia
\end{verbatim}
 
\end{preview}YYYY
\end{document}
';
 
### Creamos un par de expresiones regulares para verbatim y verbatim write
my $verbatim = join q{|}, map {quotemeta} sort { length $a <=> length $b } @verb_tmp;
$verbatim = qr/$verbatim/x;
my $verb_std = qr {
                (
                    (?:
                        \\begin\{$verbatim\*?\}
                      (?:
                        (?>[^\\]+)|
                        \\
                        (?!begin\{$verbatim\*?\})
                        (?!end\{$verbatim\*?\})|
                        (?-1)
                      )*
                      \\end\{$verbatim\*?\}
                    )
                )
                }x;
 
my $verbatim_w = join q{|}, map {quotemeta} sort { length $a <=> length $b } @verbw_tmp;
$verbatim_w = qr/$verbatim_w/x;
my $verb_wrt = qr {
                (
                    (?:
                        \\begin\{$verbatim_w\*?\}
                      (?:
                        (?>[^\\]+)|
                        \\
                        (?!begin\{$verbatim_w\*?\})
                        (?!end\{$verbatim_w\*?\})|
                        (?-1)
                      )*
                      \\end\{$verbatim_w\*?\}
                    )
                )
                }x;
 
### Cambios usando hash
my %replace = (%reemplazo_en_write,%iniciofin);
my $find    = join q{|}, map {quotemeta} sort { length $a <=> length $b } keys %replace;
 
### Recorremos línea a línea y hacemos los cambios (/p para ${^MATCH})
while ($document =~ /$verb_wrt | $verb_std /pgmx) {
    my ($pos_inicial, $pos_final) = ($-[0], $+[0]);
    my $encontrado = ${^MATCH};
    if ($encontrado =~ /$verb_wrt/) {
        $encontrado =~ s/($find)/$replace{$1}/g;
        substr $document, $pos_inicial, $pos_final-$pos_inicial, $encontrado;
        pos ($document) = $pos_inicial + length $encontrado;
    }
    if ($encontrado =~ /$verb_std/) {
        %replace = (%reemplazo_en_normal,%iniciofin);
        $find    = join q{|}, map {quotemeta} sort { length $a <=> length $b } keys %replace;
        $encontrado =~ s/($find)/$replace{$1}/g;
        substr $document, $pos_inicial, $pos_final-$pos_inicial, $encontrado;
        pos ($document) = $pos_inicial + length $encontrado;
    }
}
 
say $document;
 
__END__
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

No se si el código está del todo correcto, pero, cumple su función

Foro - Perl en Español

Uso del operador rango y reemplazo con hash

Uso del operador rango y reemplazo con hash

Publicidad

Re: Uso del operador rango y reemplazo con hash

Re: Uso del operador rango y reemplazo con hash

¿Quién está conectado?