Foro - Perl en Español

por **explorer** » 2013-06-30 05:36 @275

Ahorraríamos mucho tiempo si publicaras un trozo del archivo que quieres procesar, aunque sea con datos falseados, como las IP.

Lo que en tu código es @bserver, en mi código se llama %usuarios_del_sistema. Lo que hice fue transformar un array en un hash, relacionando todos los nombres posibles de "manolo" con el usuario "manolo".

En tu caso, si siempre va a aparecer la palabra "conectividad", entonces el problema se puede reducir un poco más, pero no sé muy bien a qué te refieres con "otros parámetros". ¿Te refieres al '1.1.1.1' y al 'testing' que está en @bserver? Entonces no siempre aparece "conectividad"...

Lo dicho: necesitamos una copia real de tu trabajo. Un trozo significativo vale. Y los datos sensibles, los falseas.

#!/usr/bin/perl 
 
use v5.16;
 
use CGI ':standard';
 
my %usuarios_del_sistema = (
    'conectividad' => 'conectividad lan0|conectividad wlan1',
    '1.1.1.1'   => '1.1.1.1',
    'testing'   => 'testing',
    'otro'      => 'otro',
);
 
my $usuarios_del_sistema       = join '|', values %usuarios_del_sistema;
my $regex_usuarios_del_sistema = qr/$usuarios_del_sistema/;
 
my @accesos =
    ( 'server 1.1.1.1'
    , 'server conectividad wlan1'
    , 'server testing'
    , 'server zanuto'
    );
 
my %usuarios_con_accesos;
 
for my $acceso (@accesos) {
 
    if ($acceso =~ /^server\s(.+)/) {                   # si tenemos un acceso
 
        $usuarios_con_accesos{$1} = 1;                  # recordamos el usuario que ha accedido
    }
}
 
my $usuarios_con_accesos       = join '|', keys %usuarios_con_accesos;
my $regex_usuarios_con_accesos = qr/$usuarios_con_accesos/;
 
 
## Vemos qué usuarios que han accedido no están en el sistema
for my $usuario_accedido (keys %usuarios_con_accesos) {
 
    if ($usuario_accedido !~ /$regex_usuarios_del_sistema/) {   # si el usuario que ha entrado no está registrado en el sistema
 
        say Tr(td("Usuario= $usuario_accedido -&gt; MAL"));     # informamos de una entrada ilegal
    }
}
 
## Vemos qué usuarios del sistema no han accedido
while ( my ($usuario_del_sistema, $regex_usuario_del_sistema) = each %usuarios_del_sistema) {
 
    my $ha_entrado;
 
    for my  $usuario_del_sistema_unico ( split '\|', $regex_usuario_del_sistema) {
 
        if ($usuario_del_sistema_unico =~ $regex_usuarios_con_accesos) {
            $ha_entrado = 'sí';
            last;
        }
    }
 
    if (not $ha_entrado) {
        say Tr(td("Usuario= $usuario_del_sistema -&gt; NO SE ENCUENTRA CONFIGURADO"));
    }
}
 
__END__
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

La salida es:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

<tr><td>Usuario= zanuto -&gt; MAL</td></tr>

<tr><td>Usuario= otro -&gt; NO SE ENCUENTRA CONFIGURADO</td></tr>Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Solo he modificado las líneas con las entradas a procesar, y la expresión regular.

De todas maneras, si lo que nos interesa es solo la presencia de la palabra "conectividad", se puede simplificar un poco, sin tener que usar el truco de los '|' en la primera entrada del primer hash, cambiando la complejidad de la exp. reg., para que deseche lo que sigue a "conectividad".

por **situ** » 2013-06-30 22:50 @993

Muchas gracias, voy a probar.

por **situ** » 2013-07-01 15:20 @680

Perdón, pero ahora estoy teniendo otra problemática con el script, lo anterior funcionó perfecto.

Obtengo los datos del archivo server.txt. Perdón, pero no sé cómo hacer el "grep" en Perl. Lo intenté y como no lo logré, lo dejé.

Aquí me quedo con las 20 líneas luego de identificar "linea con1":

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

@lineacon1=`grep -e \"^linea con1\" -A20 \"server.txt\"`;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

En @lineacon1 tengo algo como esto:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

linea con1

system reset

canales 2

acceso denegado

linea con2Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Como se puede apreciar, dentro de estas líneas tengo "linea con2", esto me muestra que en ya salí de "linea con1" y estoy entrando en otra configuración, y no debería hacerlo. Para esto, usé la siguiente regex:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

foreach $lineacon1(@lineacon1) {
        ## Paso al siguiente foreach cuando encuentro el nombre de la siguiente línea o si comienza con un !
        if ($lineacon1 =~ m/^linea\scon1|^!/) {
                last;
        }
                
        else {
           print F "$lineacon1\n";
        }
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Ahora mi problema se presenta en que debo hacer lo mismo que hicimos para "ntp": debo hacer comprobaciones y mostrar si algo está mal o si falta algún parámetro.

Digamos:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

@blineacon0=("system reset","canales 2","acceso denegado")
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

La verdad que traté de adaptar lo anterior pero ahora al tener la regex para ver cuando salto a "linea con2" me complicó todo.

Saludos.

por **explorer** » 2013-07-02 05:14 @259

Está pasando lo de siempre: no nos contáis el problema entero, por lo que las soluciones que damos solventan pequeños problemas, pero no el problema principal. Y así no terminamos nunca. :cry:

El grep() en Perl existe como sentencia. Más información en perldoc -f grep.

Lo que puedes intentar es dividir el contenido de las líneas de server.txt de forma precisa antes de entrar en los bucles, y así no tienes que poner excepciones.

por **situ** » 2013-07-02 08:51 @410

Hola, el script que ingresé es el original que tengo. Pasa que muchas veces me surgen estas problemáticas a medida que necesito hacer nuevas funcionalidades.

El tema de dividir no entendí muy bien a qué te referís.

El grep lo uso porque necesito las líneas que le siguen a "linea con1" pero el contenido que necesito debe ser hasta "linea con2", por eso la regex :S y como no sé cómo seguir con las comprobaciones mandé el mensaje.

Saludos.

por **explorer** » 2013-07-02 13:54 @621

Con dividir, me refiero a que partas el array con las líneas a procesar, en varios array, según lo que tengas que procesar.

Algo así como hacer la exp. reg. en un bucle anterior. De esa manera, en los bucles principales te ahorras poner excepciones, porque han quedado fuera.

Para procesar líneas de un archivo entre dos condiciones, lo más cómodo es usar el operador flip-flop:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

while(<leemos línea del archivo>){

if(/linea con1/../linea con2/){
# aquí procesamos líneas para con1
}
if(/linea con2/../linea con3/){
# lo mismo, para con2
}
if(/linea con3/..eof){
# aquí procesamos desde con3 hasta el fin de archivo
}
}Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Ahora bien... no nos dices cuántos conX hay... ¿lo sabemos? Si no, pues habrá que usar una exp. reg.

Yo haría entonces algo así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my %cons;  # aquí guardamos las líneas, indexadas por el nombre del conX.
my $con_actual = "ninguno";
 
while (<$archivo>) {
    if (/^linea (con\w+)/) {    # en caso de ser una línea con conX, capturamos su nombre
        $con_actual = $1;       # la recordamos
        next;                   # leemos la siguiente línea
    }
    push @{$cons{$con_actual}}, $_;   # si es una línea normal, la almacenamos en un array indexado por el nombre de la conX.
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

y al final tenemos un hash cuyas claves son los nombres de las conX, y los valores son referencias a array, que guarda una línea por cada línea del archivo dentro de la sección conX.

Y ya puedo procesar %cons, sabiendo que tengo todas las zonas separadas.

Foro - Perl en Español

Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Publicidad

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

Re: Búsqueda de parámetros en un archivo

¿Quién está conectado?