Foro - Perl en Español

por **explorer** » 2012-02-09 16:27 @727

Bueno, de aquí ya sabemos por qué solo procesa la última secuencia del fichero.

Resulta que en la línea 15 haces un chomp(), pero como la combinación de fin de línea es distinta de la del sistema operativo en donde estás, no consigue quitar esos caracteres, así que quedan dentro de %es_interesante. Excepto la última secuencia de JGI_list2.txt, ya que no tiene esos finales.

La línea 46, entonces, solo coincide con la última secuencia.

La solución pasa por un filtrado eficaz de estos ficheros.

Estamos en ello...

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
 
my %es_interesante;
 
# Lectura de la lista de secuencias
print "Enter your list name:\n";
my $entrada = <STDIN>;
chomp $entrada;                             # nos aseguramos que leemos bien el nombre del archivo
 
open(SEQ, $entrada) or die ("ERROR: $!\n");
 
while (my $linea = <SEQ>) {
    $linea =~ s/^(?:\xEF\xBB\xBF|\xFE\xFF|\xFF\xFE)// if $. == 1;       # quitar el BOM en la primera línea
    $linea =~ s/[\012\015]+$//;                                         # quitamos los finales de línea
 
    $es_interesante{$linea} = 1;            # la almacenamos en la memoria asociativa
}
 
close SEQ;
 
use Data::Dumper::Simple;
print Dumper %es_interesante;               # comprobamos lo leído
 
__END__
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Hemos sustituido el chomp() por una expresión regular, que nos garantiza la eliminación de cualquier combinación de caracteres de final de línea (incluso de Mac). También quitamos el BOM de la primera línea.

El Dumper nos muestra que ahora sale correcta la estructura que queremos:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

%es_interesante = (
                    'Agabi_varbisH97_2_121121' => 1,
                    'Agabi_varbisH97_2_59298' => 1,
                    'Agabi_varbisH97_2_71341' => 1,
                    'Agabi_varbisH97_2_118433' => 1,
                    'Agabi_varbisH97_2_194831' => 1
                  );
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

en lugar del estropicio que teníamos antes:

Sintáxis: [ Descargar ] [ Ocultar ]

Using bash Syntax Highlighting

explorer@casa:~/Documentos/Desarrollo/alfumao> perl code_29648.pl 
Enter your list name:
JGI_list2.txt
%es_interesante = (
                    'Agabi_varbisH97_2_136529' => 1,
' => 1,             'Agabi_varbisH97_2_181811
' => 1,             'Agabi_varbisH97_2_205367
' => 1,             'Agabi_varbisH97_2_80166
' => 1,             'Agabi_varbisH97_2_62215
' => 1,             'Agabi_varbisH97_2_113535
' => 1              'Agabi_varbisH97_2_189137
                  );
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Observa cómo los caracteres finales de línea, al final de los nombres de secuencia, hacen desplazar las comillas al borde izquierdo, excepto en el caso de la última $linea leída, ya que JGI_list2.txt no tiene esos caracteres en esa línea.

Esta es otra versión:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
use File::Slurp;
 
my %es_interesante;
 
# Lectura de la lista de secuencias
print "Enter your list name:\n";
my $entrada = <STDIN>;
chomp $entrada;
 
my $fichero = read_file($entrada);                      # Leemos el fichero entero
 
$fichero =~ s/^(?:\xEF\xBB\xBF|\xFE\xFF|\xFF\xFE)//;    # Quitar el BOM
 
my @lineas = split /[\012\015]+/, $fichero;             # Separar las líneas, quitando los finales
 
for my $linea (@lineas) {
    $es_interesante{$linea} = 1;                        # la almacenamos en la memoria asociativa
}
 
use Data::Dumper::Simple;
print Dumper %es_interesante;
 
__END__
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

El proceso es ligeramente distinto: haces todo el procesamiento en memoria, leyendo el archivo completamente, y usando split() para hacer la división de las líneas.

por **Alfumao** » 2012-02-10 05:16 @261

Un millón de gracias explorer, voy a ponerlo en práctica e incorporar los cambios en los cgi y os cuento qué tal ha ido.

-> En Windows lee todas las listas (la creada en Linux y utilizada en Windows antes no la leía).

Mañana toca día Linux y os cuento qué tal me ha funcionado allí, pero las expectativas son muy buenas.

por **Alfumao** » 2012-02-14 04:17 @220

Gracias una vez más, explorer, el cgi va como la seda, ahora...
:wink:

PD. Sigo intentando arreglar lo de las tildes en Linux, ¡ja,ja,ja!

Foro - Perl en Español

Problemas y problemas con Linux y CGI

Re: Problemas y problemas con Linux y CGI

Publicidad

Re: Problemas y problemas con Linux y CGI

Re: Problemas y problemas con Linux y CGI

Re: Problemas y problemas con Linux y CGI

Re: Problemas y problemas con Linux y CGI

¿Quién está conectado?