Foro - Perl en Español

por **Kuronno** » 2012-12-09 20:20 @889

Hola,
he hecho un script que me permite abrir el archivo "funcions.txt" donde solo me interesan las líneas que contengan "glycolisis" o "neogenesis" porque llevan un código que necesito posteriormente.

Una vez consigo esta información quiero leer el archivo "lee.txt" para extraer de él las líneas que contengan los códigos anteriores y guardarlos en:

- GL.txt: si contiene los códigos de glycolisis
- NL.txt: si contiene los códigos de neogenesis

El script que he ideado es el siguiente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use strict;
open( arxiu,  "funcions.txt" ) or die("No el puc obrir");
open( arxiu1, "lee.txt" )      or die("No el puc obrir!");
open( arxiu2, ">GL.txt" )      or die("el GL no s'obre");
open( arxiu3, ">NL.txt" )      or die("el GL no s'obre");
while (<arxiu>) {
 
    my @llista = split( /\t/, $_ );
    if ( $llista[1] =~ /glycolysis/ ) {
 
        my @gensGL = $llista[0];
 
    }
    if ( $llista[1] =~ /neogenesis/ ) {
 
        my @gensNL = $llista[0];
    }
 
    while (<arxiu1>) {
        my @llista2 = split( /\t/, $_ );
 
        if ( $llista2[1] eq $gensGL[0] ) {
            print arxiu2 "$_";
        }
        if ( $llista2[1] eq $gensNL[0] ) {
            print arxiu3 "$_";
        }
    }
}
close(arxiu)  or die("no el puc tancar");
close(arxiu1) or die("no el puc tancar");
close(arxiu2) or die("no el puc tancar");
close(arxiu3) or die("no el puc tancar");
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

Por desgracia me sale error: requires explicit package name (refiriéndose a @gensNL y @gensGL dentro de los últimos dos "if" del script). No consigo solventar este problema y me gustaría saber si seríais tan amables de ayudarme.

Muchas gracias,

Kuronno.

entonces, cuando se repite el bucle de la línea 6 para la siguiente línea de funcions.txt, al llegar a la línea 19 se encuentra con que no puede leer las líneas de lee.txt, ya que fueron leídos todas antes.

El error dice que en las líneas 22 y 25 haces referencia a las variables @gensGL y @gensNL, y Perl no sabe dónde fueron declaradas ni definidas.

El problema está en que en las líneas 11 y 16 las estás declarando y definiendo con un valor, pero locales al contexto (las llaves) que las rodean. Por ejemplo: en la línea 11 estás declarando un nueva variable llamada @gensGL (usando el operador my()), y le das un valor inicial (el primer elemento de @llista). Pero, en cuanto Perl llega a la línea 13, se olvida de ella, porque al declararla con my(), le indicaste a Perl que esa variable debía ser local al contexto en donde se encuentra (las llaves de las líneas 9 y 13).

La solución mejor para este problema sería leer en memoria uno de los dos archivos, y luego recorrer el otro, y si se cumple la condición que impongamos, grabar el resultado en un archivo o en otro.

Por estos foros hay problemas parecidos ya resueltos. Por ejemplo: Comparar líneas entre archivos.

por **Kuronno** » 2012-12-10 05:41 @278

En primer lugar, muchas gracias por tu respuesta. Desconocía que mi error fuera tan grave.
Desconozco cómo puedo leer en memoria uno de los dos archivos y recorrer el otro. Nunca he hecho una instrucción así en un contexto de este tipo. Por ese motivo estoy bloqueado y aún consultando por los enlaces que me has añadido no consigo solucionarlo.
¿Me podrías poner un ejemplo de cómo sería?
Muchas gracias.

por **explorer** » 2012-12-10 13:15 @594

Esta es una posible solución, pero no sé si funciona ya que no sabemos muy bien el formato real de los archivos. Solo sabemos que se componen de campos separados por tabuladores, pero no sabemos si los id se repiten o no.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
use autodie;            # Es mejor morir que regresar con deshonor --Proverbio Klingon
 
## Abrimos el primer archivo y leemos los códigos
open my $ARXIU, '<', 'funcions.txt';
 
my(%gensGL, %gensNL);                   # aquí guardamos los códigos
 
while (<$ARXIU>) {
    my($id,$funcion) = split /\t/;
 
    if ($funcion =~ /glycolysis/) {
        $gensGL{$id} = 1;               # recordamos ese código
    }
    if ($funcion =~ /neogenesis/) {
        $gensNL{$id} = 1;               # recordamos ese código
    }
}
 
close $ARXIU;
 
 
## Leemos el segundo archivo, desviando las líneas hacia las salidas
open my $ARXIU1, '<', 'lee.txt';
open my $GL,     '>', 'GL.txt';
open my $NL,     '>', 'NL.txt';
 
while (<$ARXIU1>) {
    my(undef,$id) = split /\t/;
 
    if (exists $gensGL{$id}) {          # si existe un código de glycolysis para ese $id,
        print $GL $_;                   # mandamos la línea al archivo correspondiente
    }
    if (exists $gensNL{$id}) {          # si existe un código de neogenesis para ese $id,
        print $NL $_;                   # mandamos la línea al archivo correspondiente
    }
}
close $ARXIU1;
close $GL;
close $NL;
 
 
__END__
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Extracción de líneas coincidentes

Extracción de líneas coincidentes

Publicidad

Re: Extracción de líneas coincidentes

Re: Extracción de líneas coincidentes

Re: Extracción de líneas coincidentes

¿Quién está conectado?