Foro - Perl en Español

por **explorer** » 2013-07-04 13:06 @587

Las variables de las líneas 23 a 25 deben reinicializarse por cada archivo que se procese, no solo al principio. Faltan estas líneas:
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using perl Syntax Highlighting
1. undef $en_line;
2. undef $seccion;
3. undef @seccion;
Coloreado en 0.002 segundos, usando GeSHi 1.0.8.4
Tienes una doble línea "while (<INPUT>) {", en las líneas 46 y 47. Eso provoca que no se procese la primera línea de los archivos.

Otros detalles:

@extensiones solo contiene 'txt' y 'TXT'. No necesitas esta variable ni el bucle de la línea 36 porque la expresión regular de la línea 37, con la opción /i ya tiene en cuenta el caso del cambio de mayúsculas. Las líneas 35 a 41 quedarían mejor así:
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using perl Syntax Highlighting
1. $extension_correcta = $nombre_en_servidor =~ /[.]txt$/i;
Coloreado en 0.001 segundos, usando GeSHi 1.0.8.4
con la ayuda de autodie, en la línea 11, no necesitas decir la frase 'or die "ERROR: No puedo abrir $file: $!\n";', salvo que quieras que el mensaje salga en español
la apertura y cierre del archivo $file, en las líneas 31 y 74, estaría mejor ponerlo dentro del if() de la línea 42 a 73. Así, el archivo solo se abre si la extensión es correcta
la variable $directorio no la estás usando para nada. Quizás te falta esta línea:
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using perl Syntax Highlighting
1. chdir $directorio;
Coloreado en 0.001 segundos, usando GeSHi 1.0.8.4

#!/usr/bin/perl
 
if ( @ARGV != 1 ) {
    die "\nUse: $0 <dir>\n\n" . "   <dir>    \n";
 
}
 
$directorio = $ARGV[0];
chomp $directorio;
use feature say;
use autodie;                           # «Es mejor morir que regresar con deshonor» --proverbio Klingon
 
# Extensiones permitidas
@extensiones = ( 'txt', 'TXT' );
use CGI ':standard';
 
my %informacion_recomendada = (
    'con 0' => [ 'system reset', 'canales 2' ],
    'vty 0' => [ 'system reset', 'canales 3' ],
    'vty 5' => [ 'system reset', 'canales 3' ],
);
 
my $en_line = '';
my $seccion;                           # nombre de la sección
my @seccion;                           # contenido de la sección
chdir $directorio;
 
opendir( DIR, '.' );
print "Analizando directorio - /$directorio/\n";
while ( $file = readdir(DIR) ) {
    undef $en_line;
    undef $seccion;
    undef @seccion;
 
    next if not -f $file;              # saltar al siguiente si no es un archivo txt
    open( INPUT, $file ) or die "ERROR: No puedo abrir $file: $!\n";
    $nombre_en_servidor = $file;
    $nombre_en_servidor =~ s/ /_/gi;
    $nombre_en_servidor =~ s!^.*(\\|\/)!!;
    $extension_correcta = 0;
    foreach (@extensiones) {
        if ( $nombre_en_servidor =~ /\.$_$/i ) {
            $extension_correcta = 1;
            last;
        }
    }
    if ($extension_correcta) {
 
        print "\t$file\n";
 
        while (<INPUT>) {
            chomp;
 
            if ( not $en_line ) {      # aún no hemos encontrado un "line"
                next if not /^line/;   # y en esta línea,tampoco está. Saltamos a la siguiente
 
                $en_line = 1;          # ¡encontrado!
            }
            elsif (/^!/) {
                last;                  # encontrado un '!' en una sección,terminamos inmediatamente
            }
 
            if (/^line (.+)/) {        # analizamos si la línea contiene un 'line'
                if ($seccion) {        # si tenemos una sección ya leída,
                    imprime_seccion(); # la procesamos
                }
 
                my @palabras = split " ", $1;    # separamos por los espacios en blanco
                $seccion = join " ",
                    @palabras[ 0, 1 ]; # recomponemos el nombre de la sección,con las dos primeras palabras
                undef @seccion;        # ponemos a cero el almacén
                next;                  # pasamos a la siguiente línea
            }
 
            push @seccion, $_;         # una línea normal: la guardamos en la sección
        }
    }
    close INPUT;
}
closedir DIR;
imprime_seccion();                     # procesamos la última sección
 
sub imprime_seccion {
    say uc $seccion;
 
    if ( not exists $informacion_recomendada{$seccion} ) {
        say Tr( td( { -bgcolor => 'red' }, 'Sección no reconocida' ) );
    }
    else {
        my @comandos_esperados = @{ $informacion_recomendada{$seccion} };
        my @seccion_filtrada   = @seccion;
 
        ## Sacamos de la sección leída los comandos que esperamos
        for my $comando_esperado (@comandos_esperados) {
            @seccion_filtrada = grep { $comando_esperado ne $_ } @seccion_filtrada;
        }
 
        ## Sacamos de los comandos esperados los comandos que hemos leído
        for my $comando_leido (@seccion) {
            @comandos_esperados = grep { $comando_leido ne $_ } @comandos_esperados;
        }
 
        ## Informamos de los comandos esperados que no hemos encontrado
        for my $comando_esperado (@comandos_esperados) {
            say Tr( td("FALTA : $comando_esperado") );
        }
 
        ## Informamos de los comandos que hemos recibido de más
        for my $comando_leido (@seccion_filtrada) {
            say Tr( td("MAL : $comando_leido") );
        }
    }
}
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2013-07-06 07:03 @335

La línea

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

imprime_seccion();                     # procesamos la última sección
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

debe colocarse justo después del bucle while() de las líneas 51-76.

por **situ** » 2013-07-06 18:31 @813

Muchas gracias.

por **situ** » 2013-07-06 21:37 @942

Vuelvo nuevamente con mis consultas =(

¿Hay alguna posibilidad de meter regex en:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my %informacion_recomendada = (
    'con 0' => [ 'system reset', 'canales 2', 'datos 3' ],
    'vty 0' => [ 'system reset', 'canales 3', 'datos 4' ],
    'vty 5' => [ 'system reset', 'canales 3', 'datos 5' ],
);
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

?

Digamos que yo necesito, por ejemplo, que me tome como bien si aparece datos, digamos; no me importa lo que sigue, ya para mi está correcto, ya que solamente necesito que esté datos.

Saludos.

por **explorer** » 2013-07-07 11:35 @524

Bien... el tema se sigue complicando... así que hace falta una solución más complicada...

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
 
use feature "say";
use autodie;                    # «Es mejor morir que regresar con deshonor» --proverbio Klingon
 
use CGI ':standard';
 
my %informacion_recomendada = (
    'con 0'     => [ 'system reset', 'canales 2', qr'datos \d+' ],
    'vty 0'     => [ 'system reset', 'canales 3', ],
    'vty 5'     => [ 'system reset', 'canales 3', ],
);
 
my $seccion;            # nombre de la sección
my @seccion;            # contenido de la sección
 
open my $LOG, 'server.txt';
while (<$LOG>) {
    chomp;
 
    my $es_eof = eof $LOG;                      # comprobamos si es fin de archivo
 
    if (/^!/ or /^line (.+)/ or $es_eof) {      # analizamos la línea, por si es especial
        if ($seccion) {                         # si tenemos una sección leída,
            imprime_seccion();                  # la procesamos
        }
 
        last if /^!/ or $es_eof;                # terminamos enseguida si es fin de todas las secciones 'line'
 
        ## nueva sección 'line'
        my @palabras = split " ", $1;           # separamos por los espacios en blanco
        $seccion = join " ", @palabras[0, 1];   # recomponemos el nombre de la sección, con las dos primeras palabras
        undef @seccion;                         # ponemos a cero el almacén
 
        next;                                   # pasamos a la siguiente línea
    }
 
    next if not $seccion;                       # no guardamos línea si aún no estamos en ninguna sección
 
    push @seccion, $_;                          # una línea normal: la guardamos en la sección
}
 
close $LOG;
 
 
sub imprime_seccion {
    say Tr(td({-bgcolor => '#F8AD18'}, uc $seccion));
 
    if (not exists $informacion_recomendada{ $seccion }) {
        say Tr(td({-bgcolor => 'red'}, 'Sección no reconocida'));
    }
    else {
        my @comandos_esperados = @{ $informacion_recomendada{ $seccion } };
        my @comandos_no_ejecutados;
 
        ## Sacamos de la sección leída los comandos que esperamos
        for my $comando_esperado (@comandos_esperados) {
 
            my $encontrado = 0;                         # ¿hemos encontrado el comando esperado en la seccion?
            my @seccion_filtrada;                       # la @seccion, filtrada (sin los comandos esperados)
    
            for my $comando_leido (@seccion) {
 
                if (ref($comando_esperado) eq 'Regexp') {       # si es una exp. reg.
                    
                    if ($comando_leido =~ /$comando_esperado/) {
                        $encontrado = 1;
                        next;
                    }
                }
                elsif ($comando_leido eq $comando_esperado) {   # si es una cadena de caracteres
                    $encontrado = 1;
                    next;
                }
 
                push @seccion_filtrada, $comando_leido;         # no coincide, lo recordamos para la siguiente vuelta
            }
 
            @seccion = @seccion_filtrada;
 
            if (not $encontrado) {
                push @comandos_no_ejecutados, $comando_esperado;
            }
        }
 
 
        ## Informamos de los comandos esperados que no hemos encontrado
        for my $comando_no_ejecutado (@comandos_no_ejecutados) {
            say Tr(td("FALTA : $comando_no_ejecutado"));
        }
 
        ## Informamos de los comandos que hemos recibido de más
        for my $comando_leido (@seccion) {
            say Tr(td("MAL : $comando_leido"));
        }
    }
}
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Los cambios principales son:

En la definición de %informacion_recomendada, en caso de que queramos poner un patrón, lo marcaremos con qr(), que lo que hace es precisamente eso
El bucle de la 18 a la 42 se ha ampliado para contemplar el caso de fin de archivo, dentro del propio bucle: ya no es necesario llamar a imprime_seccion() al final del bucle
imprime_seccion() ha cambiado bastante. Pasamos de hacer una resta entre conjuntos a un doble bucle, recorriendo todos los comandos leídos en cada @seccion, por todos los @comandos_esperados. Si existe coincidencia entre los dos, se elimina la entrada correspondiente de los dos arrays de comandos. Al final, sigue quedando la misma diferencia entre los dos conjuntos, pero había que hacerlo así (es la forma que he encontrado) para contemplar el caso de que uno de los comandos esperados sea un patrón de exp. reg.

Lo he probado añadiendo un "datos 3", y funciona.

por **situ** » 2013-07-07 14:24 @642

Muchas gracias, creo que nunca iba a poder hacerlo =( , ahora tendré que ver cómo adaptar tu código al mio, en el sentido que yo debo correrlo sobre todos los .txt del directorio que le debo pasar como argumento.

por **situ** » 2013-07-09 20:30 @896

situ escribiste:Perdón, pero ahora estoy teniendo otra problemática con el script, lo anterior funcionó perfecto.

Obtengo los datos del archivo server.txt. Perdón, pero no sé cómo hacer el "grep" en Perl. Lo intenté y como no lo logré, lo dejé.

Aquí me quedo con las 20 líneas luego de identificar "linea con1":
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using perl Syntax Highlighting
@lineacon1=`grep -e \"^linea con1\" -A20 \"server.txt\"`;

Coloreado en 0.001 segundos, usando GeSHi 1.0.8.4

En @lineacon1 tengo algo como esto:

Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using text Syntax Highlighting

linea con1
system reset
canales 2
acceso denegado
linea con2
Coloreado en 0.000 segundos, usando GeSHi 1.0.8.4

Como se puede apreciar, dentro de estas líneas tengo "linea con2", esto me muestra que en ya salí de "linea con1" y estoy entrando en otra configuración, y no debería hacerlo. Para esto, usé la siguiente regex:

Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using perl Syntax Highlighting

foreach $lineacon1(@lineacon1) {

## Paso al siguiente foreach cuando encuentro el nombre de la siguiente línea o si comienza con un !

if ($lineacon1 =~ m/^linea\scon1|^!/) {

last;

}

else {

print F "$lineacon1\n";

}

}

Coloreado en 0.001 segundos, usando GeSHi 1.0.8.4

Ahora mi problema se presenta en que debo hacer lo mismo que hicimos para "ntp": debo hacer comprobaciones y mostrar si algo está mal o si falta algún parámetro.

Digamos:
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using perl Syntax Highlighting
@blineacon0=("system reset","canales 2","acceso denegado")

Coloreado en 0.001 segundos, usando GeSHi 1.0.8.4

La verdad que traté de adaptar lo anterior pero ahora al tener la regex para ver cuando salto a "linea con2" me complicó todo.

Saludos.

Al final usé este script y pude hacer las comprobaciones, sé que no es el más óptimo pero no logré hacer funcionar tu script.

Ahora detecté otro problema: muchas veces las configuraciones no tienen la line vty 5 15 por lo cual el script me informa que no tengo configurado los parámetros de ésta, pero al no tener esa línea está bien que no estén los parámetros.

Yo hasta el momento usaba esta regex para cortar el contenido y identificar la próxima line vty.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

        if ($lineacon1 =~ m/^linea\scon1|^!/) {
                last;
        }
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Para la line vty 5 15 tengo esto, donde busco el signo para cortar el contenido del array, pero ahora no sé cómo hacer para que compruebe si existe o no la línea line vty 5 15.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

 if ($linevty5 =~ m/^!/) {
                last;
        }
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Para no marearlos tanto la idea sería ver si está esa línea y sino está es que continúe con el script pero sin comprobar los parámetros de ésta ya que no existe.

Foro - Perl en Español

Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Publicidad

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

¿Quién está conectado?