Foro - Perl en Español

por **lis** » 2013-07-23 11:12 @508

Hola, amigos del foro.

Tengo un archivo que que tiene 5 columnas, la primera corresponde a fecha y hora juntos -AAAAMMDDHH- (por ejemplo, 2012010100) pero falta un día (es el año 2012 completo) e hice un script para que buscara esa fecha, y es obvio que estoy haciendo algo mal porque el resultado muestra una fecha, pero al revisar el archivo esa fecha sí está.

Agradezco mucho si me ayudan. Adjunto mi script:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
 
open(DATA,"<WRF_HUARA.txt"); 
 
%hash = qw (01 31 02 29 03 31 04 30 05 31 06 30 07 31 08 31 09 30 10 31 11 30 12 31);
foreach my $mes (sort keys %hash){
foreach my $dia ( '01' .. "$hash{$mes}" ) {
foreach my $hora ('00' .. '23'){
 
$fecha='2012' . $mes . $dia . $hora;
 
while($lineas=<DATA>){
chop($lineas); 
@datos= split(" ",$lineas); 
 
if ($datos[0] =~ m/$fecha/){
 
print "$fecha se encuentra en $datos[0]\n";
}else{
print"$fecha no se encuentra en $datos[0]\n";
}
 
}}}}
 
close(DATA);
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

2012010100      19      66      4.48     277.95 

2012010101      19      68      3.74     298.48

2012010102      19      68      3.08     275.45

2012010103      18      68      4.02     290.57

2012010104      18      70      2.73     285.49

2012010105      17      87      0.15     153.46

2012010106      17      89      1.28     238.21

2012010107      17      92      1.24     279.74

2012010108      16      89      1.32     269.44

2012010109      16      83      1.63     286.37

2012010110      17      79      3.45     284.84

2012010111      19      72      3.69     285.70

2012010112      21      63      4.82     292.99

2012010113      23      56      4.34     298.23

2012010114      24      53      3.69     306.36

2012010115      25      49      3.85     304.29

2012010116      26      49      5.03     295.78

2012010117      27      49      5.62     295.08

2012010118      27      50      6.59     292.61

2012010119      26      51      7.08     287.49

2012010120      26      53      6.65     284.43

2012010121      25      55      6.28     284.18

2012010122      23      59      5.66     288.06

2012010123      22      62      5.10     299.44

2012010200      21      65      5.83     314.83

2012010201      20      69      4.73     319.92

.               .        .       .        .

.               .        .       .        .

.               .        .       .        .

2012123123      21      58      4.36     305.15
Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2013-07-23 11:35 @524

Hay dos problemas:

la comparación la haces con una expresión regular, pero es mejor que lo hagas con un operador de comparación de cadenas de caracteres: 'eq'
el problema gordo está en el algoritmo. Tienes un triple bucle for() para recorrer todas las fechas. Por cada una de ellas, tu intención es leer las fechas del archivo, y buscar la coincidencia. El problema, bueno, varios problemas, son:
- imprimes un mensaje de está o no está por cada fecha existente en el archivo. Eso quiere decir que, en la primera fecha, 2012010100, saldrá un mensaje de que sí está (está en la primera línea del archivo), seguido de 366*24 mensajes de que "no está", porque, efectivamente, el resto de fechas del archivo ya no coincide con la primera
- una vez terminado de leer el archivo, el triple bucle sigue, pero... ¡el archivo ya se agotó de leer! Deberías abrir y cerrar el archivo dentro del triple bucle. O mejor aún: hacer un seek() para colocar el puntero de lectura al principio.

Lo malo... es que la ejecución del programa se va a hacer eterno... (366x24)^2 = 77 158 656 vueltas.

Se inicia un concurso... a ver quién da con la solución más rápida...

por **explorer** » 2013-07-23 12:56 @580

Más preguntas.

¿Esa fecha/hora, a qué zona horaria se refiere? ¿Es hora local o GMT? Quiero decir que no me importa la zona horaria, sino si es hora local, ya que sabemos que hay dos momentos a lo largo del año (al menos aquí en España), donde la hora local cambia (pasa de horario de verano a invierno, y viceversa).

Si es hora local, entonces, en el archivo, puede aparecer líneas con fechas duplicadas (retrasar una hora) o con una línea de menos (adelantar una hora).

Si es GMT, entonces consideramos que todos los días tienen 24 horas. Y que puede haber un día bisiesto en febrero.

por **lis** » 2013-07-23 13:52 @619

Está en GMT.

por **explorer** » 2013-07-23 17:48 @783

Esta es mi solución.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl 
use v5.16;
use autodie;                    # «Es mejor morir que regresar con deshonor» --proverbio Klingon
use utf8::all;                  # Turn on UTF-8. All of it.
 
## Configuración
my $año = 2012;
## Fin de configuración
 
## Constantes
my %meses_días = (
    '01' => '31',
    '02' => '28',
    '03' => '31',
    '04' => '30',
    '05' => '31',
    '06' => '30',
    '07' => '31',
    '08' => '31',
    '09' => '30',
    '10' => '31',
    '11' => '30',
    '12' => '31',
);
if ($año % 4 == 0 and ($año % 100 != 0  or  $año % 400 == 0)) {
    $meses_días{'02'} = '29';                                  # Este año es bisiesto
}
 
 
## Variables
my %fechas_en_archivo;
 
## Leemos el archivo y nos quedamos solo con las fechas
open my $WRF, 'WRF_HUARA.txt';
while (<$WRF>) {
    $fechas_en_archivo{ (split " ")[0] }++;
}
close   $WRF;
 
## Recorremos todo el año
for my $mes  ('01' .. '12'             ) {
for my $día  ('01' .. $meses_días{$mes}) {
for my $hora ('00' .. '23'             ) {
 
    my $fecha = "$año$mes$día$hora";
 
    if (exists $fechas_en_archivo{ $fecha }) {
        delete $fechas_en_archivo{ $fecha };                    # Vamos borrando las fechas que vamos encontrando
    }
    else {                                                      # Hemos encontrado una fecha que no está en el archivo
        say "Fecha $fecha no aparece en el archivo";
    }
}}}
 
## Recorremos las fechas que aparecen demás en el archivo
for my $fecha (sort keys %fechas_en_archivo) {
    say "Fecha $fecha aparece demás en el archivo";
}
 
__END__
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Bueno, yo he usado "features" de las nuevas versiones de Perl, pero debería serte fácil adaptar esta solución a tu problema.

Básicamente, consiste en leer primero todas las fechas del archivo, y luego, en el triple bucle, irlas borrando del hash. Si una fecha no estaba en el hash del archivo, tenemos una fecha que no aparece en el archivo. Y al final, un bucle más para identificar las fechas que sobran en el archivo (no corresponden con ninguna fecha normal esperada para ese año).

por **lis** » 2013-07-24 13:44 @614

Hola, explorer, tuve que instalar varios módulos y actualizar otros pero funcionó excelente. Muchísimas gracias una vez más.

por **otronovato** » 2013-08-28 06:13 @301

He hecho un código que, a falta de un archivo de datos, no sé si funcionaría.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
 
use strict;
use warnings;
 
my @fechas;
 
#Como hay un registro por hora por cada día, sabemos que tendremos
#para enero 31 días * 24 horas = 744 registros
#para febrero de 2012 29 días * 24 horas = 696 registros
#para abril 30 días * 24 horas = 720 registros...
 
my %registros = (
    "01" => 744,
    "02" => 696,
    "03" => 744,
    "04" => 720,
    "05" => 744,
    "06" => 720,
    "07" => 744,
    "08" => 744,
    "09" => 720,
    "10" => 744,
    "11" => 720,
    "12" => 744
);
 
my $contador;
my @regpormes;
my $incompleto;
my @dias;
 
open( FH, "<", $ARGV[0] ) || die "No puedo abrir $ARGV[0]";
 
while (<FH>) {
    chomp $_;
    my @registro = split /\s+/, $_;
    push @fechas, $registro[0];
}
 
close FH;
 
#Compruebo que me he quedado con los datos que quiero
 
foreach (@fechas) {
    print $_, "\n\n\n\n";
}
 
#Primero localizamos el mes que está incompleto
 
foreach (@fechas) {
 
    $contador = 0;
    foreach ( sort keys %registros ) {
        if ( ~/\d\d\d\d$_.*/ ) {
            $contador++;
        }
 
        if ( $registros{$_} > $contador ) {
            $incompleto = $_;
        }
    }
}
print "mes $incompleto\n";
 
#Luego encontramos el día que falta. Supondré que sólo hay uno
foreach (@fechas) {
 
    if ( ~/\d\d\d\d$incompleto(\d\d).*/ ) {
        push @dias, $1;
    }
 
}
 
#quitamos todos los elementos repetidos mediante un hash
 
my %unicos = map { $_, 1 } @dias;
 
my @lista = sort keys %unicos;
 
print @lista, "\n\n";
 
#En la lista podríamos ver fácilmente el día que falta
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

He supuesto que no tenemos problemas de cambios horarios y demás peculiaridades. De las expresiones regulares no estoy nada seguro, pues hace años que no las tocaba. ¿Podría haber extraído los campos mediante unpack()?... ¿Qué os parece? ¿Podría funcionar?

Me gustaría que me explicaseis esta línea de código de la solución de explorer:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$fechas_en_archivo{ (split " ")[0] }++;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Entiendo lo que hace, pero sólo porque imagino lo que debe hacer :shock:

por **explorer** » 2013-08-28 08:00 @375

No he comprobado el programa pero, de funcionar, irá bastante más lento que mi solución: solo el hecho de no usar hash, y en su lugar usar bucles, para hacer las búsquedas, hará que el procesamiento se alargue muchísimo.

Precisamente, los hash son muy indicados para estos casos, en los que tenemos que saber si cierta información existe o ya ha salido antes.

La línea

$fechas_en_archivo{ (split " ")[0] }++;

hace lo siguiente:

split() parte la línea por los espacios en blanco. Devuelve una lista de elementos (los distintos campos encontrados)
de esa lista (que está rodeada por los paréntesis), nos quedamos sólo con el primer elemento ([0])
ese elemento se convierte en una clave dentro del hash %fechas_en_archivo, y como valor, el que teníamos antes, más uno

Es decir, vamos contando las veces que va apareciendo el valor que está en la primera columna. En la mayor parte de los casos (o todos), ese valor será un '1', pero eso no nos importa. Lo que nos importa es que hemos creado una clave con el valor de la primera columna. Eso nos servirá luego para saber si tal fecha la hemos leído antes o no (con un simple if(), no con un bucle).

Foro - Perl en Español

Buscar dato en archivo

Buscar dato en archivo

Publicidad

Re: Buscar dato en archivo

Re: Buscar dato en archivo

Re: Buscar dato en archivo

Re: Buscar dato en archivo

Re: Buscar dato en archivo

Re: Buscar dato en archivo

Re: Buscar dato en archivo

Re: Buscar dato en archivo

Re: Buscar dato en archivo

¿Quién está conectado?