Foro - Perl en Español

por **explorer** » 2014-04-01 13:01 @584

Siempre se puede poner un

next if /^%+/;

para que salte esa línea.

#!/usr/bin/perl
use v5.14.2;
use re 'eval';
use autodie;                                            # muere si ocurre un error
use File::Basename;                                     # separa el archivo de entrada
 
### Argumentos --------------------------------------------------------------
@ARGV == 1  or die "Uso: $0 <archivo TeX a procesar>\n";
my $nombre_archivo = shift;
-f $nombre_archivo or die "ERROR: No encuentro [$nombre_archivo]\n";
 
### Arreglo de la extensión -------------------------------------------------
my @SuffixList = ('.tex', '', '.ltx');                  # posible extensión
my ($name, $path, $ext) = fileparse($nombre_archivo, @SuffixList);
$ext = '.tex' if not $ext; 
 
### Parte 1: Comentamos bloques de texto a lo largo de todo el archivo -------
 
my @lineas;
{
    open my $FILE, $nombre_archivo;
    @lineas = <$FILE>;
    close $FILE;
}
 
my %cambios = (
    '\pspicture'                => '\TRICKS',
    '\endpspicture'             => '\ENDTRICKS',
 
    '\begin{MYexample'          => '\begin{MYEXAMPLE',
    '\end{MYexample'            => '\end{MYEXAMPLE',
 
    '\begin{pspicture'          => '\begin{TRICKS',
    '\end{pspicture'            => '\end{TRICKS',
 
    '\begin{postscript}'        => '\begin{POSTRICKS}',
    '\end{postscript}'          => '\end{POSTRICKS}',
    
    '\begin{document}'          => '\begin{DOCUMENT}',
    '\end{document}'            => '\end{DOCUMENT}',
);
 
my $ENTORNO  = qr/(?: verbatim\*? | LTXexample | tcblisting | mybox | comment )/xi;
#    
my $DEL;
 
for (@lineas) {
    if (/^\\begin\{($ENTORNO)(?{ $DEL = $^N })\}/ .. /^\\end\{$DEL\}/) {
        while (my($busco, $cambio) = each %cambios) {
            s/\Q$busco\E/$cambio/g;
        }
    }
  print;  
 }
 
## Escritura del resultado
open my $SALIDA, '>', "$name-out$ext";
print   $SALIDA @lineas;
close   $SALIDA;
Coloreado en 0.007 segundos,  usando GeSHi 1.0.8.4

pero, modifica una línea que no debería, en este caso, el último \end{document}. Si el archivo de entrada es de esta forma:

Sintáxis: [ Descargar ] [ Ocultar ]

Using latex Syntax Highlighting

\documentclass{article}
\begin{comment}
\begin{document} cambia
\end{document} cambia
\end{comment}
\begin{document} esta línea no debería cambiar
Test
\begin{comment}
\begin{document} cambia
\end{document} cambia
\end{comment}
Texto'
\begin{verbatim*} 
\psset{unit=1.0cm}
\begin{pspicture}[showgrid=true](4,2) cambia
  \psscaleboxto(8,2){foo bar baz}
\end{pspicture} cambia
\end{verbatim*} 
 
\end{document} esta línea no debería cambiar
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Cambia el último \end{document} por \end{DOCUMENT} siendo que este no está en el rango sobre el que deseo hacer modificaciones, creo que el problema está en el * que uso en verbatim\*? el cual ya está escapado.

Saludos,
Pablo.

por **explorer** » 2014-04-02 06:26 @310

Tienes razón.

El problema está en que $DEL va guardando los delimitadores que encontramos, y en el caso de 'verbatim*', lo que estamos indicando, en la segunda parte del biestable, es que busque por un delimitador '\end{verbatim*}'. Es decir, queremos que finalice el rango con una 'm' opcional seguida inmediatamente por la llave de cierre... y eso no se cumple en todo el resto del archivo. Por eso, desde que captura el primer 'verbatim*', hace los cambios a todas las líneas.

La solución es indicar que ese asterisco es literal, no un comodín de un patrón.

Cambia la línea 48 a:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

    if (/^\\begin\{($ENTORNO)(?{ $DEL = "\Q$^N" })\}/ .. /^\\end\{$DEL\}/) {
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

y así, en $DEL guardamos la versión "escapada" del delimitador, y la segunda parte del biestable sí que encuentra la fila del final del rango.

por **pablgonz** » 2014-04-02 22:07 @963

Ahora funciona perfecto, un par de consultas (para variar):

En la línea que me propones usas $DEL = "\Q$^N" no se debería colocar también \E.
Como el hash no es conmutativo y en otra parte del script necesitaré deshacer los cambios que hice en un principio, pero, ahora ya no tendré la limitación de buscarlos dentro de los rangos de palabras, sino modificar todas las apariciones de esas palabras en el $cuerpo del archivo, me gustaría hacerlos usando una expresión regular y un hash, algo como esto:
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using perl Syntax Highlighting
1. open my $ENTRADA, '<', "test.tex";
2. my $archivo;
3. {
4. local $/;
5. $archivo = <$ENTRADA>;
6. }
7. close $ENTRADA;
9. ## Partición del documento
10. my($cabeza,$cuerpo,$final) = $archivo =~ m/\A (.+? ^\\begin{document}) (.+) (^ \\end{document} .*) \z/msx;
12. my %cambios = (
13. '\TRICKS' => '\pspicture',
14. '\ENDTRICKS' => '\endpspicture',
15. '\begin{MYEXAMPLE' => '\begin{MYexample',
16. '\end{MYEXAMPLE' => '\end{MYexample',
17. '\begin{TRICKS' => '\begin{pspicture',
18. '\end{TRICKS' => '\end{pspicture',
19. '\begin{POSTRICKS}' => '\begin{postscript}',
20. '\end{POSTRICKS}' => '\end{postscript}' ,
21. '\begin{DOCUMENT}' => '\begin{document}' ,
22. '\end{DOCUMENT}' => '\end{document}' ,
23. );
25. $cuerpo=~ s/\Q$busco\E/$cambio/g;
Coloreado en 0.001 segundos, usando GeSHi 1.0.8.4
y aquí es donde me pierdo, no sé si puedo usar el mismo nombre para el hash, es decir, si reescribe las claves que ya usé antes o debo darle otro nombre y cómo hacerlo correr en la expresión regular.

Totalmente agradecido,
Pablo

por **pablgonz** » 2014-04-03 22:02 @960

Ya aclaré mi duda, el hash se sobreescribe y basta con usar un for para lo que deseo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

for ($cuerpo) {
        while (my($busco, $cambio) = each %cambios) {
            s/\Q$busco\E/$cambio/g;
        }
        print;
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Saludos.
Pablo

por **explorer** » 2014-04-04 10:08 @463

¿Un bucle for de un solo elemento? Es igual a si no pusieras nada.

Lo que has escrito se puede reducir a esto:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

        while (my($busco, $cambio) = each %cambios) {
            $cuerpo =~ s/\Q$busco\E/$cambio/g;
        }
 
        print $cuerpo;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Es decir: aplicar los %cambios a $cuerpo.

por **pablgonz** » 2014-04-05 22:05 @962

Sí, tienes razón, luego de leer un poco más comprendí que for no era el indicado, lo dejaré como tú lo propones. Otra consulta, con la siguiente expresión regular:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$cuerpo =~ s/ ^\\psset\{.+?\} \s+ (\\includegrahicx\{name-fig-\d*\})/$1/gms;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

intenté quitar la palabra \psset{cualquier cosa incluso saltos de línea} que preceda a la palabra \includegrahicx{name-fig-numero} pero, no me funciona, he cambiado varias veces los modificadores y no he podido dar con la correcta.

Saludos,
Pablo

por **explorer** » 2014-04-06 06:57 @331

Por de pronto, veo que estás usando espacios en blanco dentro del patrón, sin poner el calificador '/x'.

por **pablgonz** » 2014-04-06 18:31 @813

Tienes toda la razón, solo recordaba que /x era para colocar comentarios... Me olvidé por completo de que es el modificador preciso para esta circunstancia. Al final lo dejé así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$cuerpo =~ s/ ^\\psset\{.+?\}\s*(\\includegrahicx\{name-fig-\d*\})/$1/gmsx;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Acotar expresión regular

Re: Acotar expresión regular

Publicidad

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

¿Quién está conectado?