Foro - Perl en Español

por **situ** » 2011-01-25 20:02 @876

Les molesto nuevamente porque hice un script y la verdad que no me resulta muy competente. Por este motivo quería consultarles si pueden darme una mano.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
use Term::ANSIColor qw(:constants);
print"----------------------------------------------------------------------------------------------------------------\n";
$comando2 = (split " ",( qx(grep ^PASS_MAX_DAY /etc/login.defs))[0] )[1];
chomp $comando2;
if ("$comando2" != 90) {
 
   print BOLD, RED, "Negativo:", RESET . " El valor del parametro PASS_MAX_DAYS es incorrecto\n";  
 
   }
 
    else{
 
        print  BOLD, GREEN, "Positivo:", RESET . " El valor del parametro PASS_MAX_DAYS es correcto\n";
 
          }
 
$comando3 = (split " ",( qx(grep ^PASS_MIN_DAYS /etc/login.defs))[0] )[1];
 
chomp $comando3;
if ("$comando3" != 7) {
   print BOLD, RED, "Negativo:", RESET . " El valor del parametro PASS_MIN_DAYS es incorrecto\n";   
 
   }
 
    else{
 
        print  BOLD, GREEN, "Positivo:", RESET . " El valor del parametro PASS_MIN_DAYS es correcto\n";
          }       
  
$comando4 = (split " ",( qx(grep ^PASS_WARN_AGE /etc/login.defs))[0] )[1];
chomp $comando4;
if ("$comando4" != 28) {
   print BOLD, RED, "Negativo:", RESET . " El valor del parametro PASS_WARN_AGE es incorrecto\n";
    
   }
   else{
        print  BOLD, GREEN, "Positivo:", RESET . " El valor del parametro PASS_WARN_AGE es correcto\n";
 
          }
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Gracias.

#!/usr/bin/perl
#
# Análisis del fichero /etc/login.defs
#
# Joaquín Ferrero, 20110126
#
use common::sense;
use autodie;
 
use Term::ANSIColor qw(:constants);
 
use open ':locale';
 
say( '-' x 112 );
 
my $FICHERO = '/etc/login.defs';
 
my $login_defs = do { undef $/; open F, $FICHERO; <F> };
 
my %valor_correcto_de = (
    PASS_MAX_DAYS => 90,
    PASS_MIN_DAYS =>  7,
    PASS_WARN_AGE => 28,
    ZZZ_PARAMETRO => 1,
);
 
for my $parámetro (sort keys %valor_correcto_de) {
 
    if (my($valor_actual) = $login_defs =~ /^ $parámetro \s+ (\S+?) $/xsim) {
 
        if ($valor_actual == $valor_correcto_de{$parámetro}) {
            say BOLD, GREEN, 'Positivo: ', RESET, "El valor del parámetro $parámetro es correcto";
        }
        else {
            say BOLD, RED  , 'Negativo: ', RESET, "El valor del parámetro $parámetro es incorrecto: ",
                "$valor_actual != $valor_correcto_de{$parámetro}";
        }
    }
    else {
        say BOLD . 'No existe ' . RESET, "el parámetro $parámetro en $FICHERO";
    }
}
 
say( '-' x 112 );
 
__END__
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **situ** » 2011-01-26 13:11 @591

Voy a probarlo, muchísimas gracias.
Saludos.

por **situ** » 2011-01-27 18:32 @814

Te hago una consulta: guardé la variable en un archivo aparte y lo importe con "do", pero ahora no me funciona.

El archivo tiene lo siguiente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my%valor_correcto_de=(

    PASS_MAX_DAYS => 90,

    PASS_MIN_DAYS =>  7,

    PASS_WARN_AGE => 28,
);Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Si le saco el "my" o le agrego "our" tampoco me anda. Perdón, pero no logro saber cómo es. Con variables que no son hash me anda perfecto.

por **explorer** » 2011-01-27 18:59 @832

El error está en el my(). Este operador declara (e inicializa) variables en el contexto donde está, así que entonces, la variable hash no será conocida en el programa principal.

Bueno, además, yo suelo usar casi siempre los strict y warnings activados, así que saldrán avisos en pantalla si el programa ve que uso el hash sin haberlo declarado...

Así que hay que hacer cambios en los códigos.

En el programa principal, antes del do(), hago un

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

our %valor_correcto_de;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

que declara a esa variable como global a todo el fichero donde se encuentre. Ahora Perl ya sabe que existe y que puedo usarla en el resto del programa.

Y en el fichero a importar con do():

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

%valor_correcto_de = (
    PASS_MAX_DAYS => 90,
    PASS_MIN_DAYS =>  7,
    PASS_WARN_AGE => 28,
    ZZZ_PARAMETRO => 1,
);
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Es decir: declaro e inicializo una variable global (no hay my() ni our(), pero como tampoco hay warnings ni strict, así perl no se queja). do() carga el código y se lo pasa al analizador de expresiones de Perl, que lo interpretará. Como ya conoce, de antes, a la variable hash, pues...

por **situ** » 2011-01-27 19:03 @835

Muchas gracias; como siempre me salvas =)
Saludos.

por **situ** » 2011-01-31 14:30 @645

Te hago una consulta desde mi ignorancia.

Estoy parseando con tu script el archivo /etc/ssh/sshd_config, donde seteo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

%valor_correcto_ssh = (
    Protocol => 2,
    PermitRootLogin => no,
);
 
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Y como regex:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

    if (my($valor_actual_ssh) = $var_ssh =~ /^ $parametro3 \s+ (\S+?) $/xsim) {
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

El tema es que si lo uso así no me entrega datos y si quiero ver la info de los otros parseos que tengo, tampoco obtengo info. No sé si me explico bien.

Saludos.

por **explorer** » 2011-01-31 14:44 @655

Yo no veo problemas en ese código...

Foro - Perl en Español

Análisis del archivo /etc/login.defs

Análisis del archivo /etc/login.defs

Publicidad

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

¿Quién está conectado?