Foro - Perl en Español

explorer escribiste:Precisamente, el operador Coincidencia inteligente está para evitar muchos de los dobles bucles que hacíamos en el siglo pasado.

El truco está, primero, en ahorrar código sacando la información que nos interesa para que sea más fácil de tratar. En tu caso, hay que simplificar el acceso a @username, ya que estás continuamente extrayendo el nombre del usuario con una expresión regular. Mejor hacerlo una vez y ya está. Y segundo: usar la Coincidencia inteligente para comprobar la existencia de cada usuario en el array que nos interesa.

Aparte, te hago notar que para ejecutar solo la parte negada de un if(), puedes a) negar la condición, o b), usar unless().

Otro detalle: no puedes poner '>' dentro de un código HTML sin que pertenezca a una marca HTML. Debes escribirlo como '>'. Si no, estarás escribiendo HTML erróneo.

Sintáxis: [ Descargar ] [ Ocultar ]

Sintáxis: [ Descargar ] [ Mostrar ]

Using perl Syntax Highlighting

1. #!/usr/bin/perl
2.  
3. my @busername = qw(
4.     manolo
5.     margarita
6.     fungencio
7. );
8.  
9. my @username =
10.     ( 'username rosa acceso 1'
11.     , 'username manolo acceso 2'
12.     , 'username manolo acceso 3'
13.     , 'username garcia acceso 1'
14.     , 'username margarita acceso 2'
15.     , 'username antonio acceso 3'
16. );
17.  
18. my @usuarios_que_han_accedido;
19. foreach my $acceso (@username) {
20.     if (   $acceso =~ m/^username\s(.*)\sacceso/ ) {
21.         push @usuarios_que_han_accedido, $1;
22.     }
23. }
24.  
25. foreach   my $usuario_que_ha_accedido (@usuarios_que_han_accedido) {
26.     unless ( $usuario_que_ha_accedido ~~ @busername ) {
27.         print "<tr><td>Usuario= $usuario_que_ha_accedido -&gt; MAL</td></tr>\n";
28.     }
29. }
30.  
31. foreach   my $usuario_del_sistema (@busername) {
32.     unless ( $usuario_del_sistema ~~ @usuarios_que_han_accedido ) {
33.         print "<tr><td>Usuario= $usuario_del_sistema -&gt; NO SE ENCUENTRA CONFIGURADO</td></tr>\n";
34.     }
35. }

Coloreado en 0.001 segundos, usando GeSHi 1.0.8.4

Salida:

Sintáxis: [ Descargar ] [ Ocultar ]

Sintáxis: [ Descargar ] [ Mostrar ]

Using text Syntax Highlighting

<tr><td>Usuario= rosa -&gt; MAL</td></tr>
<tr><td>Usuario= garcia -&gt; MAL</td></tr>
<tr><td>Usuario= antonio -&gt; MAL</td></tr>
<tr><td>Usuario= fungencio -&gt; NO SE ENCUENTRA CONFIGURADO</td></tr>

Coloreado en 0.000 segundos, usando GeSHi 1.0.8.4

Pero... en cuestiones de comparación, de existencia de un elemento dentro de un conjunto, es mucho mejor usar los hash. Lo siguiente es mi versión:

Sintáxis: [ Descargar ] [ Ocultar ]

Sintáxis: [ Descargar ] [ Mostrar ]

Using perl Syntax Highlighting

1. #!/usr/bin/perl
2. use v5.14;            # activa say(), strict y warnings;
3. use CGI ':standard';
4.  
5. my @busername = qw(
6.     manolo
7.     margarita
8.     fungencio
9. );
10.  
11. my @username =
12.     ( 'username rosa acceso 1'
13.     , 'username manolo acceso 2'
14.     , 'username manolo acceso 3'
15.     , 'username garcia acceso 1'
16.     , 'username margarita acceso 2'
17.     , 'username antonio acceso 3'
18.     );
19.  
20. my %usuarios_con_accesos;
21. for my $acceso (@username) {
22.     if ($acceso =~ /^username\s(.+?)\s/) {
23.         $usuarios_con_accesos{$1} = 1;          # recordamos los usuarios que han accedido
24.     }
25. }
26.  
27. my %usuarios_del_sistema;
28. for my $usuario (@busername) {
29.     $usuarios_del_sistema{$usuario} = 1;        # recordamos los usuarios del sistema
30. }
31.  
32. ## Vemos qué usuarios han accedido no están en el sistema
33. # Para cada $usuario_accedido, de todos los %usuarios_con_accesos
34. for my $usuario_accedido (keys %usuarios_con_accesos) {
35.     # Si el $usuario_accedido no existe en el grupo de %usuarios_del_sistema
36.     if (not exists $usuarios_del_sistema{$usuario_accedido}) {
37.         say Tr(td("Usuario= $usuario_accedido -&gt; MAL"));                           # informamos
38.     }
39. }
40.  
41. ## Vemos qué usuarios del sistema no han accedido
42. # Para cada $usuario_en_sistema, de todos los %usuarios_del_sistema
43. for my $usuario_en_sistema (keys %usuarios_del_sistema) {
44.     # Si el $usuario_en_sistema no existe en el grupo de %usuario_con_accesos
45.     if (not exists $usuarios_con_accesos{$usuario_en_sistema}) {
46.         say Tr(td("Usuario= $usuario_en_sistema -&gt; NO SE ENCUENTRA CONFIGURADO")); # informamos
47.     }
48. }

Coloreado en 0.002 segundos, usando GeSHi 1.0.8.4

El resultado es el mismo, claro. Pero más rápido, ya que no hay búsquedas recorriendo listas de valores. Simplemente se compruebe la existencia o no de usuarios dentro de cada grupo.

Aparte... ¿qué ocurre si un usuario accede más de una vez...? Pues que con la solución de los array no nos daremos cuenta y lo reportaremos tantas veces como aparezca en la lista. Con los hash solo es "recordado" una vez, ya que las claves de los hash son únicas.