Foro - Perl en Español

por **pablgonz** » 2014-02-04 13:14 @593

En pantalla no me arroja nada, pero, en el fichero que genera no se llevan a cabo los cambios, elimina las frases que debería convertir... por eso tengo dudas con given/when... ya que al modificar por if/else, conservando el resto del código, funciona.

Instalé el módulo y agregué la línea que me indicas y no funcionó. Estoy utilizando Perl v5.18.2 (Strawberry portable 32 bits). Sigue siendo un absoluto misterio (para mi) el por qué no funciona, creo que el problema podría estar en el substr, que es donde se deberían hacer los cambios o es algo en el funcionamiento interno de SmartMatch o es alguno de los casos de excepción comentados en http://search.cpan.org/~rjbs/perl-5.18.2/pod/perlsyn.pod#Experimental_Details_on_given_and_when.
Saludos,
Pablo

P.D.: La verdad es que este misterio me tiene bastante ocupado, modificando a if/else resolví el problema, pero, es interesante (e intrigante) saber por qué dejo de funcionar el script.

por **explorer** » 2014-02-04 20:52 @911

Yo necesitaría ver el código original junto con un archivo de prueba, y el archivo resultado. Si puedes meterlos en un zip y adjuntarlos en el siguiente mensaje, podemos ver qué pasa.

por **pablgonz** » 2014-02-04 21:11 @924

Ok, te adjunto un fichero comprimido con los archivos y el script.

P.D.: El script y los archivos son de otro tema que quedo unido a este hilo (en la hoja 2).

Gracias nuevamente.

por **explorer** » 2014-02-05 17:14 @760

Ya lo encontré. Es algo muy extraño, pero no que no funcione en Perl v5.18.2, sino que sí funcione en versiones anteriores

Este es el nuevo código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use v5.18.2;
no warnings;
use autodie;
 
@ARGV == 1 or die "Uso: $0 <archivo LaTeX a procesar\n";
 
my $nombre_archivo_entrada = shift;
 
-f $nombre_archivo_entrada or die "ERROR: No encuentro $nombre_archivo_entrada\n";
 
 
## Lectura del archivo
open my $ENTRADA, '<', $nombre_archivo_entrada;
undef $/;                                                                       # modo 'slurp'
my $archivo_entrada = <$ENTRADA>;
close   $ENTRADA;
 
 
## Partición del documento
my($cabeza,$cuerpo,$final) = $archivo_entrada =~ m/\A (.+? ^\\begin{document}) \s* (.+?) \s* (^ \\end{document}) \s* \z/msx;
 
 
## Cambios a realizar
my %cambios = (
        '\pspicture'            => '\TRICKS',
        '\endpspicture'         => '\ENDTRICKS',
 
        '\begin{pspicture'      => '\begin{TRICKS',
        '\end{pspicture'        => '\end{TRICKS',
 
        '\postscript'           => '\POSTRICKS',
 
        '\begin{postscript}'    => '\begin{POSTRICKS}',
        '\end{postscript}'      => '\end{POSTRICKS}',
);
 
 
## Variables y constantes
my $no_del = "\0";
my $del    = $no_del;
 
## Reglas
my $llaves      = qr/\{ .+? \}                                                                  /x;
my $no_corchete = qr/(?:\[ .+? \])?                                                             /x;
my $delimitador = qr/\{ (?<del>.+?) \}                                                          /x;
my $verb        = qr/verb [*]?                                                                  /ix;
my $lst         = qr/lstinline (?!\*) $no_corchete                                              /ix;
my $mint        = qr/mint      (?!\*) $no_corchete $llaves                                      /ix;
my $marca       = qr/\\ (?:$verb | $lst | $mint) (\S) .+? \g{-1}                                /x;
my $comentario  = qr/^ \s* \%+ .+? $                                                            /mx;
my $definedel   = qr/\\ (?:   DefineShortVerb | lstMakeShortInline  ) $no_corchete $delimitador /ix;
my $indefinedel = qr/\\ (?: UndefineShortVerb | lstDeleteShortInline) $llaves                   /ix;
 
 
## Cambiar
while ($cuerpo =~
    /   $marca
    |   $comentario
    |   $definedel
    |   $indefinedel
    |   $del .+? $del
    /pgmx) {
 
    my($pos_inicial, $pos_final) = ($-[0], $+[0]);                              # posiciones
    my $encontrado = ${^MATCH};                                                 # lo encontrado
 
    given ($encontrado) {
        when (/$definedel/) {                                                   # definimos delimitador
            $del = $+{del};
            $del = "\Q$+{del}" if substr($del,0,1) ne '\\';                     # es necesario "escapar" el delimitador
        }
        when (/$indefinedel/) {                                                 # indefinimos delimitador
            $del = $no_del;
        }
        default {                                                               # Aquí se hacen los cambios
            while (my($busco, $cambio) = each %cambios) {
                $encontrado =~ s/\Q$busco\E/$cambio/g;                          # es necesario escapar $busco, ya que contiene caracteres extraños
            }
 
            substr $cuerpo, $pos_inicial, $pos_final-$pos_inicial, $encontrado; # insertamos los nuevos cambios
 
            pos($cuerpo) = $pos_inicial + length $encontrado;                   # reposicionamos la siguiente búsqueda
        }
    }
}
 
 
## Escritura del resultado
open my $SALIDA, '>', "test-out2.tex";
print   $SALIDA "$cabeza\n$cuerpo\n$final\n";
close   $SALIDA;
 
__END__
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Los cambios son mínimos, pero claro, hay que saber cuáles hay que poner

en la línea 2 ponemos un 'use' para indicar que este código funciona con la última versión estable de Perl (si la tenemos instalada, claro)
en la línea 3 desactivamos los 'warnings', y así dejamos de ver los avisos de 'característica experimental' del given/when
como estamos usando un Perl >= v5.14, ya no hace falta la línea 'use strict;', así que la quitamos
y... la línea problemática... es la 63. Ahí faltaba por poner la opción '/p'. Sin ella, no se actualiza la variable '${^MATCH}' de la línea 66

Y esto es lo curioso: con una versión anterior de Perl, sí que funciona el programa sin la opción '/p' (preservar). Pero la documentación en perlvar dice que sí hay que ponerlo.

Otra opción sería quitar la opción '/p' y cambiar entonces '${^MATCH}' por '$&', pero la velocidad del programa disminuye.

Misterio resuelto: hay que programar según cómo lo diga la documentación

por **pablgonz** » 2014-02-05 18:42 @821

Genial, había ocupado "/p" en el resto de las expresiones y me percaté de que funcionaba a medias... nunca intenté en la línea que usaste, es más, no sabía si usarlo o no, no lo veo muy seguro en expresiones regulares... en fin... misterio resuelto y mis disculpas a given/when.
Saludos.

por **pablgonz** » 2014-03-16 14:24 @641

Hice unos pequeños cambios en el script y lo dejé así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use v5.14;
use autodie;                                            # muere si ocurre un error
use File::Basename;                                     # separa el archivo de entrada
 
### Argumentos --------------------------------------------------------------
@ARGV == 1  or die "Uso: $0 <archivo TeX a procesar>\n";
my $nombre_archivo = shift;
-f $nombre_archivo or die "ERROR: No encuentro [$nombre_archivo]\n";
 
### Arreglo de la extensión -------------------------------------------------
my @SuffixList = ('.tex', '', '.ltx');                  # posible extensión
my ($name, $path, $ext) = fileparse($nombre_archivo, @SuffixList);
$ext = '.tex' if not $ext;                              # fijamos la extensión
 
### Abrimos el archivo de entrada a modificar -------------------------------
open my $ENTRADA, '<', $nombre_archivo;
my $archivo;
{
    local $/;
    $archivo = <$ENTRADA>;
}
close   $ENTRADA;
 
## Partición del documento
my($cabeza,$cuerpo,$final) = $archivo =~ m/\A (.+? ^\\begin{document}) (.+) (^ \\end{document} .*) \z/msx;
 
## Cambios a realizar
my %cambios = (
        '\pspicture'                => '\TRICKS',
        '\endpspicture'             => '\ENDTRICKS',
 
        '\begin{MYexample'          => '\begin{MYEXAMPLE',
        '\end{MYexample'            => '\end{MYEXAMPLE',
        
        '\begin{pspicture'          => '\begin{TRICKS',
        '\end{pspicture'            => '\end{TRICKS',
        
        '\begin{postscript}'        => '\begin{POSTRICKS}',
        '\end{postscript}'          => '\end{POSTRICKS}',
);
 
 
## Variables y constantes
my $no_del = "\0";
my $del    = $no_del;
 
## Reglas
my $llaves      = qr/\{ .+? \}                                                                  /x;
my $no_corchete = qr/(?:\[ .+? \])?                                                             /x;
my $delimitador = qr/\{ (?<del>.+?) \}                                                          /x;
my $verb        = qr/verb [*]?                                                                  /ix;
my $lst         = qr/lstinline (?!\*) $no_corchete                                              /ix;
my $mint        = qr/mint      (?!\*) $no_corchete $llaves                                      /ix;
my $marca       = qr/\\ (?:$verb | $lst | $mint) (\S) .+? \g{-1}                                /x;
my $comentario  = qr/^ \s* \%+ .+? $                                                            /mx;
my $definedel   = qr/\\ (?:   DefineShortVerb | lstMakeShortInline  ) $no_corchete $delimitador /ix;
my $indefinedel = qr/\\ (?: UndefineShortVerb | lstDeleteShortInline) $llaves                   /ix;
 
## Cambiar
while ($cuerpo =~
        /   $marca
        |   $comentario
        |   $definedel
        |   $indefinedel
        |   $del .+? $del                                                       # delimitado
        /pgmx) {
 
        my($pos_inicial, $pos_final) = ($-[0], $+[0]);                          # posiciones
        my $encontrado = ${^MATCH};                                             # lo encontrado
 
    if ($encontrado =~ /$definedel/){                                           # definimos delimitador
                        $del = $+{del};
                        $del = "\Q$+{del}" if substr($del,0,1) ne '\\';         # es necesario "escapar" el delimitador
                }
    elsif($encontrado =~ /$indefinedel/) {                                      # indefinimos delimitador
                 $del = $no_del;                                        
        }
    else {                                                                      # aquí se hacen los cambios
        while (my($busco, $cambio) = each %cambios) {
                       $encontrado =~ s/\Q$busco\E/$cambio/g;                   # es necesario escapar $busco
                        }
        substr $cuerpo, $pos_inicial, $pos_final-$pos_inicial, $encontrado;     # insertamos los nuevos cambios
 
        pos($cuerpo)= $pos_inicial + length $encontrado;                        # re posicionamos la siguiente búsqueda
        }
}
 
## Escritura del resultado
open my $SALIDA, '>', "$name-out$ext";
print   $SALIDA "$cabeza$cuerpo$final";
close   $SALIDA;
 
__END__
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

y me gustaría añadir una nueva regla para que modifique las palabras que se encuentren entre otras dos, por ejemplo, si la entrada es de esta forma:

Sintáxis: [ Descargar ] [ Ocultar ]

Using latex Syntax Highlighting

\documentclass{article}
\usepackage{minted}
\usepackage{pstricks-add}
\newenvironment{postscript}{}{}
\begin{document}
 
Usamos \verb|\begin{pspicture} o \begin{pspicture*}| o \verb*|\begin{pspicture} o \begin{pspicture*}| (cambia)
esta línea debería quedar intacta \begin{pspicture} o \begin{pspicture*}
% esta línea debería modificarse \begin{pspicture} o \begin{pspicture*}
 
%\begin{postscript} debería cambiar
\begin{verbatim} 
\psset{unit=1.0cm}
\begin{pspicture}[showgrid=true](4,2)
  \psscaleboxto(8,2){foo bar baz}
\end{pspicture}
\end{verbatim}
 TEXTO
\begin{LTXexample}[algo=1,
                                        algo=2] 
\begin{pspicture*}(4,2)(8,1)
\psset{unit=1.0cm}
\psscaleboxto(8,2){foo bar baz}
\end{pspicture*}
\end{LTXexample}
TEXTO
\begin{tcblisting}{colback=red!5!white,colframe=red!25,left=6mm,
listing options={style=tcblatex,numbers=left,numberstyle=\tiny\color{red!75!black}}}
\begin{postscript}[showgrid=true](4,2)
  \psscaleboxto(8,2){foo bar baz}
\end{postscript}
\end{tcblisting}
TEXTO
\begin{mybox}[listing side text]
{Listing Box}
\psset{unit=1.0cm}
\begin{pspicture}[showgrid=true](4,2)
  \psscaleboxto(8,2){foo bar baz}
\end{pspicture}
\end{mybox}
\end{document}
 
%\endpspicture o \end{pspicture} no debería cambiar
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

la salida sea de esta forma:

Sintáxis: [ Descargar ] [ Ocultar ]

Using latex Syntax Highlighting

\documentclass{article}
\usepackage{minted}
\usepackage{pstricks-add}
\newenvironment{postscript}{}{}
\begin{document}
 
Usamos \verb|\begin{TRICKS} o \begin{TRICKS*}| o \verb*|\begin{TRICKS} o \begin{TRICKS*}| (cambia)
esta línea debería quedar intacta \begin{pspicture} o \begin{pspicture*}
% esta línea debería modificarse \begin{TRICKS} o \begin{TRICKS*}
 
%\begin{POSTRICKS} debería cambiar
\begin{verbatim} 
\psset{unit=1.0cm}
\begin{TRICKS}[showgrid=true](4,2)
  \psscaleboxto(8,2){foo bar baz}
\end{TRICKS}
\end{verbatim}
 TEXTO
\begin{LTXexample}[algo=1,
                                        algo=2] 
\begin{TRICKS*}(4,2)(8,1)
\psset{unit=1.0cm}
\psscaleboxto(8,2){foo bar baz}
\end{TRICKS*}
\end{LTXexample}
TEXTO
\begin{tcblisting}{colback=red!5!white,colframe=red!25,left=6mm,
listing options={style=tcblatex,numbers=left,numberstyle=\tiny\color{red!75!black}}}
\begin{POSTRICKS}[showgrid=true](4,2)
  \psscaleboxto(8,2){foo bar baz}
\end{POSTRICKS}
\end{tcblisting}
TEXTO
\begin{mybox}[listing side text]
{Listing Box}
\psset{unit=1.0cm}
\begin{TRICKS}[showgrid=true](4,2)
  \psscaleboxto(8,2){foo bar baz}
\end{TRICKS}
\end{mybox}
 
\end{document}
 
%\endpspicture o \end{pspicture} no debería cambiar
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

es decir, que modifique las palabras si se encuentran entre las líneas que digan \begin{verbatim}, \begin{LTXexample}, \begin{tcblisting}, \begin{mybox} y \end{verbatim}, \end{LTXexample}, \end{tcblisting}, \end{mybox}. ¿Se puede modificar el script para lograr esto? o ¿debo crear otro que haga esta función?

Saludos,
Pablo

por **explorer** » 2014-03-22 18:46 @823

En principio, habría que hacer una prueba ampliando el hash %cambios, pero sabiendo que esos cambios no tienen en cuenta la paridad de las marcas (si van parejas o no) o si están incluidas unas dentro de otras.

Si necesitas una comprobación más fuerte, lo mejor es hacer un programa nuevo.

por **pablgonz** » 2014-03-22 20:28 @894

Gracias por la respuesta, explorer, la verdad he analizado bastante lo que deseo hacer y ya tengo claras las condiciones de mi problema. La descripción es más menos así:

Usar el mismo hash ya definido (siempre son las mismas palabras las que deseo cambiar)
La paridad de las palabras entre las que deseo cambiar es necesaria y nunca van anidadas entre sí (incluidas unas dentro de otras), es decir, son siempre de la forma:
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using latex Syntax Highlighting
1. \begin{LTXexample}[aveces está presente con y sin saltos de línea]{a veces está presente con y sin saltos de línea} \s (obligatorio)
2. Texto y palabras que deseo cambiar usando el hash.
3. \end{LTXexample}
Coloreado en 0.000 segundos, usando GeSHi 1.0.8.4
Crear una lista con las palabras que delimitan lo que deseo cambiar:
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using perl Syntax Highlighting
1. my $ENTORNO = qr/(v|V)erbatim | (v|V)erbatim| LTXexample | tcblisting | mybox | otras/x;
Coloreado en 0.001 segundos, usando GeSHi 1.0.8.4
Como ya tengo cargado el archivo en memoria, uso una expresión regular en $cuerpo y hago los cambios que deseo, algo como:
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using perl Syntax Highlighting
1. $cuerpo =~s/\A (.+? ^\\begin{$ENTORNO}?:\[ .+? \]?:\{ .+? \}\s) (lo que deseo cambiar usando el hash)(\\end{$ENTORNO})\z/$1$2$3/msxg;
Coloreado en 0.001 segundos, usando GeSHi 1.0.8.4

En mi lógica es factible, ya tengo el archivo cargado y dividido en memoria pero no logro armar la idea dentro del bucle. Espero haberme explicado.

Agradecido,
Pablo

Foro - Perl en Español

Acotar expresión regular

Re: Acotar expresión regular

Publicidad

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

¿Quién está conectado?